Агрегирование фактов в экспертной системе CLIPS для поиска максимума

Я пытаюсь прояснить свое понимание семантики в экспертной системе Clips, поэтому я пытаюсь написать несколько простых правил для агрегирования списка фактов, чтобы найти факт с наивысшим значением слота. Я использую метафору простого агента, пытающегося решить, следует ли ему есть или спать. Факты, описывающие состояния агента, расширяются до возможных действий, а затем правило пытается найти последнее действие с наибольшей полезностью.

Это мой код:

(clear)

(deftemplate state 
    (slot name) 
    (slot level (type NUMBER)) 
) 
(deftemplate action 
    (slot name) 
    (slot utility (type NUMBER)) 
    (slot final (type INTEGER) (default 0)) 
) 
(defrule eat-when-hungry "" 
    (state (name hungry) (level ?level)) 
    => 
    (assert (action (name eat) (utility ?level))) 
) 
(defrule sleep-when-sleepy "" 
    (state (name sleepy) (level ?level)) 
    => 
    (assert (action (name sleep) (utility ?level))) 
) 
(defrule find-final-action "" 
    ?current_final <- (action (name ?current_final_action) (utility ? 
current_final_utility) (final 1)) 
    (action (name ?other_action) (utility ?other_utility) (final 0)) 
    (neq ?current_final_action ?other_action) 
    (< ?current_final_action ?other_action) 
    => 
    (modify ?current_final (name ?other_action) (utility ? 
other_utility)) 
) 
(assert (action (name none) (utility 0.0) (final 1))) 
(assert (state (name hungry) (level 0.5))) 
(assert (state (name sleepy) (level 0.1))) 
(run) 
(facts)

После запуска я ожидал, что последнее действие будет следующим:

(action (name eat) (utility 0.5) (final 1))

Однако Clips оценивает это как:

(action (name none) (utility 0.0) (final 1))

означает, что правило поиска-финального действия никогда не активируется. Почему это? Как бы вы перебрали группу фактов и нашли бы тот, у которого значение слота min / max?


clips expert-system
person Cerin    schedule 04.03.2010    source источник

Ответы (1)


arrow_upward
1
arrow_downward

В вашем правиле было несколько ошибок. Вот исправленная версия:

(defrule find-final-action "" 
    ?current_final <- (action (name ?current_final_action) 
                              (utility ?current_final_utility) (final 1)) 
    (action (name ?other_action) (utility ?other_utility) (final 0)) 
    (test (neq ?current_final_action ?other_action))
    (test (< ?current_final_utility ?other_utility)) 
    => 
    (modify ?current_final (name ?other_action) (utility ?other_utility)))

Альтернативный метод, который не требует хранения промежуточных вычислений и многократных запусков правил, заключается в следующем:

(defrule find-final-action-2 "" 
    (declare (salience -10)) ; lower salience to allow all actions to be asserted first
    (action (name ?action) (utility ?utility)) 
    (not (action (utility ?other_utility&:(> ?other_utility ?utility))))
    => 
    (printout t "Final action is " ?action crlf))
person Gary Riley    schedule 05.07.2010