XSLT 1.0 Жадные методы группировки ранца?

У меня есть набор данных XML (предоставленный из SharePoint 2007 в DVWP), структурированный примерно так:

<Rows>
  <Row ID="1" Spanoffset="0" Span="55" Spantail="55"/>
  <Row ID="2" Spanoffset="30" Span="31" Spantail="61"/>
  <Row ID="3" Spanoffset="61" Span="20" Spantail="81"/>
  <Row ID="4" Spanoffset="82" Span="30" Spantail="112"/>
</Rows>

Скажем, каждая строка представляет собой полосу, которая начинается с @Spanoffset и имеет ширину @Span, @Spantail есть, поэтому мне не нужно вычислять ее, если она мне нужна. Я пытаюсь эффективно упаковать строки вместе, чтобы строки, которые не перекрываются, группировались вместе. Набор данных предварительно отсортирован по @Spanoffset. По сути, это задача о рюкзаке, поскольку каждый ряд может входить в несколько возможных групп. Я хочу сделать простое жадное решение и знаю, как я могу его закодировать, скажем, на C # или java, но поскольку я не могу пометить узлы как посещенные (ну, я могу, но я теряю его, когда возвращаюсь к дереву рекурсии) и я не могу удалить узлы, когда посещаю их, я не понимаю, как к этому подойти.

Например, приведенные выше данные будут выглядеть примерно так:

<div style="clear:both">
  <div style="width: 110px; margin-left: 0px; float:left;">1</div>
  <div style="width: 40px; margin-left: 12px; float:left;">3</div>
  <div style="width: 60px; margin-left: 2px; float:left;">4</div>
</div>
<div style="clear:both">
  <div style="width: 62px; margin-left: 60px; float:left;">2</div>
</div>

Я не утруждала себя попытками заставить поплавки работать правильно, так как мне еще не удалось заставить узлы Row появляться только по одному разу каждый в правильном порядке. Как только я получу их там, я почти уверен, что смогу заставить форматирование работать.

Лучший XSLT, который я придумал, был:

<xsl:template match="row">
  <xsl:variable name="tail" select="@Spantail"/>
  <div style="width:{2*@Span}px;
    left:{2*(@Spanoffset)}px;">
    <xsl:value-of select="@ID"/>
  </div>                        
  <xsl:apply-templates select="(following-sibling::row)[@Spanoffset>=$tail][1]"/>
</xsl:template>

Что порождает

<div style="width: 110px;left: 0px">1</div>
<div style="width: 40px; left: 122px">3</div>
<div style="width: 60px; left: 164px">4</div>
<div style="width: 62px; left: 60px">2</div>
<div style="width: 40px; left: 122px">3</div>
<div style="width: 60px; left: 164px">4</div>
<div style="width: 40px; left: 122px">3</div>
<div style="width: 60px; left: 164px">4</div>
<div style="width: 60px; left: 164px">4</div>

Итак, у меня две проблемы (которые я вижу), и я думаю, что они взаимосвязаны. 1) Как исправить / перефакторить мой шаблон (ы), чтобы выдавать каждую строку только один раз. и 2) Как обернуть группы в контейнер <div> элементов.

Бился головой об это 2 дня, кто-нибудь может помочь?

Изменить: Ну, после некоторого сна у меня есть контейнер для упаковки, добавив логический параметр в мой шаблон и используя некоторые теги CDATA для испускания тегов <div>, когда он истинен. По умолчанию логическое значение имеет значение true, и когда я вызываю вложенные шаблоны apply, я устанавливаю его значение false, тем самым упаковывая группы в контейнеры. Я все еще не вижу способа отметить <Row> как посещенные.


xslt msxml xslt-1.0 sharepoint-2007 dataviewwebpart
person Hector    schedule 18.11.2013    source источник
comment
Кажется сложным без более подробных правил группировки. Что, если бы у вас было три строки: <Row ID="1" Spanoffset="0" Span="10" Spantail="10"/>, <Row ID="2" Spanoffset="15" Span="10" Spantail="25"/>, <Row ID="3" Spanoffset="20" Span="10" Spantail="35"/>. Сгруппировали бы вы строки 1 и 2 вместе или строки 1 и 3 вместе?   -  person Ben L    schedule 19.11.2013
comment
@BenL Итак, ваш вопрос поднимает проблему с рюкзаком. Я просто стремился к простому жадному алгоритму. Итак, в вашем примере я бы сгруппировал 1 и 2 вместе, а 3 сформировал бы новую группу.   -  person Hector    schedule 19.11.2013

Ответы (1)


arrow_upward
1
arrow_downward

Я думаю, что это очень сложно с базовым XSLT, но проще с node-set (), функция расширения XSLT:

<xsl:template name="add-row">
    <xsl:param name="row"/>
    <xsl:param name="prev-group" />
    <xsl:if test="$row and not($row/@ID = $prev-group/Row/@ID)">
        <xsl:copy-of select="$row" />
        <xsl:call-template name="add-row">
            <xsl:with-param name="row" select="$row/following-sibling::Row[@Spanoffset &gt; $row/@Spantail][1]" />
            <xsl:with-param name="prev-group" select="$prev-group" />
        </xsl:call-template>
    </xsl:if>   
</xsl:template>

<xsl:template name="add-group">
    <xsl:param name="first-row" />
    <xsl:param name="prev-group" select="exsl:node-set(/)" />
    <xsl:if test="$first-row">
        <xsl:variable name="group">
            <xsl:call-template name="add-row">
                <xsl:with-param name="row" select="$first-row" />
                <xsl:with-param name="prev-group" select="$prev-group" />
            </xsl:call-template>
        </xsl:variable>
        <div clear="both">
            <xsl:for-each select="exsl:node-set($group)/Row">
                <div style="width: {2*@Span}px; left: {2*@Spanoffset}px"><xsl:value-of select="@ID"/></div>                             
            </xsl:for-each>
        </div>
        <xsl:call-template name="add-group">
            <xsl:with-param name="first-row" select="$first-row/following-sibling::Row[@Spanoffset &lt; preceding-sibling::Row/@Spantail][1]" />
            <xsl:with-param name="prev-group" select="exsl:node-set($group)" />
        </xsl:call-template>
    </xsl:if>
</xsl:template>

<xsl:template match="Rows">
    <xsl:call-template name="add-group">
        <xsl:with-param name="first-row" select="Row[1]" />
    </xsl:call-template>
</xsl:template>

Не забудьте объявить префикс расширения и пространство имен в теге таблицы стилей:

<xsl:stylesheet
  version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  extension-element-prefixes="exsl"
  xmlns:exsl="http://exslt.org/common">

http://exslt.org/common - допустимое пространство имен для процессоров Java XSLT, таких как Xalan или Saxon; если вы используете MSXML, используйте вместо этого urn: schemas-microsoft-com: xslt.

person Erlock    schedule 20.11.2013
comment
Мне пришлось внести некоторые изменения, но это действительно привело меня на правильный путь. Я пытался и не мог использовать msxsl:node-set(), но это было хорошей отправной точкой. Данные моего примера были не такими большими и разнообразными, как реальные данные, поэтому не было очевидно, что может быть более двух строк, поэтому мне пришлось добавить аккумулятор в prev-group, но это была простая часть. Большое вам спасибо, я собирался сдаться и попытаться решить эту проблему с помощью javascript. - person Hector; 20.11.2013
comment
Впоследствии я подумал, что может потребоваться объединение групп в prev-group ... Я рад видеть, что этот частичный ответ вас не смутил. :) - person Erlock; 20.11.2013