Как сделать точки диаграммы рассеяния полупрозрачными с помощью SPSS?

Я построил этот график с помощью базовой диаграммы рассеяния SPSS по умолчанию: я использовал параметры «Bin-element» и «Marker Size», чтобы перегруппировать наложенные точки и упростить их чтение. Вот он: http://imageshack.com/a/img902/8746/pTRzJV.jpg

Но я бы хотел получить график, который выглядит примерно так: http://espnfivethirtyeight.files.wordpress.com/2014/09/morris-feature-skepticnflweek2-2.png

Точки этого графика используют полупрозрачность. Я попытался найти кое-что о непрозрачности или полупрозрачности, и нашел только этот ресурс: http://andrewpwheeler.wordpress.com/2012/06/17/visualization-techniques-for-large-n-scatterplots-in-spss/

К сожалению, я не понимаю, как это сделать ... Не могли бы вы мне помочь?

Кстати, знаете ли вы, был ли этот график создан с помощью SPSS или, скорее, R? Какой инструмент лучше всего подходит для таких графиков?

Спасибо !


opacity scatter-plot spss
person Guillaume    schedule 23.09.2014    source источник
comment
Диаграмма в блоге 538, я полагаю, редактируется в программе векторной графики (например, в Illustrator). Это может быть сначала сделано, а затем отредактировано в любых пакетах статистики (Натан Яу в Visualize This имеет примеры этого.) Обратите внимание в моем сообщении в блоге, на которое вы связались, у меня есть код для создания всех графиков в конце поста.   -  person Andy W    schedule 23.09.2014

Ответы (1)


arrow_upward
3
arrow_downward

Вот краткий пример. Итак, сначала я сделаю несколько фальшивых данных.

INPUT PROGRAM.
LOOP ID = 1 TO 10000.
END CASE.
END LOOP.
END FILE.
END INPUT PROGRAM.
COMPUTE X = RV.NORMAL(0,1).
COMPUTE Y = RV.NORMAL(0,1).

Насколько мне известно, теперь вы не можете создавать непрозрачность в графическом интерфейсе - вам нужно указать это в синтаксисе. Итак, пройдите через диалоговое окно Graph Builder GUI, укажите интересующую вас диаграмму рассеяния и затем вставьте синтаксис. Вот что дает мне по умолчанию плюс график (с моим конкретным шаблоном диаграммы).

GGRAPH
  /GRAPHDATASET NAME="graphdataset" VARIABLES=X Y MISSING=LISTWISE REPORTMISSING=NO
  /GRAPHSPEC SOURCE=INLINE.
BEGIN GPL
  SOURCE: s=userSource(id("graphdataset"))
  DATA: X=col(source(s), name("X"))
  DATA: Y=col(source(s), name("Y"))
  GUIDE: axis(dim(1), label("X"))
  GUIDE: axis(dim(2), label("Y"))
  ELEMENT: point(position(X*Y))
END GPL.

введите описание изображения здесь

Теперь вам нужно будет отредактировать параметры в предпоследней строке оператора ELEMENT. Я собираюсь сделать две вещи; 1) сделать точки меньше и 2) сделать внешнюю линию точек полупрозрачной. Вот код и результирующий график.

GGRAPH
  /GRAPHDATASET NAME="graphdataset" VARIABLES=X Y MISSING=LISTWISE REPORTMISSING=NO
  /GRAPHSPEC SOURCE=INLINE.
BEGIN GPL
  SOURCE: s=userSource(id("graphdataset"))
  DATA: X=col(source(s), name("X"))
  DATA: Y=col(source(s), name("Y"))
  GUIDE: axis(dim(1), label("X"))
  GUIDE: axis(dim(2), label("Y"))
  ELEMENT: point(position(X*Y), size(size."2"), 
           transparency.exterior(transparency."0.9"))
END GPL.

введите описание изображения здесь

person Andy W    schedule 23.09.2014
comment
Извините, я не видел вашего ответа до сих пор. Большое спасибо за ваш ответ и ваш комментарий. - person Guillaume; 16.01.2015