Что такое хук pre-revprop-change в SVN и как его создать?

По сути, это сценарий, который запускается перед изменением неверсированного свойства в репозитории, чтобы вы могли более точно управлять тем, что происходит в вашем репозитории.

В дистрибутиве SVN есть шаблоны для различных хуков, расположенные в подкаталоге / hooks (* .tmpl, который вам нужно отредактировать и переименовать в зависимости от вашей ОС, чтобы активировать).

Для Windows вот ссылка на пример пакетного файла, который позволяет изменять только сообщение журнала (но не другие свойства):

http://ayria.livejournal.com/33438.html

В основном скопируйте приведенный ниже код в текстовый файл, назовите его pre-revprop-change.bat и сохраните его в подкаталоге \hooks вашего репозитория.

@ECHO OFF
:: Set all parameters. Even though most are not used, in case you want to add
:: changes that allow, for example, editing of the author or addition of log messages.
set repository=%1
set revision=%2
set userName=%3
set propertyName=%4
set action=%5

:: Only allow the log message to be changed, but not author, etc.
if /I not "%propertyName%" == "svn:log" goto ERROR_PROPNAME

:: Only allow modification of a log message, not addition or deletion.
if /I not "%action%" == "M" goto ERROR_ACTION

:: Make sure that the new svn:log message is not empty.
set bIsEmpty=true
for /f "tokens=*" %%g in ('find /V ""') do (
set bIsEmpty=false
)
if "%bIsEmpty%" == "true" goto ERROR_EMPTY

goto :eof

:ERROR_EMPTY
echo Empty svn:log messages are not allowed. >&2
goto ERROR_EXIT

:ERROR_PROPNAME
echo Only changes to svn:log messages are allowed. >&2
goto ERROR_EXIT

:ERROR_ACTION
echo Only modifications to svn:log revision properties are allowed. >&2
goto ERROR_EXIT

:ERROR_EXIT
exit /b 1

Чтобы Linux разрешил редактирование комментария журнала,

• найдите файл pre-revprop-change.tmpl в каталоге hooks вашего репозитория
• скопируйте файл в тот же каталог, переименовав его в pre-revprop-change
• предоставить разрешение на выполнение для файла (для пользователя сервера, например, www-data)

Отредактировано: (спасибо lindes)

• после этого вам, возможно, придется отредактировать скрипт, чтобы вернуть значение выхода 0 для того типа редактирования, который вы хотите разрешить.

Вот ссылка на вопрос о переполнении стека со многими распространенными хуками Общие типы хуков Subversion, включая исходный код ловушки pre-revprop-change для Windows, размещенный здесь.

Вам следует обратиться туда, так как со временем они могут улучшиться.

Спасибо #patmortech

И я добавил ваш код, который «только один и тот же пользователь может изменить свой код».

:: Only allow editing of the same user.
for /f "tokens=*" %%a in ( 
'"%VISUALSVN_SERVER%\bin\svnlook.exe" author -r %revision% %repository%') do ( 
set orgAuthor=%%a
)
if /I not "%userName%" == "%orgAuthor%" goto ERROR_SAME_USER

Название скрипта перехвата не так страшно, если вам удастся его расшифровать: это перехватчик изменения свойства до ревизии. Короче говоря, цель _1 _ предназначен для управления изменениями неверсированных (ревизионных) свойств и для отправки уведомлений (например, для отправки электронного письма при изменении свойства ревизии).

# Store hook arguments into variables with mnemonic names
$repos    = $args[0]
$rev      = $args[1]
$user     = $args[2]
$propname = $args[3]
$action   = $args[4]

# Only allow changes to svn:log. The author, date and other revision
# properties cannot be changed
if ($propname -ne "svn:log")
{
  [Console]::Error.WriteLine("Only changes to 'svn:log' revision properties are allowed.")
  exit 1
}

# Only allow modifications to svn:log (no addition/overwrite or deletion)
if ($action -ne "M")
{
  [Console]::Error.WriteLine("Only modifications to 'svn:log' revision properties are allowed.")
  exit 2
}

# Read from the standard input while the first non-white-space characters
$datalines = ($input | where {$_.trim() -ne ""})
if ($datalines.length -lt 25)
{
  # Log message is empty. Show the error.
  [Console]::Error.WriteLine("Empty 'svn:log' properties are not allowed.")
  exit 3
}

exit 0

IF "%3" == "svnmgr" (goto :label1) else (echo "Only the svnmgr user may change revision properties" >&2 )

exit 1
goto :eof

:label1
exit 0

Для пользователей ПК: расширение .bat не работало для меня при использовании на Windows Server. Я использовал VisualSvn, как предложил Джанго Рейнхардт, и он создал ловушку с расширением .cmd.

Если вы хотите сохранить изменения в сообщениях журнала, используйте пакетный скрипт из ответа выше от @patmortech (https://stackoverflow.com/a/468475),
который скопировал сценарий из https://stackoverflow.com/a/68850,
и добавьте эти строки между if "%bIsEmpty%" == "true" goto ERROR_EMPTY и goto :eofbefore:

set outputFile=%repos%\log-change-history.txt

echo User '%user%' changes log message in rev %rev% on %date% %time%.>>%outputFile%
echo ----- Old message: ----->>%outputFile%
svnlook propget --revprop %repos% svn:log -r %rev% >>%outputFile%
echo.>>%outputFile%
echo ----- New message: ----->>%outputFile%
for /f "tokens=*" %%g in ('find /V ""') do (echo %%g >>%outputFile%)
echo ---------->>%outputFile%
echo.>>%outputFile%

Он создаст текстовый файл log-change-history.txt в папке репо на сервере и будет добавлять каждое уведомление об изменении журнала.

Для меня это был самый простой способ на Windows Server: в VisualSVN щелкните правой кнопкой мыши свой репозиторий, затем выберите Свойства ..., а затем вкладку Хуки.

Выберите Обработчик изменения свойств предварительной версии, нажмите Изменить.

Мне нужно было сменить автора - это часто случается на удаленных компьютерах, используемых несколькими людьми, когда мы по ошибке регистрируемся, используя чужие сохраненные учетные данные.

Вот измененный скрипт вики-сообщества, который нужно вставить:

@ECHO OFF
:: Set all parameters. Even though most are not used, in case you want to add
:: changes that allow, for example, editing of the author or addition of log messages.
set repository=%1
set revision=%2
set userName=%3
set propertyName=%4
set action=%5

:: Only allow the author to be changed, but not message ("svn:log"), etc.
if /I not "%propertyName%" == "svn:author" goto ERROR_PROPNAME

:: Only allow modification of a log message, not addition or deletion.
if /I not "%action%" == "M" goto ERROR_ACTION

:: Make sure that the new svn:log message is not empty.
set bIsEmpty=true
for /f "tokens=*" %%g in ('find /V ""') do (
set bIsEmpty=false
)
if "%bIsEmpty%" == "true" goto ERROR_EMPTY

goto :eof

:ERROR_EMPTY
echo Empty svn:author messages are not allowed. >&2
goto ERROR_EXIT

:ERROR_PROPNAME
echo Only changes to svn:author messages are allowed. >&2
goto ERROR_EXIT

:ERROR_ACTION
echo Only modifications to svn:author revision properties are allowed. >&2
goto ERROR_EXIT

:ERROR_EXIT
exit /b 1

1. Перейдите в каталог репозитория SVN в подпапку «хуки», например "D: \ SVN \ крючки \"
2. создайте там пустой файл "pre-revprop-change.bat"
3. в файле напишите "exit 0" (без "") и сохраните его
4. наслаждаться :)

(У этого решения, безусловно, есть недостатки, поскольку ничего не проверяется / не запрещается. Но в моем случае - локальное репо, которое использую только я, - похоже, работает.)