Подделка учетных данных друга с помощью Midje

Недавно я столкнулся с подобной проблемой, и после некоторого копания я думаю, что понял, почему это происходит. Давайте посмотрим, как со временем меняются привязки для auth/cred-fn.

(clojure.pprint/pprint (macroexpand '(defn cred-fn
                                                [creds]
                                                (println (str "hey look I got called with " creds))
                                                (throw (Exception.)))))
(def
 cred-fn
 (clojure.core/fn
  ([creds]
   (println (str "hey look I got called with " creds))
   (throw (Exception.)))))

Как вы можете видеть выше, макрос defn вставляет символ cred-fn в текущее пространство имен и связывает его с Var, ссылающимся на вашу фиктивную функцию.

(def app 
    (-> app-routes
        (wrap-json-body {:keywords? true :bigdecimals? true})
        wrap-json-response
        (wrap-defaults defaults)
        (friend/authenticate
        {:unauthorized-handler json-auth/login-failed
        :workflows [(json-auth/json-login
                    :login-uri "/login"
                    :login-failure-handler json-auth/login-failed
                    :credential-fn auth/cred-fn)]})
        (ring-session/wrap-session)))

Вот важная часть. Во время компиляции мы пропускаем app-routes через серию функций. Одной из таких функций является friend/authenticate, которая берет карту с ключом :workflows. Значение :workflows представляет собой вектор, заполненный результатами вызова json-auth/json-login, который получает auth/credential-fn в качестве параметра. Помните, что мы находимся внутри определения, так что все это происходит во время компиляции. Мы ищем символ cred-fn в пространстве имен auth и передаем Var, к которому привязан символ. На данный момент это все еще фиктивная реализация. Предположительно, json-auth/json-login фиксирует эту реализацию и устанавливает обработчик запросов, который ее вызывает.

(fact "login with incorrect username and password returns unauthenticated"
    (:status (post "/login" invalid-auth-account-json)) => 401
    (provided
    (auth/cred-fn anything) => nil))

Теперь мы во время выполнения. В нашем предварительном условии Midje перепривязывает символ auth/cred-fn к Var, который ссылается на макет. Но значение auth/cred-fn уже было захвачено, когда мы def'd app во время компиляции.

Так почему же обходной путь, который вы опубликовали, работает? (На самом деле это была подсказка, которая привела меня к моменту Эврики — спасибо за это.)

(defn another-fn []
  (println (str "hey look I got called"))
  (throw (Exception.)))

(defn cred-fn [creds]
  (another-fn))

И в ваших тестах...

(fact "login with incorrect username and password returns unauthenticated"
  (:status (post "/login" invalid-auth-account-json)) => 401
  (provided
    (auth/another-fn) => nil))

(fact "login with correct username and password returns success"
  (:status (post "/login" auth-account-json)) => 200
  (provided
    (auth/another-fn) => {:identity "root"}))

Это работает, потому что во время компиляции значение auth/cred-fn, которое перехватывается, является функцией, которая просто делегирует auth/another-fn. Обратите внимание, что auth/another-fn еще не оценивался. Теперь в наших тестах Мидже перепривязывает auth/another-fn для ссылки на макет. Затем он выполняет сообщение, и где-то в промежуточном программном обеспечении вызывается auth/cred-fn. Внутри auth/cred-fn мы ищем Var, привязанный к auth/another-fn (который является нашим макетом), и вызываем его. И теперь, конечно, поведение именно такое, как вы ожидали в первый раз.

Мораль этой истории такова: будьте осторожнее с определением в Clojure

Я до сих пор не уверен, почему это происходит, но у меня есть обходной путь. Если я заменю свой credential-fn на:

(defn another-fn
  []
  (println (str "hey look I got called"))
  (throw (Exception.)))

(defn cred-fn
  [creds]
  (another-fn))

А затем создайте подделку для новой функции в тесте, например:

(fact "login with incorrect username and password returns unauthenticated"
  (:status (post "/login" invalid-auth-account-json)) => 401
  (provided
    (auth/another-fn) => nil))

(fact "login with correct username and password returns success"
  (:status (post "/login" auth-account-json)) => 200
  (provided
    (auth/another-fn) => {:identity "root"}))

Я получаю результат, которого ожидал. cred-fn по-прежнему вызывается, но another-fn не вызывается из-за ошибки provided.

Если кто-нибудь знает, почему это так, мне было бы интересно узнать. Это может быть связано с тем, как вызывается функция учетных данных? - https://github.com/marianoguerra/friend-json-workflow/blob/master/src/marianoguerra/friend_json_workflow.clj#L46