Как получить доступ к (динамически выделенным) массивам Fortran в C

На мой взгляд, не рекомендуется пытаться получить доступ к глобальным данным в библиотеке Fortran. Это можно сделать с помощью блоков COMMON, но они вредны и требуют массивов статического размера. Как правило, ассоциация хранения - это плохо.

Никогда не обращайтесь к символам модуля как "__bar_MOD_a", они специфичны для компилятора и не предназначены для непосредственного использования. Передавайте указатели, используя функции и подпрограммы.

Передайте массив в качестве аргумента подпрограммы. Вы также можете выделить массив в C и передать его в Fortran. Также можно получить указатель на первый элемент массива. Он будет служить указателем C на массив.

Мое решение, для простоты без .so, добавить его тривиально:

бар.f90

module bar
 use iso_C_binding

implicit none

integer, parameter :: pa = selected_real_kind(15, 307)

real(pa), dimension(:), allocatable,target :: a
integer :: as

contains

subroutine allocArray(asize,ptr) bind(C,name="allocArray")
    integer, intent(in) :: asize
    type(c_ptr),intent(out) :: ptr

    as = asize
    allocate(a(asize))

    ptr = c_loc(a(1))
end subroutine

subroutine fillArray(values) bind(C,name="fillArray")
    real(pa), dimension(as), intent(in) :: values

    a = values
end subroutine

subroutine printArray()  bind(C,name="printArray")

    write(*,*) a
end subroutine

end module

main.c

#include <dlfcn.h>
#include <stdio.h>

int main()
{
int i, k = 4;
double arr[k];
char * e;
double *a;
void allocArray(int*,double**);
void fillArray(double*);
void allocArray();


for(i = 0; i < k; i++)
    arr[i] = i * 3.14;

allocArray(&k,&a);
fillArray(arr);
printArray();
for(i = 0; i < 4; i++)
    printf("%f ", a[i]);
printf("\n");

return 0;
}

скомпилировать и запустить:

gcc -c -g main.c

gfortran -c -g -fcheck=all bar.f90

gfortran main.o bar.o

./a.out
0.0000000000000000        3.1400000000000001        6.2800000000000002        9.4199999999999999     
0.000000 3.140000 6.280000 9.420000 

Примечание. Нет никакой причины для возврата в ваших подпрограммах Fortran, они только затемняют код.

Многие компиляторы Фортрана используют внутри так называемые дескрипторы массива - структуры, которые содержат форму массива (то есть размер и диапазон каждого измерения, а также указатель на реальные данные). Он позволяет реализовать такие вещи, как аргументы массива предполагаемой формы, указатели массива и размещаемые массивы. То, что вы получаете через символ __bar_MOD_a, является дескриптором размещаемого массива, а не его данными.

Дескрипторы массива зависят от компилятора, и код, основанный на определенном формате дескриптора, не является переносимым. Примеры дескрипторов:

• GNU Fortran
• Intel Фортран

Обратите внимание, что даже они относятся к некоторым версиям этих компиляторов. Intel, например, заявляет, что их текущий формат дескриптора несовместим с форматом, используемым в Intel Fortran 7.0.

Если вы посмотрите на оба дескриптора, вы увидите, что они во многом похожи и что первый элемент является указателем на данные массива. Таким образом, вы сможете легко прочитать данные, используя double ** вместо double *:

double **a_descr = (double**)dlsym(bar, "__bar_MOD_a");
...
for(i = 0; i < 4; i++)
    printf("%f ", (*a_descr)[i]);

Опять же, это не переносимо, поскольку формат этих дескрипторов может измениться в будущем (хотя я сомневаюсь, что указатель данных будет перемещен куда-то еще, кроме как в начало дескриптора). Существует предварительная спецификация, которая пытается унифицировать все форматы дескрипторов, но неясно, как и когда она будет принята различными поставщиками компиляторов.

Изменить: вот как использовать функцию доступа, которая использует C_LOC() из модуля ISO_C_BINDING для переносимого получения указателя на выделяемый массив:

Код Фортрана:

module bar
  use iso_c_binding
  ...
  ! Note that the array should be a pointer target
  real(pa), dimension(:), allocatable, target :: a
  ...
contains
  ...

  function getArrayPtr() result(cptr)
    type(c_ptr) :: cptr

    cptr = c_loc(a)
  end function

end module

C-код:

...
void * (*getArrayPtr)(void);
*(void **)(&getArrayPtr) = dlsym(bar, "__bar_MOD_getarrayptr");
...
double *a = (*getArrayPtr)();
for(i = 0; i < 4; i++)
    printf("%f ", a[i]);
...

Результат:

$ ./prog.x
   0.0000000000000000        3.1400000000000001        6.2800000000000002
 9.4199999999999999
0.000000 3.140000 6.280000 9.420000