Что на самом деле делает свойство Excel range.Rows?

Range.Rows и Range.Columns возвращают по существу один и тот же диапазон, за исключением того факта, что новый диапазон имеет флаг, который указывает, что он представляет строки или столбцы. Это необходимо для некоторых свойств Excel, таких как Range.Count и Range.Hidden, а также для некоторых методов, таких как Range.AutoFit():

• Range.Rows.Count возвращает количество строк в диапазоне.
• Range.Columns.Count возвращает количество столбцов в диапазоне.
• Range.Rows.AutoFit() автоматически заполняет строки в диапазоне.
• Range.Columns.AutoFit() автоматически заполняет столбцы в диапазоне.

Вы можете обнаружить, что Range.EntireRow и Range.EntireColumn полезны, хотя они все еще не совсем то, что вы ищете. Они возвращают все возможные столбцы для EntireRow и все возможные строки для EntireColumn для представленного диапазона.

Я знаю это, потому что SpreadsheetGear для .NET поставляется с .NET API, которые очень похожи на API Excel. SpreadsheetGear API поставляется с несколькими строго типизированными перегрузками для индексатора IRange, включая ту, которую вы, вероятно, хотели бы иметь в Excel:

• IRange this[int row1, int column1, int row2, int column2];

Отказ от ответственности: я владею SpreadsheetGear LLC

Range.Rows, Range.Columns and Range.Cells are Excel.Range objects, according to the VBA Type() functions:

?TypeName(Selection.rows)
Range

Таким образом, .Cells повторяется и считается набором диапазонов с одной ячейкой, как итератор по умолчанию для родительского диапазона.

Но .Columns повторяется и считается набором вертикальных поддиапазонов, каждый из которых имеет ширину в один столбец;

... И .Rows повторяется и считается набором горизонтальных поддиапазонов, каждый из которых является одной строкой в ​​высоту.

The easiest way to understand this is to step through this code and watch what's selected:

Public Sub Test() 

Dim SubRange As Range
Dim ParentRange As Range 

Set ParentRange = ActiveSheet.Range("B2:E5") 
 

For Each SubRange In ParentRange.Cells
    SubRange.Select
Next  

For Each SubRange In ParentRange.Rows
    SubRange.Select
Next 

For Each SubRange In ParentRange.Columns
    SubRange.Select
Next 

For Each SubRange In ParentRange
    SubRange.Select
Next 

End Sub

Два ваших примера - единственное, для чего я когда-либо использовал свойства Rows и Columns, но теоретически вы можете делать с ними все, что можно сделать с помощью объекта Range.

Тип возврата этих свойств сам по себе Range, поэтому вы можете делать такие вещи, как:

Dim myRange as Range
Set myRange = Sheet1.Range(Cells(2,2),Cells(8,8))
myRange.Rows(3).Select

Что выберет третью строку в myRange (ячейки B4: H4 на листе Sheet1).

update: Чтобы делать то, что вы хотите, вы можете использовать:

Dim interestingRows as Range
Set interestingRows = Sheet1.Range(startRow & ":" & endRow)

обновление №2: Или, чтобы получить подмножество строк из другого диапазона:

Dim someRange As Range
Dim interestingRows As Range

Set myRange = Sheet1.Range(Cells(2, 2), Cells(8, 8))

startRow = 3
endRow = 6

Set interestingRows = Range(myRange.Rows(startRow), myRange.Rows(endRow))

Поскольку результат .Rows помечен как состоящий из строк, вы можете "Для каждого" обрабатывать каждую строку отдельно, например:

Function Attendance(rng As Range) As Long
Attendance = 0
For Each rRow In rng.Rows
    If WorksheetFunction.Sum(rRow) > 0 Then
        Attendance = Attendance + 1
    End If
Next
End Function

Я использую это, чтобы проверить посещаемость в любой из нескольких категорий (разные столбцы) для списка людей (разные строки).

(И, конечно же, вы можете использовать .Columns для выполнения «Для каждого» столбцов в диапазоне.)

Я не уверен, но думаю, что второй параметр - отвлекающий маневр.

И .Rows, и .Columns принимают два необязательных параметра: RowIndex и ColumnIndex. Попробуйте использовать ColumnIndex, например. Rows(ColumnIndex:=2), генерирует ошибку для обоих .Rows и .Columns.

Мне кажется, это в некотором смысле унаследовано от свойства Cells(RowIndex,ColumnIndex), но подходит только первый параметр.

Я обнаружил, что использую range.Rows для его эффектов в методе Copy. Он копирует высоту строк от источника до места назначения, что мне и нужно.

rngLastRecord.Rows.Copy Destination:=Sheets("Availability").Range("a" & insertRow)

Если бы я использовал rngLastRecord.Copy вместо rngLastRecord.Rows.Copy, высота строки была бы такой, какая была до копирования.

Возможно, это немного похоже на кладж, но следующий код делает то, что вы, кажется, хотите делать:

Set rng = wks.Range(wks.Rows(iStartRow), wks.Rows(iEndRow)).Rows

Есть другой способ, возьмите это как пример

Dim sr As String    
sr = "6:10"
Rows(sr).Select

Все, что вам нужно сделать, это преобразовать ваши переменные iStartRow, iEndRow в строку.

Я нашел такие работы:

Rows(CStr(iVar1) & ":" & CStr(iVar2)).Select