Использование emacs (и magit?) Для посещения файла в данной фиксации / ветке / и т. Д.

Канонический способ сделать это в Emacs - использовать VC: C-x v ~ из буфера файла запросит у вас ревизию, а затем покажет этот файл таким, каким он был в этой ревизии. Он должен работать с любой системой управления, поддерживаемой VC, например Git, Bzr, ...

• C-x v l для просмотра истории файла.
• n и p для перемещения между коммитами.
• f, чтобы посетить файл с момента фиксации в точке.

Это связано с log-view-find-revision, и если мы посмотрим на код, мы увидим, что критический бит:

(switch-to-buffer (vc-find-revision file revision)))

Таким образом, мы могли бы обернуть это в пользовательскую функцию следующим образом:

(defun my-vc-visit-file-revision (file revision)
  "Visit FILE as it was at REVISION."
  (interactive
   (list (expand-file-name
          (read-file-name (if (buffer-file-name)
                              (format "File (%s): " (file-name-nondirectory
                                                     (buffer-file-name)))
                            "File: ")))
         (read-string "Revision: ")))
  (require 'vc)
  (switch-to-buffer
   (vc-find-revision file revision)))

Изменить: Стефан дал лучший ответ, но если вам понравилась возможность выбрать файл, а также ревизию, вот версия моей функции, которая поддерживает интерактивный выбор файла, но использует код из vc-revision-other-window для обработки ревизии.

Я пришел к выводу, что использование другого окна по умолчанию действительно имеет больше смысла, поэтому я сделал то же самое здесь - если вы не укажете аргумент префикса, и в этом случае он использует текущее окно.

(defun my-vc-visit-file-revision (file rev)
  "Visit revision REV of FILE in another window.
With prefix argument, uses the current window instead.
If the current file is named `F', the revision is named `F.~REV~'.
If `F.~REV~' already exists, use it instead of checking it out again."
  ;; based on `vc-revision-other-window'.
  (interactive
   (let ((file (expand-file-name
                (read-file-name
                 (if (buffer-file-name)
                     (format "File (%s): " (file-name-nondirectory
                                            (buffer-file-name)))
                   "File: ")))))
     (require 'vc)
     (list file (if (vc-backend file)
                    (vc-read-revision
                     "Revision to visit (default is working revision): "
                     (list file))
                  (vc-read-revision "Revision to visit: " t
                                    (or (vc-deduce-backend)
                                        (vc-responsible-backend file)))))))
  (require 'vc)
  (let ((revision (if (string-equal rev "")
                      (if (vc-backend file)
                          (vc-working-revision file)
                        (error "No revision specified for unregistered file %s"
                               file))
                    rev))
        (backend (or (vc-backend file)
                     (vc-deduce-backend)
                     (vc-responsible-backend file)))
        (visit (if current-prefix-arg
                   'switch-to-buffer
                 'switch-to-buffer-other-window)))
    (condition-case err
        (funcall visit (vc-find-revision file revision backend))
      ;; The errors which can result when we request an invalid combination of
      ;; file and revision tend to be opaque side-effects of some unexpected
      ;; failure within the backend; so we simply trap everything and signal a
      ;; replacement error indicting the assumed cause.
      (error (error "File not found at revision %s: %s" revision file)))))

Я привязываю эту команду к C-x v C-f

Существует пакет под названием git-timemachine, который делает процесс просмотра предыдущих версий файла почти полностью бесшовным; см. ссылку для инструкций по установке и демонстрации. (Если вы уже используете MELPA, просто выполните M-x package-install RET git-timemachine RET).

Это работает так: вы вызываете M-x git-timemachine RET из буфера, обращаясь к отслеживаемому файлу. Тогда ты можешь:

• p Посетить предыдущую историческую версию
• n Посетить следующую историческую версию
• w Скопируйте сокращенный хэш текущей исторической версии
• W Скопируйте полный хэш текущей исторической версии
• q Выйдите из машины времени.

Обратите внимание: если вы знаете хэш фиксации, которую хотите посетить, пользовательская команда из решения @phils лучше подойдет вам для этого конкретного варианта использования. Но для навигации между разными версиями файла я считаю, что использовать git-timemachine даже проще, чем использовать функциональные возможности, предоставляемые VC.

Конечно, вы можете привязать git-timemachine к привязке клавиш по вашему выбору.

Если вы просматриваете фиксацию в magit, вы можете просто нажать Enter на файле или части файла, который вас интересует.