Генерация случайного подмножества последовательностей из файла fasta

Ваш подход выглядит прекрасно, просто излишне сложным. Я бы сделал это так:

use strict;
use warnings;

# usage: randseq.pl [fraction] < input.fasta > output.fasta
my $fraction = (@ARGV ? shift : 0.6321);

# Collect input lines into an array of sequences:
my @sequences;
while (<>) {
    # A leading > starts a new sequence. (The "\" is only there to
    # avoid confusing the Stack Overflow syntax highlighting.)
    push @sequences, [] if /^\>/;
    push @{ $sequences[-1] }, $_;
}

# Calculate how many sequences we want:
my $n = @sequences;
my $k = int( $n * $fraction + 0.5 );
warn "Selecting $k out of $n sequences (", 100 * $k / $n, "%).\n";

# Do a partial Fisher-Yates shuffle to select $k random sequences out of $n:
foreach my $i (0 .. $k-1) {
    my $j = $i + int rand($n-$i);
    @sequences[$i,$j] = @sequences[$j,$i];
}

# Print the output:
print @$_ for @sequences[0 .. $k-1];

Обратите внимание, что этот код считывает все содержимое входного файла в память. Если входной файл слишком велик для этого, и вам нужна только небольшая его часть, можно использовать резервуар sampling, чтобы выбрать k случайных последовательностей из произвольно большой их коллекции, не удерживая больше:

use strict;
use warnings;

my $k = (@ARGV ? shift : 632);  # sample size: need to know this in advance

# Use reservoir sampling to select $k random sequences:
my @samples;
my $n = 0;  # total number of sequences read
my $i;      # index of current sequence
while (<>) {
    if (/^\>/) {
        # Select a random sequence from 0 to $n-1 to replace:
        $i = int rand ++$n;
        # Save all samples until we've accumulated $k of them:
        $samples[$n-1] = $samples[$i] if $n <= $k;
        # Only actually store the new sequence if it's one of the $k first ones:
        $samples[$i] = [] if $i < $k;
    }
    push @{ $samples[$i] }, $_ if $i < $k;
}

warn "Only read $n < $k sequences, selected all.\n" if $n < $k;
warn "Selected $k out of $n sequences (", 100 * $k / $n, "%).\n" if $n >= $k;

# Print sampled sequences:
print @$_ for @samples;

Однако, если вам действительно нужна определенная часть входных последовательностей, вам нужно сначала подсчитать их в отдельном проходе по файлу.

Обе программы, указанные выше, также равномерно перемешивают выбранные последовательности в качестве побочного эффекта. (Фактически, я намеренно изменил алгоритм выборки резервуара, чтобы сделать перемешивание единообразным для всех значений n и k.) Если вы этого не хотите, вы всегда можете перед печатью отсортируйте последовательности по любому критерию, который вы предпочитаете.

я использовал функцию spritf для круглых чисел и массивов вместо временных файлов

#!/usr/bin/perl

use strict;

if (@ARGV != 1)
{
    print "Invalid arguments\n";
    print "Usage: perl randseq.pl [proteom_file]";
    exit(0);
}

my $FILE = $ARGV[0];

open(LIST,"<$FILE");

my @peptides;
my $element;
while (my $line = <LIST>){
      if ($line =~ />.*/) {
      push (@peptides, $element);
      $element=$line;
      }
      else {
      $element.=$line;
      }
}
close(LIST);

my $GET_LINES = sprintf("%.0f",$#peptides*0.6321);

my @out;
for (0..$GET_LINES) {
    my $index=$#peptides;
    push (@out, $peptides[int(rand($index))]);
    splice(@peptides, $index, 1);
}

open (OUT, '>out.fasta');
foreach (@out) {
  print OUT $_."\n";
}

exit;