Шаблон XSLT не применяется к вновь созданным элементам

Я использую XSLT 2.0. Внутри xsl:template (шаблона-1) я использую xsl:analyze-string для создания новых span элементов с атрибутом xml:lang. У меня есть второй шаблон (шаблон-2), который добавляет атрибут class к элементам, содержащим атрибут xml:lang. В моей таблице стилей вновь созданные элементы диапазона, созданные первым шаблоном, не обрабатываются вторым. Как я могу это исправить и заставить второй шаблон работать с результатами первого?

Пример:

Ввод: <p>The base form of a noun is technically called a <span xml:lang="sa-Latn">prātipadika</span> (प्रातिपदिक).</p>

Желаемый результат: <p>The base form of a noun is technically called a <span xml:lang="sa-Latn" class="lang-sa-latn">prātipadika</span> (<span xml:lang="sa-Deva" class="lang-sa-deva">प्रातिपदिक</span>).</p> Этот правильный результат имеет окончательный span с атрибутами xml:lang и class.

Вывод таблицы стилей: <p>The base form of a noun is technically called a <span xml:lang="sa-Latn" class="lang-sa-latn">prātipadika</span> (<span xml:lang="sa-Deva">प्रातिपदिक</span>).</p> Этот неправильный вывод отсутствует class="sa-lang-deva" в финальном span.

(Дополнительные классы, создаваемые таблицей стилей, помогают обойти недостаточную поддержку CSS в определенной программе для чтения электронных книг.)

Вот моя таблица стилей:

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="2.0"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns="http://www.w3.org/1999/xhtml"
                xpath-default-namespace="http://www.w3.org/1999/xhtml"
                xmlns:xml="http://www.w3.org/XML/1998/namespace"
                xmlns:epub="http://www.idpf.org/2007/ops">

    <xsl:output method="xhtml" encoding="utf-8" indent="no"/>

    <xsl:template match="/">
        <html xmlns="http://www.w3.org/1999/xhtml" xmlns:epub="http://www.idpf.org/2007/ops">
            <xsl:apply-templates/>
        </html>
    </xsl:template>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

    <!-- Template-1: Add xml:lang attribute to Devanagari text. -->
    <xsl:template match="element()/text()">
        <xsl:variable name="textValue" select="."/>
        <xsl:analyze-string select="$textValue" regex="([&#x0900;-&#x097f;]+)((\s+[&#x0900;-&#x097f;]+)*)">
            <xsl:matching-substring>
                <span xml:lang="sa-Deva"><xsl:value-of select="."/></span>
            </xsl:matching-substring>
            <xsl:non-matching-substring>
                <xsl:value-of select="."/>
            </xsl:non-matching-substring>
        </xsl:analyze-string>
    </xsl:template>

    <!-- Template-2: Add lang-* class attribute when xml:lang attribute present. -->
    <xsl:template match="*[@xml:lang]">
        <xsl:call-template name="addClass">
            <xsl:with-param name="newClass">lang-<xsl:value-of select="@xml:lang"/></xsl:with-param>
        </xsl:call-template>
    </xsl:template>

    <!-- Add a class attribute to an element. -->
    <xsl:template name="addClass">
        <xsl:param name="newClass"/>
        <xsl:copy>
            <xsl:copy-of select="@*"/>
            <xsl:attribute name="class"><xsl:value-of select="normalize-space(concat(@class, ' ', lower-case($newClass)))"/></xsl:attribute>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

</xsl:stylesheet>

xml xslt saxon xslt-2.0
person keithm    schedule 08.02.2015    source источник

Ответы (1)


arrow_upward
1
arrow_downward

Вам нужно будет захватить узлы, созданные analyze-string, в переменную, а затем применить к ним шаблоны. Вы можете использовать режимы шаблона, чтобы избежать бесконечной рекурсии.

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="2.0"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns="http://www.w3.org/1999/xhtml"
                xpath-default-namespace="http://www.w3.org/1999/xhtml"
                xmlns:xml="http://www.w3.org/XML/1998/namespace"
                xmlns:epub="http://www.idpf.org/2007/ops">

    <xsl:output method="xhtml" encoding="utf-8" indent="no"/>

    <xsl:template match="/">
        <html xmlns="http://www.w3.org/1999/xhtml" xmlns:epub="http://www.idpf.org/2007/ops">
            <xsl:apply-templates/>
        </html>
    </xsl:template>

    <xsl:template match="@*|node()" mode="#all">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()" mode="#current"/>
        </xsl:copy>
    </xsl:template>

    <!-- Template-1: Add xml:lang attribute to Devanagari text. Note no
         mode attribute, so only applies in default mode. -->
    <xsl:template match="text()">
        <xsl:variable name="textValue" select="."/>
        <xsl:variable name="nodes" as="node()*">
            <xsl:analyze-string select="$textValue" regex="([&#x0900;-&#x097f;]+)((\s+[&#x0900;-&#x097f;]+)*)">
                <xsl:matching-substring>
                    <span xml:lang="sa-Deva"><xsl:value-of select="."/></span>
                </xsl:matching-substring>
                <xsl:non-matching-substring>
                    <xsl:value-of select="."/>
                </xsl:non-matching-substring>
            </xsl:analyze-string>
        </xsl:variable>
        <!-- apply templates to generated nodes, but with a mode that stops
             this template from firing again -->
        <xsl:apply-templates select="$nodes" mode="no-deva" />
    </xsl:template>

    <!-- Template-2: Add lang-* class attribute when xml:lang attribute present. -->
    <xsl:template match="*[@xml:lang]" mode="#all">
        <xsl:call-template name="addClass">
            <xsl:with-param name="newClass">lang-<xsl:value-of select="@xml:lang"/></xsl:with-param>
        </xsl:call-template>
    </xsl:template>

    <!-- Add a class attribute to an element. -->
    <xsl:template name="addClass">
        <xsl:param name="newClass"/>
        <xsl:copy>
            <xsl:copy-of select="@*"/>
            <xsl:attribute name="class"><xsl:value-of select="normalize-space(concat(@class, ' ', lower-case($newClass)))"/></xsl:attribute>
            <xsl:apply-templates select="@*|node()" mode="#current"/>
        </xsl:copy>
    </xsl:template>

</xsl:stylesheet>

Рабочий пример

В исходный XSLT я внес следующие изменения:

  • добавил mode="#all" к шаблону удостоверения и "шаблон 2", чтобы они применялись во всех режимах, и добавил mode="#current" к соответствующим apply-templates инструкциям, чтобы они рекурсивно повторялись с использованием любого текущего режима.
  • окружил analyze-string <xsl:variable>, чтобы захватить узел (ы), которые он генерирует.
  • apply-templates к этим узлам в другом режиме

Поскольку я (намеренно) не добавил mode="#all" в шаблон 1, он соответствует только во время начального прохода, а не во время apply-templates mode="no-deva".

person Ian Roberts    schedule 08.02.2015
comment
Это прекрасно работает! Спасибо. Я не думал о захвате узлов таким образом. Поучительно и то, как вы настраиваете режимы. - person keithm; 09.02.2015