CDO.Message Classic ASP — Добавление вложения

У меня возникают проблемы с попыткой добавить вложение в сообщение электронной почты с помощью Classic ASP. Я просмотрел форумы и, похоже, мне нужно было добавить .AddAttachment = "c:\users\samplb\logoblack.gif", но форма больше не работает. Выдает сообщение "Веб-сайт не может отобразить страницу".

Вот мой код:

<% 

name = request.form("name")
Message = request.form("Message")


Set cdoConfig = CreateObject("CDO.Configuration")  

With cdoConfig.Fields  
    .Item(cdoSendUsingMethod) = cdoSendUsingPort  
    .Item(cdoSMTPServer) = "xxx"  
    .Update  
End With 

Set cdoMessage = CreateObject("CDO.Message")  

With cdoMessage 
    Set .Configuration = cdoConfig 
    .From = "[email protected]"
    .To = "[email protected]" 
    .Subject = "Feedback / Suggestions" 
    .AddAttachment = "c:\users\samplb\logoblack.gif" 
    .TextBody = "Name: " & name & vbcrlf & vbcrlf & "Message: " & Message  
    .Send 
End With 

Set cdoMessage = Nothing  
Set cdoConfig = Nothing  
%>

Кто-нибудь знает, почему он может не работать? Когда я вынимаю .AddAttachment, форма работает нормально, но мне действительно нужно отправить вложение.


asp-classic cdo.message
person Samp    schedule 01.04.2014    source источник

Ответы (1)


arrow_upward
3
arrow_downward

Проблема в том, что .AddAttachment() - это метод, а не свойство, попробуйте изменить свой код следующим образом;

Call .AddAttachment("c:\users\samplb\logoblack.gif")

или вернуть вложение как CDO.BodyPart использование;

Set cdoBodyPart = .AddAttachment("c:\users\samplb\logoblack.gif")

Примечание. См. Метод AddAttachment (библиотека MSDN) для получения дополнительной информации об этом методе и способах его использования.

person user692942    schedule 01.04.2014