Почему MessageBox не блокирует приложение в синхронизированном потоке?

Этот ответ состоит из двух частей.

Часть 1 хорошо объяснена в Если MessageBox () / related синхронны, почему мой цикл сообщений не зависает?. Функция MessageBox не блокирует, она просто создает диалоговое окно с собственным циклом сообщений.

Часть 2 объясняется в Документация MessageBox.

hWnd: дескриптор окна владельца создаваемого окна сообщения. Если этот параметр имеет значение ПУСТО (NULL), окно сообщения не имеет окна владельца.

Когда вы показываете модальное диалоговое окно, Windows отключает его владельца, но если вы передадите 0 для первого параметра, владельца нет и нечего отключать. Следовательно, ваша программа будет продолжать обрабатывать сообщения (и реагировать на них), пока отображается окно сообщения.

Чтобы изменить это поведение, передайте дескриптор формы в качестве первого параметра. Например:

procedure TTestThread.SynchThread;
begin
  MessageBoxA (Form1.Handle, 'Hello', 'Test', 0);
end;

Я подозреваю, что вопрос сводится к тому, что вы имеете в виду, когда говорите:

Окно сообщения не блокирует основное приложение.

Я понимаю, что это означает, что когда вы показываете окно сообщения, с вашей формой VCL все еще можно взаимодействовать. Проблема здесь не связана с потоками, и я предлагаю удалить их из уравнения. Ваше понимание того, что делает Synchronize, хорошее.

Проблема полностью связана с концепцией владельца окна , и как модальные диалоговые окна ведут себя по отношению к своим владельцам. Обратите внимание, что под владельцем я не имею в виду свойство Delphi TComponent.Owner, но я имею в виду значение API Windows владелец.

Создайте приложение VCL и поместите две кнопки в форму. Добавьте следующие OnClick обработчики.

procedure TForm1.Button1Click(Sender: TObject);
begin
  MessageBox(0, 'Not owned', nil, MB_OK);
end;

procedure TForm1.Button2Click(Sender: TObject);
begin
  MessageBox(Handle, 'Owned by the VCL form', nil, MB_OK);
end;

Теперь посмотрите, что происходит, когда вы нажимаете Button1. Появится окно сообщения, но вы все равно можете щелкнуть форму VCL. И сравните с Button2. Когда отображается окно сообщения, с формой VCL невозможно взаимодействовать.

Когда отображается модальное диалоговое окно, диалоговое окно отключает своего владельца. В случае Button2 владельцем является форма VCL. И как только форма отключена, вы не можете с ней взаимодействовать. В случае Button1 нет владельца, поэтому модальное диалоговое окно не отключает другие окна. Вот почему с формой VCL можно взаимодействовать.

Раймонд Чен опубликовал длинную серию статей о модальности в своем блоге Old New Thing:

• Модальность, часть 1: модальность пользовательского интерфейса и модальность кода
• Модальность, часть 2: модальность кода и модальность пользовательского интерфейса
• Модальность, часть 3: сообщение WM_QUIT
• Модальность, часть 4: важность установки правильного владельца для модального пользовательского интерфейса
• Модальность, часть 5. Установка правильного владельца для модального пользовательского интерфейса
• Модальность, часть 6. Взаимодействие с программой, которая стала модальной
• Модальность, часть 7: Timed MessageBox, дешевая версия
• Модальность, часть 8: Timed MessageBox, лучшая версия
• Модальность, часть 9: Установка правильного владельца для модального пользовательского интерфейса, практический экзамен

Синхронизация выполнит код в Mainthread.
Хорошее объяснение можно найти здесь Синхронизация в классе Delphi TThread

Вам просто нужно будет запретить пользователю взаимодействовать с формами вашего приложения, например. к

procedure TTestThread.SynchThread;
begin
MessageBoxA (0, 'Hello', 'Test', MB_TASKMODAL);      
end;

использование MessageBoxA, как и вы, не помешает Mainthread реагировать на те события, которые инициируются взаимодействием пользователя с вашими формами, просто попробуйте

procedure TForm4.Button2Click(Sender: TObject);
begin
    MessageBoxA (0, 'Hello', 'Test', 0);
   // vs
   //  MessageBoxA (0, 'Hello', 'Test', MB_TASKMODAL);
end;

MessageBoxA

что синхронизация будет выполняться в основном потоке, может быть показано (IMHO) с помощью

type
  TTestThread = class(TThread)
  private
    FSync:Boolean;
    FCalled:TDateTime;
    procedure SynchThread;
  protected
    procedure Execute; override;
  public
    constructor Create(CreateSuspended: Boolean;sync:Boolean);
  end;

procedure TTestThread.SynchThread;
begin
 MessageBox (0,PChar(DateTimeToStr(FCalled)+#13#10+DateTimeToStr(Now)),'Hello' , 0);
end;

procedure TTestThread.Execute;
begin
 sleep(100); // give Caller Time to fell asleep
 if Fsync then Synchronize (SynchThread) else SynchThread;
end;

constructor TTestThread.Create(CreateSuspended: Boolean;sync:Boolean);
begin
  inherited Create(CreateSuspended);
  FSync := Sync;
  FCalled :=Now;
  FreeOnTerminate := True;
end;

procedure StartThread(sync:Boolean);
var
 TestThread : TTestThread;
begin
 TestThread := TTestThread.Create (FALSE,sync);
end;

procedure TForm4.RunUnsynchronizedClick(Sender: TObject);
begin
   StartThread(false);// no sync
   Sleep(5000);       // Stop messageloop
end;

procedure TForm4.RunSynchronizedClick(Sender: TObject);
begin
   StartThread(true); // sync
   Sleep(5000);       // Stop messageloop
end;