xsl нахождение относительного положения относительно узла-предка

Есть некоторые проблемы, чтобы получить положение дочерних элементов division относительно узла section. Вот мой XML-файл:

<document>
    <section>
        <division>text of division</division>
        <division>text of division</division>
        <division>text of division</division>
    </section>
    <section>
        <division>text of division</division>
        <division>text of division</division>
        <division>text of division</division>
    </section>
</document>

А вот мой XSL:

<xsl:template match="/">
   <xsl:for-each select="//section">
       <div class="section">
           <xsl:text>section </xsl:text>
           <xsl:value-of select="position ()"/>
           <xsl:apply-templates/>
       </div>
    </xsl:for-each>
</xsl:template>

<xsl:template match="division">
    <div class="division">
        <xsl:text>division </xsl:text>
        <xsl:value-of select='count(../preceding-sibling::section)+1' /><xsl:text>.</xsl:text>
        <xsl:value-of select="position ()"/>
        <xsl:apply-templates/>
    </div>
</xsl:template>

И я хотел бы такой вывод, где позиция зависит от section:

section 1
division 1.1 
division 1.2
division 1.3
section 2
division 2.1
division 2.2
division 2.3

И не этот:

section 1
division 1.2 
division 1.4
division 1.6
section 2
division 2.2
division 2.4
division 2.6

Кажется, что-то вроде ../section[position()] или ../ancestor/position(), но это неправильно… Спасибо!


xml xslt position relative-path ancestor
person Yann    schedule 23.05.2013    source источник

Ответы (1)


arrow_upward
2
arrow_downward

Вместо position() попробуйте использовать xsl:number.

Пример:

Ввод XML

<document>
    <section>
        <division>text of division</division>
        <division>text of division</division>
        <division>text of division</division>
    </section>
    <section>
        <division>text of division</division>
        <division>text of division</division>
        <division>text of division</division>
    </section>
</document>

XSLT 1.0

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="text()"/>

    <xsl:template match="section|division">
        <xsl:value-of select="concat(name(),' ')"/>
        <xsl:number level="multiple" count="section|division"/>
        <xsl:text>&#xA;</xsl:text>
        <xsl:apply-templates/>
    </xsl:template>

</xsl:stylesheet>

Вывод

section 1
division 1.1
division 1.2
division 1.3
section 2
division 2.1
division 2.2
division 2.3

РЕДАКТИРОВАТЬ: Вот еще один пример, который ближе к тому, что вы делали в своем XSLT. (Я добавил <p> элементов, чтобы обернуть текст.

XSLT 1.0

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="text()"/>

    <xsl:template match="section|division">
        <div class="{name()}">
            <p>
                <xsl:value-of select="concat(name(),' ')"/>
                <xsl:number level="multiple" count="section|division"/>             
            </p>
            <xsl:apply-templates/>              
        </div>
    </xsl:template>

</xsl:stylesheet>

Вывод

<div class="section">
   <p>section 1</p>
   <div class="division">
      <p>division 1.1</p>
   </div>
   <div class="division">
      <p>division 1.2</p>
   </div>
   <div class="division">
      <p>division 1.3</p>
   </div>
</div>
<div class="section">
   <p>section 2</p>
   <div class="division">
      <p>division 2.1</p>
   </div>
   <div class="division">
      <p>division 2.2</p>
   </div>
   <div class="division">
      <p>division 2.3</p>
   </div>
</div>
person Daniel Haley    schedule 23.05.2013
comment
О, спасибо большое, все работает! Просто еще один вопрос, связанный с этим. Если у меня много <p> в узлах xml <division>, примерно так: <document> <section> <division><p>text</p><p>text</p></division> <division><p>text</p></division> <division><p>text</p></division> </section> <section> <division><p>text</p></division> <division><p>text</p><p>text</p></division> <division><p>text</p><p>text</p><p>text</p></division> </section> </document> Как пронумеровать все ‹p› из документа, а не из раздела? - person Yann; 23.05.2013
comment
Извините, нашел <xsl:number level="any"/>. Еще раз спасибо ! - person Yann; 24.05.2013