Как я могу перебрать строку с разделителями и присвоить содержимое строки локальным переменным Delphi?

Вам нужен второй TStringList:

  lineLst := TStringList.Create;
  try
    lineLst.Delimiter := '#';
    lineLst.DelimitedText := Line;
    ...
  finally
    lineLst.Free;
  end;

В зависимости от вашей версии Delphi вы можете установить lineLst.StrictDelimiter := true, если строка содержит пробелы.

Вы можете сделать что-то вроде этого:

program Project1;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  System.SysUtils, StrUtils;

var
  S : string;
  D : string;

begin
  S := '23#80#10#2#1#...255#';

  for D in SplitString(S,'#') do //SplitString is in the StrUtils unit
    writeln(D);

  readln;
end.

Вы не указали свою версию Delphi, поэтому я не знаю, применима она или нет. Это зависит от версии IS. Пожалуйста, сделай!

В порядке моих личных предпочтений:

1: Загрузите Jedi CodeLib — http://jcl.sf.net. Затем используйте TJclStringList. У него очень хороший сплит-метод. После этого вам нужно будет только повторить.

функция Split(const AText, ASeparator: string; AClearBeforeAdd: Boolean = True): IJclStringList;

uses JclStringLists;
...
var s: string;  js: IJclStringList.
begin
...
   js := TJclStringList.Create().Split(input, '#', True);
   for s in js do begin
      .....
   end;
...
end;

2: Delphi теперь имеет несколько менее многофункциональную процедуру StringSplit. http://docwiki.embarcadero.com/Libraries/en/System.StrUtils.SplitString Недостаток в том, что тип массив строк может быть несовместим с самим собой по присваиванию. Здравствуй, правила Паскаля 1949...

uses StrUtils;
...
var s: string;  
    a_s: TStringDynArray; 
(* aka array-of-string aka TArray<string>. But you have to remember this term exactly*)
begin
...
   a_s := SplitString(input, '#');
   for s in a_s do begin
      .....
   end;
...
end;

3: Используйте TStringList. Основная проблема с ним заключается в том, что он был разработан таким образом, что пробелы или новые строки являются встроенными разделителями. В новых Delphi это можно подавить. В целом код должен быть адаптирован к вашей точной версии Delphi. Вы можете легко найти в Google что-то вроде «Использование TStringlist для разделения строки» и получить множество примеров (например, @Uwe).

Но вы можете забыть подавить здесь или там. А можно и на стареньких Дельфах, где этого сделать нельзя. И вы можете неправильно применить пример для другой версии Delphi. И... это просто скучно :-) Хотя вы можете сделать свою собственную функцию для генерации таких предварительно настроенных списков строк для вас и тщательно проверять в ней версию Delphi :-) Но тогда вам придется тщательно освобождать этот объект после использования.

Я использую написанную мной функцию под названием Fetch. Я думаю, что некоторое время назад я украл эту идею из библиотеки Indy:

function Fetch(var VString: string; ASeperator: string = ','): string;
var   LPos: integer;
begin
  LPos := AnsiPos(ASeperator, VString);
  if LPos > 0 then
  begin
    result := Trim(Copy(VString, 1, LPos - 1));
    VString := Copy(VString, LPos + 1, MAXINT);
  end
  else
  begin
    result := VString;
    VString := '';
  end;
end;

Тогда я бы назвал это так:

var
  value: string;
  line: string;
  profileFile: string;
  profileList: TStringList;
  index: integer;
begin
  if OpenDialog1.Execute then
  begin 
    profileFile := OpenDialog1.FileName;
    if (profileFile = '') or not FileExists(profileFile) then
      exit;

    profileList := TStringList.Create;
    try
      profileList.LoadFromFile(profileFile);

      for index := 0 to profileList.Count - 1 do
      begin
        line := profileList[index];
        Fetch(line, ''''); //discard "Line '"
        value := Fetch(line, '#')
        while (value <> '') and (value[1] <> '''') do //bail when we get to the quote at the end
        begin
           ProcessTheNumber(value); //do whatever you need to do with the number
           value := Fetch(line, '#');
        end;
      end;
    finally
      profileList.Free;
    end;
  end;
end;

Примечание: это было введено в браузере, поэтому я не проверял, работает ли оно.