Стилизация части процедуры docbook с помощью XSL

Я пытаюсь повлиять на свойства блока fo: list в процедуре docbook 5. Я хочу взять следующий XML-код документации:

<procedure>
    <title>Eating a banana</title>
    <step><para>Find banana</para></step>
    <step><para>Peel banana</para></step>
    <step><para>Stick banana in mouth</para></step>
<procedure>

и влияют на вывод FO только шагов (списка), а не заголовка.

Используя это:

<xsl:template match="d:procedure">
    <fo:block border-left-width="1pt" border-left-style="solid" padding-left="0.25in">
        <xsl:apply-imports />
    </fo:block>
</xsl:template>

Получается примерно так:

|
| Procedure 1: Eating a banana
|   1. Find banana
|   2. Peal banana
|   3. Stick banana in mouth
|

Я пытаюсь получить следующее:

Procedure 1: Eating a banana
  |   1. Find banana
  |   2. Peal banana
  |   3. Stick banana in mouth

Попытка сопоставить с <step> недопустима, поскольку docbook превращает их в fo: list-block (fo:block как потомок fo:list-block генерирует ошибку «недопустимый дочерний элемент»).

В Docbook есть xsl: attribute-set для <procedures>, но, насколько я могу судить, его можно использовать только для стилизации всего блока (аналогично шаблону match = 'd: procedure', а не только списку.


xslt xsl-fo docbook docbook-5
person Scribblemacher    schedule 13.04.2012    source источник

Ответы (2)


arrow_upward
1
arrow_downward

Вот как это можно сделать.

  1. Добавьте эту версию шаблона «процедура» (оригинал находится в lists.xsl) на свой уровень настройки:

    <xsl:template match="d:procedure">
  <xsl:variable name="id">
    <xsl:call-template name="object.id"/>
  </xsl:variable>

  <!-- Preserve order of PIs and comments -->
  <xsl:variable name="preamble"
        select="*[not(self::d:step
                  or self::d:title
                  or self::d:titleabbrev)]
                |comment()[not(preceding-sibling::d:step)]
                |processing-instruction()[not(preceding-sibling::d:step)]"/>

  <xsl:variable name="steps" 
                select="d:step
                        |comment()[preceding-sibling::d:step]
                        |processing-instruction()[preceding-sibling::d:step]"/>

  <xsl:call-template name="formal.object.heading"/>  

  <fo:block id="{$id}" xsl:use-attribute-sets="procedure.properties list.block.spacing"
        border-left-width="1pt" border-left-style="solid" padding-left="0.25in">

    <xsl:apply-templates select="$preamble"/>

    <fo:list-block xsl:use-attribute-sets="list.block.spacing"
                   provisional-distance-between-starts="2em"
                   provisional-label-separation="0.2em">
      <xsl:apply-templates select="$steps"/>
    </fo:list-block>

  </fo:block>
</xsl:template>

    <xsl:call-template name="formal.object.heading"/> (который возвращает fo:block с заголовком процедуры) выполняется перед выводом блока с рамкой. Я также упростил шаблон, удалив код, который обрабатывает размещение заголовка.

  2. Добавьте отступ текста в набор атрибутов formal.title.properties:

    <xsl:attribute-set name="formal.title.properties" 
               use-attribute-sets="normal.para.spacing">
  <xsl:attribute name="text-indent">
    <xsl:choose>
      <xsl:when test="self::d:procedure">-30pt</xsl:when>
      <xsl:otherwise>0pt</xsl:otherwise>
    </xsl:choose>
  </xsl:attribute>
</xsl:attribute-set>

Это сдвинет заголовок процедуры влево (но оставит другие заголовки в покое).

person mzjn    schedule 14.04.2012

arrow_upward
0
arrow_downward

Мне в голову пришла эта идея. Хотя он отлично работает для одноуровневых процедур, все, что связано с подшагами, вызовет проблемы.

<xsl:template match="d:step">
    <fo:list-item margin-left="0.25in" padding-left='1em' border-left-width='2pt' border-left-color="gray" border-left-style='solid'>
        <fo:list-item-label start-indent="0.40in" end-indent="label-end()">
            <fo:block>
                <xsl:number format="1."/>
            </fo:block>
        </fo:list-item-label>       
        <fo:list-item-body start-indent="3.5pc">
            <fo:block>
                <xsl:apply-templates />
            </fo:block>
        </fo:list-item-body>
    </fo:list-item>
</xsl:template>
person Scribblemacher    schedule 16.04.2012