Получить действительную букву диска и занято

Я предоставил пару функций, которые могут помочь. Первый использует функцию Win32 API GetLogicalDriveStrings для получения списка назначенных букв дисков на компьютере. Второй запрашивает диск, чтобы узнать, готов ли он к использованию (есть ли в нем диск). (Есть также служебная функция, которая преобразует букву диска в целочисленное значение, необходимое для DiskSize, старой функции ввода-вывода Pascal.)

Код работает со времен Win95 и только что был протестирован на 64-разрядной версии Win7 в консольном приложении Delphi 2007. Ниже приведено консольное тестовое приложение.

program Project2;

{$APPTYPE CONSOLE}

uses
  SysUtils, Windows, Types;

// Returns an array filled wit the assigned
// drive letters on the current computer.
function  GetDriveList: TStringDynArray;
var
  Buff: array[0..128] of Char;
  ptr: PChar;
  Idx: Integer;
begin
  if (GetLogicalDriveStrings(Length(Buff), Buff) = 0) then
    RaiseLastOSError;
  // There can't be more than 26 lettered drives (A..Z).
  SetLength(Result, 26);      

  Idx := 0;
  ptr := @Buff;
  while StrLen(ptr) > 0 do
  begin
    Result[Idx] := ptr;
    ptr := StrEnd(ptr);
    Inc(ptr);
    Inc(Idx);
  end;
  SetLength(Result, Idx);
end;

// Converts a drive letter into the integer drive #
// required by DiskSize().
function DOSDrive( const sDrive: String ): Integer;
begin
  if (Length(sDrive) < 1) then
    Result := -1
  else
    Result := (Ord(UpCase(sDrive[1])) - 64);
end;

// Tests the status of a drive to see if it's ready
// to access. 
function DriveReady(const sDrive: String): Boolean;
var
  ErrMode: Word;
begin
  ErrMode := SetErrorMode(0);
  SetErrorMode(ErrMode or SEM_FAILCRITICALERRORS);
  try
    Result := (DiskSize(DOSDrive(sDrive)) > -1);
  finally
    SetErrorMode(ErrMode);
  end;
end;

// Demonstrates using the above functions.
var
  DrivesArray: TStringDynArray;
  Drive: string;
const
  StatusStr = 'Drive %s is ready: %s';
begin
  DrivesArray := GetDriveList;
  for Drive in  DrivesArray do
    WriteLn(Format(StatusStr, [Drive, BoolToStr(DriveReady(Drive), True)]));
  ReadLn;
end.

Пример вывода при запуске в моей системе (Win7 64, два физических жестких диска (C: и D:), устройство ISO без смонтированного образа (E:) и DVD-привод (Z:).

Drive C:\ is ready: True 
Drive D:\ is ready: True 
Drive E:\ is ready: False
Drive Z:\ is ready: True

Диалоговое окно с ошибкой является проблемой обратной совместимости. Старые версии (намного старше) Windows показывали такие диалоги. Дизайнеры поняли, что часто они нежелательны. Приложения должны иметь возможность самостоятельно обрабатывать эти условия.

Но изменение оптовой продажи затронуло бы те приложения, которые хотели иметь диалоги. Поэтому был введен механизм, позволяющий приложениям контролировать определенные аспекты обработки ошибок.

Вы можете подавить такие диалоги ошибок, вызвав SetErrorMode. Это позволяет вам подавить диалоговое окно, и вместо этого неудачный вызов API вернет ошибку.

Вызовите следующую функцию один раз при запуске:

procedure SetProcessErrorMode;
var
  CurrentMode: DWORD;
begin
  CurrentMode := SetErrorMode(0);
  SetErrorMode(CurrentMode or SEM_FAILCRITICALERRORS
    or SEM_NOOPENFILEERRORBOX);
end;

Этот вызов должен быть сделан один раз при запуске. Режим ошибки является общим свойством процесса, и изменения после запуска могут привести к нежелательным и непредсказуемым побочным эффектам. MSDN говорит:

Рекомендуется, чтобы все приложения вызывали функцию SetErrorMode для всего процесса с параметром SEM_FAILCRITICALERRORS при запуске. Это необходимо для предотвращения зависания приложения в диалоговых окнах режима ошибок.

Я лично рекомендую также добавить SEM_NOOPENFILEERRORBOX.

Я попытался здесь ответить на часть вашего вопроса, но не на все. Я думаю, что это разумно, когда вы задаете несколько вопросов одновременно.