Prolog — необычный синтаксис cons для списков

Оператор точки использовался для списков в самой первой системе Prolog 1972 года, написанной на Algol-W, иногда называемом Prolog 0. Он вдохновлен аналогичными обозначениями в системах LISP. Следующий пример взят из статьи Алена Колмерауэра и Филиппа Рождение Пролога. Русселем, создателями Пролога.

+ELEMENT(*X, *X.*Y).
+ELEMENT(*X, *Y.*Z) -ELEMENT(*X, *Z).

В то время [] был NIL.

Следующая версия Пролога, написанная на Фортране Баттани и Мелони, использовала регистры для различения атомов и переменных. Затем DECsystem 10 Prolog представила нотацию квадратных скобок, заменив nil и X.Xs на [] и [X,..Xs], которые в более поздних версиях DECsystem 10 получили [X|Xs] в качестве альтернативы. В ISO Prolog есть только [X|Xs], .(X,Xs) и канонический синтаксис '.'(X,Xs).

Обратите внимание, что точка играет много разных ролей в ISO Prolog. Он служит уже как

• конечный токен, за которым следует % или символ макета, такой как ПРОБЕЛ, НОВАЯ СТРОЧКА, TAB.

• десятичная точка в числе с плавающей запятой, например 3.14159

• графический токен char, формирующий графические токены как =..

Поэтому, если вы теперь объявляете . в качестве инфиксного оператора, вы должны быть очень осторожны. Как с тем, что вы пишете, так и с тем, что будут читать системы Prolog. Один дополнительный пробел может изменить значение термина. Рассмотрим два списка чисел в обеих нотациях:

[1,2.3,4]. [5].
1 .2.3.4.[]. 5.[].

Обратите внимание, что вы должны добавить пробел после 1. В этом контексте дополнительный пробел перед числом может изменить значение ваших терминов. Вот так:

[1|2.3]. [4]. 5. [].
1 .2.3. 4.[]. 5. [].

Вот еще один пример, который может быть еще более убедительным:

[1,-2].
1.(-2).[].

Отрицательные числа требуют круглых скобок в точечных списках.

Сегодня остались только YAP и XSB, которые по-прежнему предлагают инфикс . по умолчанию, и они это делают. иначе. И XSB даже не распознает приведенный выше синтаксис с точкой: вам нужны круглые скобки вокруг некоторых неотрицательных чисел.

Вы написали, что N.H.L кажется более удобным способом сказать [N|[H|L]]. Существует простое эмпирическое правило для упрощения таких выражений в ISO Prolog: всякий раз, когда вы видите в списке токены | и [ сразу друг за другом, вы можете заменить их на , (и удалить соответствующий ] с правой стороны) . Итак, теперь вы можете написать: [N,H|L] что не выглядит так уж плохо.

Вы можете использовать это правило и в другом направлении. Если у нас есть список [1,2,3,4,5], мы можем использовать | как "лезвие бритвы", например: [1,2,3|[4,5]].

Еще одно замечание, поскольку вы читаете статью Нейша: тем временем, она хорошо понята что нужно только call/N! И ISO Prolog поддерживает call/1, call/2 до call/8.

Да, вы правы, точка - это инфиксный оператор списка cons. На самом деле это требуется стандартом ISO Prolog, но обычно скрыто. Я нашел (и использовал) этот синтаксис некоторое время назад:

:- module(eog, []).
:- op(103, xfy, (.)).

% where $ARGS appears as argument, replace the call ($ARGS) with a VAR
% the calle goes before caller, binding the VAR (added as last ARG)
funcs(X, (V, Y)) :-
    nonvar(X),
    X =.. W.As,

    % identify meta arguments
    (   predicate_property(X, meta_predicate M)
        % explicitly exclude to handle test(dcg)
        % I'd like to handle this case in general way...
    ,   M \= phrase(2, ?, ?)
    ->  M =.. W.Ms
    ;   true
    ),

    seek_call(As, Ms, Bs, V),
    Y =.. W.Bs.

% look for first $ usage
seek_call([], [], _Bs, _V) :-
    !, fail.
seek_call(A.As, M.Ms, A.Bs, V) :-
    M @>= 0, M @=< 9, % skip meta arguments
    !, seek_call(As, Ms, Bs, V).
seek_call(A.As, _, B.As, V) :-
    nonvar(A),
    A = $(F),
    F =.. Fp.FAs,
    (   current_arithmetic_function(F) % inline arith
    ->  V = (PH is F)
    ;   append(FAs, [PH], FBs),
        V =.. Fp.FBs
    ),
    !, B = PH.
seek_call(A.As, _.Ms, B.As, V) :-
    nonvar(A),
    A =.. F.FAs,
    seek_call(FAs, Ms, FBs, V),
    !, B =.. F.FBs.
seek_call(A.As, _.Ms, A.Bs, V) :-
    !, seek_call(As, Ms, Bs, V).

:- multifile user:goal_expansion/2.
user:goal_expansion(X, Y) :-
    ( X = (_ , _) ; X = (_ ; _) ; X = (_ -> _) )
    -> !, fail % leave control flow unchanged (useless after the meta... handling?)
    ;  funcs(X, Y).

/* end eog.pl */

Мне посоветовали против этого. По сути, синтаксис [A|B] — это эволюция синтаксиса . оператор, введенный для удобства чтения.

OT: что это за код?

приведенный выше код — моя попытка подсластить Пролог функциями. А именно, вводит по запросу посредством $ временные переменные, необходимые (например) арифметическими выражениями

fact(N, F) :-
     N > 1 -> F is N * $fact($(N - 1)) ; F is 1.

каждый $ представляет переменную. После расширения у нас есть более традиционный факт/2

?- listing(fact).
plunit_eog:fact(A, C) :-
    (   A>1
    ->  B is A+ -1,
        fact(B, D),
        C is A*D
    ;   C is 1
    ).

Там, где у нас много выражений, это может быть полезно...

Этот синтаксис взят из NU-Prolog. См. здесь. Вероятно, это просто обычный функтор списка '.'/2, переопределенный как инфиксный оператор, без необходимости завершающего пустого списка:

?- L= .(a,.(b,[])).
L = [a,b]
Yes (0.00s cpu)
?- op(500, xfy, '.').
Yes (0.00s cpu)
?- L = a.b.[].
L = [a,b]
Yes (0.00s cpu)