Использование тега ‹br /› в XML для XSLT

CDATA говорит процессору интерпретировать содержимое как простой текст, а не как разметку. Вот почему disable-output-escaping необходимо, чтобы <br/> не отображался как <br/>.

Если вы хотите воспользоваться преимуществом disable-output-escaping, вам придется изменить способ выбора по содержимому тега.

Добавить шаблон

<xsl:template match="tag/text()">
    <xsl:value-of select="." disable-output-escaping="yes"/>
</xsl:template>

и измените строку value-of на

<xsl:apply-templates select="text()|*"/>

Одно из решений - использовать оба:

<xsl:template match="tag">
    <tr>
        <td>
            <b>
                <xsl:value-of select="@tag_code" />
            </b>
        </td>
        <td>
            <xsl:apply-templates/>
        </td>
    </tr>
</xsl:template>

<xsl:template match="tag//text()">
    <xsl:value-of select="." disable-output-escaping="yes" />
</xsl:template>

<xsl:template match="highlight">
    <span style="background-color:yellow;">
        <xsl:apply-templates />
    </span>
</xsl:template>

Однако обратите внимание, что если вы это сделаете, вам необходимо убедиться, что любые текстовые значения в узлах <tag> правильно экранируются в CDATA и дважды экранируются за его пределами, то есть, а не

<tag tag_code=":2:"><![CDATA[Robbie & Bobbie <br />]]><highlight> &amp; The Hand</highlight></tag>

Вам потребуется:

<tag tag_code=":2:"><![CDATA[Robbie &amp; Bobbie<br />]]><highlight> &amp;amp; The Hand</highlight></tag>

Так что это, вероятно, не лучший подход, если элементы <tag> имеют любую возможность содержать специальные символы XML.

Если вы можете гарантировать, что текст непосредственно под <tag> будет всегда в CDATA и что что-либо в нижних узлах (например, <highlight>s) не будет, тогда это будет немного проще. Вы можете заменить приведенный выше шаблон сопоставления текста следующим:

<xsl:template match="tag/text()">
    <xsl:value-of select="." disable-output-escaping="yes" />
</xsl:template>

И тогда вам просто нужно убедиться, что содержимое CDATA правильно экранировано, и что все остальное является просто допустимым XML.

Наконец, если у вас есть некоторый контроль над исходными данными, вам следует подумать об отказе от CDATA и просто иметь <br /> прямо в <tag>:

<tag tag_code=":2:">Robbie<br /><highlight>The Hand</highlight></tag>

Затем вы можете использовать этот XSL, который намного надежнее, чем все, что использует disable-output-escaping:

<xsl:template match="tag">
    <tr>
        <td>
            <b>
                <xsl:value-of select="@tag_code" />
            </b>
        </td>
        <td>
            <xsl:apply-templates/>
        </td>
    </tr>
</xsl:template>

<xsl:template match="tag/@* | tag/node()">
   <xsl:copy>
      <xsl:apply-templates select="@* | node()" />
   </xsl:copy>
</xsl:template>

<xsl:template match="highlight">
    <span style="background-color:yellow;">
        <xsl:apply-templates />
    </span>
</xsl:template>

К счастью, есть и простое решение. Просто добавьте эту строку в свой xsl файл:

<xsl:template match="br"><br/></xsl:template>  

Таким образом, нет необходимости переносить данные в CDATA, а вместо этого использовать гораздо более интуитивно понятный:

<tag tag_code=":1:">Jaco<br/>Ronnie</tag>

Аналогичным образом могут быть включены другие распространенные простые теги HTML. Вот пример ссылки на стили CSS жирным шрифтом, курсивом и т. Д., Но однострочный шрифт для каждого из них (как указано выше) тоже работает:

<xsl:template match="i|b|u|strong">
    <span>
        <xsl:attribute name="class">html_<xsl:value-of select="name(.)" /></xsl:attribute>
        <xsl:apply-templates />
    </span>
</xsl:template>

Если вы обнаружите, что делаете это часто, скопируйте их все в html.xsl и используйте xsl:include, чтобы использовать их при необходимости.

если вы хотите сделать в HTML это

все, что вам нужно, это сделать в XLS:

<br></br>