Dired: Duplicate Files (операция, а не способ избавиться от них)

Может быть, вы захотите переименовать функции (я не придумал лучших имен), может быть, какое-то более сложное форматирование, если хотите...

(defcustom dired-keep-marker-version ?V
  "Controls marking of versioned files.
If t, versioned files are marked if and as the corresponding original files were.
If a character, copied files are unconditionally marked with that character."
  :type '(choice (const :tag "Keep" t)
         (character :tag "Mark"))
  :group 'dired-mark)

(defun dired-version-file (from to ok-flag)
  (dired-handle-overwrite to)
  (dired-copy-file-recursive from to ok-flag dired-copy-preserve-time t
                 dired-recursive-copies))

(defun dired-do-version (&optional arg)
  "Search for numeric pattern in file name and create a version of that file
with that number incremented by one, or, in case such file already exists,
will search for a file with the similar name, incrementing the counter each
time by one.
Additionally, if called with prefix argument, will prompt for number format.
The formatting is the same as is used with `format' function."
  (interactive "P")
  (let ((fn-list (dired-get-marked-files nil nil)))
    (dired-create-files
     (function dired-version-file) "Version" fn-list
     (function
      (lambda (from)
        (let (new-name (i 0) (fmt (if arg (read-string "Version format: " "%d") "%d")))
          (while (or (null new-name) (file-exists-p new-name))
            (setq new-name
                  (if (string-match  "^\\([^0-9]*\\)\\([0-9]+\\)\\(.*\\)$" from)
                      (concat (match-string 1 from)
                              (format fmt
                                      (+ (string-to-number (match-string 2 from)) (1+ i)))
                              (match-string 3 from))
                    (concat from (format (concat "." fmt) i)))
                  i (1+ i))) new-name)))
     dired-keep-marker-version)))

(define-key dired-mode-map (kbd "c") 'dired-do-version)

Кроме того, я изначально использовал v для привязки этой функции, потому что я не использую dired-view, но вам нужно будет привязать это внутри хука direds. c просто был первым неопределенным ключом, поэтому я использовал его.

Есть одна функция, которая делает то, что вы хотите: dired-do-copy-regexp

Пример использования:

1. пометить файлы
2. M-x dired-do-copy-regexp
3. \(.*\)\.\(.*\)
4. \1 (copy).\2

Для файла с именем foo.txt вы создадите другой файл с именем foo (copy).txt.

Обратите внимание, что мое первое регулярное выражение имеет две группы, а второе регулярное выражение ссылается на них. При необходимости можно делать гораздо более сложные вещи.

В режиме Dired поместите курсор на файл, который вы хотите продублировать, или отметьте этот файл, затем нажмите «C». Вам будет предложено ввести новое имя.

Вы также можете использовать эту функцию для копирования файлов между буферами Dired. Чтобы это было возможно, поместите в свой файл инициализации: (setq dired-dwim-target t)