Доступ к оператору пустого угла Perl ‹› из реального дескриптора файла?

Из perldoc perlvar:

• ARGV

Специальный дескриптор файла, который перебирает имена файлов командной строки в @ARGV. Обычно записывается как пустой дескриптор файла в операторе угла <>. Обратите внимание, что в настоящее время ARGV имеет магический эффект только внутри оператора <>; в других местах это просто дескриптор файла, соответствующий последнему файлу, открытому <>. В частности, передача \*ARGV в качестве параметра функции, которая ожидает дескриптор файла, может не привести к тому, что ваша функция автоматически прочитает содержимое всех файлов в @ARGV.

Я считаю, что это отвечает на все аспекты вашего вопроса в том, что Ненависть говорит это, но это не будет делать то, что вы хотите. Что вы могли бы сделать, так это создать функции, которые берут список имен файлов для открытия, и сделать это:

sub takes_filenames (@) {
  local @ARGV = @_;
  // do stuff with <>
}

Но это, вероятно, лучшее, с чем вы сможете справиться.

Развивая идею Криса Лутца, вот очень элементарная реализация:

#!/usr/bin/perl

package My::ARGV::Reader;

use strict; use warnings;
use autodie;
use IO::Handle;

use overload
    '<>' => \&reader,
    '""' => \&argv,
    '0+' => \&input_line_number,
;

sub new {
    my $class = shift;
    my $self = {
        names => [ @_ ],
        handles => [],
        current_file => 0,
    };
    bless $self => $class;
}

sub reader {
    my $self = shift;

    return scalar <STDIN> unless @{ $self->{names}};

    my $line;

    while ( 1 ) {
        my $current = $self->{current_file};
        return if $current >= @{ $self->{names} };

        my $fh = $self->{handles}->[$current];

        unless ( $fh ) {
            $self->{handles}->[$current] = $fh = $self->open_file;
        }

        if( eof $fh ) {
            close $fh;
            $self->{current_file} = $current + 1;
            next;
        }

        $line = <$fh>;
        last;
    }
    return $line;
}

sub open_file {
    my $self = shift;
    my $name = $self->{names}->[ $self->{current_file} ];
    open my $fh, '<', $name;
    return $fh;
}

sub argv {
    my $self = shift;
    my $name = @{$self->{names}}
             ? $self->{names}->[ $self->{current_file} ]
             : '-'
             ;
    return $name;
}

sub input_line_number {
    my $self = shift;
    my $fh = @{$self->{names}}
           ? $self->{handles}->[$self->{current_file}]
           : \*STDIN
           ;
    return $fh->input_line_number;
}

который можно использовать как:

package main;

use strict; use warnings;

my $it = My::ARGV::Reader->new(@ARGV);

echo($it);

sub echo {
    my ($it) = @_;
    printf "[%s:%d]:%s", $it, +$it, $_ while <$it>;
}

Вывод:

[file1:1]:bye bye
[file1:2]:hello
[file1:3]:thank you
[file1:4]:no translation
[file1:5]:
[file2:1]:chao
[file2:2]:hola
[file2:3]:gracias
[file2:4]:

Похоже, это уже реализовано как Iterator::Diamond< /а>. Iterator::Diamond также отключает магию открытия с двумя аргументами, которую Perl использует при чтении <ARGV>. Более того, он поддерживает чтение '-' как STDIN, не включая всю остальную магию. На самом деле, я мог бы использовать его для этой цели только на отдельных файлах.