Могут ли файлы классов Java использовать зарезервированные ключевые слова в качестве имен?

Единственные ограничения на имена классов на уровне байт-кода заключаются в том, что они не могут содержать символы [, . или ; и их длина не может превышать 65535 байт. Помимо прочего, это означает, что вы можете свободно использовать зарезервированные слова, пробелы, специальные символы, Unicode или даже странные вещи, такие как символы новой строки.

Теоретически вы даже можете использовать нулевые символы в имени класса, но поскольку нулевой символ в имени файла быть не может, вы не можете включить такой файл класса в банку. Однако вы можете создать и загрузить его динамически.

Вот пример того, что вы можете сделать (написано на ассемблере Krakatau):

; Entry point for the jar
.class Main
.super java/lang/Object

.method public static main : ([Ljava/lang/String;)V
    .limit stack 10
    .limit locals 10
    invokestatic int                                hello ()V
    invokestatic "-42"                              hello ()V
    invokestatic ""                                 hello ()V
    invokestatic "  some  whitespace and \t tabs"   hello ()V
    invokestatic "new\nline"                        hello ()V
    invokestatic 'name with "Quotes" in it'         hello ()V
    return
.end method
.end class


.class int
.super java/lang/Object
.method public static hello : ()V
    .limit stack 2
    .limit locals 0
    getstatic java/lang/System out Ljava/io/PrintStream;
    ldc "Hello from int"
    invokevirtual java/io/PrintStream println (Ljava/lang/Object;)V
    return
.end method
.end class

.class "-42"
.super java/lang/Object
.method public static hello : ()V
    .limit stack 2
    .limit locals 0
    getstatic java/lang/System out Ljava/io/PrintStream;
    ldc "Hello from -42"
    invokevirtual java/io/PrintStream println (Ljava/lang/Object;)V
    return
.end method
.end class

; Even the empty string can be a class name!
.class ""
.super java/lang/Object
.method public static hello : ()V
    .limit stack 2
    .limit locals 0
    getstatic java/lang/System out Ljava/io/PrintStream;
    ldc "Hello from "
    invokevirtual java/io/PrintStream println (Ljava/lang/Object;)V
    return
.end method
.end class

.class "  some  whitespace and \t tabs"
.super java/lang/Object
.method public static hello : ()V
    .limit stack 2
    .limit locals 0
    getstatic java/lang/System out Ljava/io/PrintStream;
    ldc "Hello from   some  whitespace and \t tabs"
    invokevirtual java/io/PrintStream println (Ljava/lang/Object;)V
    return
.end method
.end class

.class "new\nline"
.super java/lang/Object
.method public static hello : ()V
    .limit stack 2
    .limit locals 0
    getstatic java/lang/System out Ljava/io/PrintStream;
    ldc "Hello from new\nline"
    invokevirtual java/io/PrintStream println (Ljava/lang/Object;)V
    return
.end method
.end class

.class 'name with "Quotes" in it'
.super java/lang/Object
.method public static hello : ()V
    .limit stack 2
    .limit locals 0
    getstatic java/lang/System out Ljava/io/PrintStream;
    ldc "Hello from name with \"Quotes\" in it"
    invokevirtual java/io/PrintStream println (Ljava/lang/Object;)V
    return
.end method
.end class

Вывод выполнения:

Hello from int
Hello from -42
Hello from
Hello from   some  whitespace and        tabs
Hello from new
line
Hello from name with "Quotes" in it

См. ответ Хольгера для точной цитаты правил из спецификации JVM.

Да, вы можете использовать зарезервированные слова. Слова предназначены только для компилятора. Они не появляются в сгенерированном байтовом коде.

Пример использования зарезервированных слов Java находится в языке Scala на основе JVM. Scala имеет другие конструкции и синтаксис, чем Java, но компилируется в байт-код Java для работы на JVM.

Это легальная Scala:

class `class`

Это определяет класс с именем class с конструктором без аргументов. Запуск javap (дизассемблера) на скомпилированном файле class.class показывает

public class class {
    public class();
}

Scala может сделать то же самое с любым другим зарезервированным словом Java.

class int
class `while`
class goto

Их также можно использовать для имен методов или полей.

Как вы и подозревали, вы не сможете использовать эти классы из Java, кроме отражения. Вы можете использовать их из аналогично "настраиваемого" файла класса, например. из файла класса, созданного компилятором Scala.

Таким образом, это ограничение javac (компилятора), а не java (среда VM/runtime).

Ограничения на имена зафиксированы в спецификации JVM:

§4.2.1. Имена двоичных классов и интерфейсов

Имена классов и интерфейсов, которые появляются в структурах файлов классов, всегда представлены в полностью определенной форме, известной как двоичные имена (JLS §13.1). Такие имена всегда представлены в виде структур CONSTANT_Utf8_info (§4.4.7) и, таким образом, могут быть получены, если нет дополнительных ограничений, из всего кодового пространства Unicode…

По историческим причинам синтаксис двоичных имен, которые появляются в структурах файлов классов, отличается от синтаксиса двоичных имен, описанных в JLS §13.1. В этой внутренней форме точки ASCII (.), которые обычно разделяют идентификаторы, составляющие двоичное имя, заменяются косой чертой ASCII (/). Сами идентификаторы должны быть неквалифицированными именами (§4.2.2).

§4.2.2. Неполные имена

Имена методов, полей, локальных переменных и формальных параметров хранятся как неполные имена. Неполное имя должно содержать по крайней мере одну кодовую точку Unicode и не должно содержать никаких символов ASCII . ; [ / (то есть точки, точки с запятой, левой квадратной скобки или косой черты).

Имена методов имеют дополнительные ограничения, поэтому, за исключением имен специальных методов <init> и <clinit> (§2.9), они не должны содержать символы ASCII < или > (то есть левая угловая скобка или правая угловая скобка).

Итак, ответ таков: есть лишь несколько символов, которые нельзя использовать на двоичном уровне. Во-первых, / — это разделитель пакетов. Затем нельзя использовать ; и [, поскольку они имеют особое значение в подписи полей и метод подписи, которые могут содержать имена типов. В этих подписях [ начинает тип массива, а ; отмечает конец имени ссылочного типа.

Нет четкой причины, по которой . запрещен. Он не используется в JVM и имеет значение только в пределах общие подписи, но если вы используете общие подписи, имена типов дополнительно ограничиваются тем, что им не разрешено содержать <, >, :, а также эти символы имеют особое значение внутри общие подписи тоже.

Следовательно, нарушение спецификации путем использования . в идентификаторах не влияет на основную функцию JVM. Обфускаторы это делают. Полученный код работает, но вы можете столкнуться с проблемами с Reflection при запросе подписей универсального типа. Кроме того, преобразование двоичных имен в исходное имя путем замены всех /s на .s станет необратимым, если двоичное имя содержит .s.

Интересно, что было предложение поддерживать все возможные идентификаторы в синтаксисе Java (см. пункт 3, «экзотические идентификаторы»), но в финальную версию Java 7 он не попал. И, похоже, сейчас никто не предпринимает новых попыток его внедрить.

Существует дополнительное техническое ограничение: имена не могут иметь Измененное представление UTF-8 длиннее 65 535 байт, поскольку число байтов хранится как беззнаковое короткое значение.

1. Ключевые слова известны только компилятору. Компилятор переводит их в адекватный байт-код. Таким образом, они не существуют во время выполнения скомпилированного байт-кода и, следовательно, не проверяются JVM.
2. Конечно, вы не можете получить доступ к членам класса, неизвестным во время компиляции. Но вы можете использовать рефлексию для этой цели, если вы уверены, что такой член класса будет существовать в скомпилированном коде (вы будете «творить» их там), потому что доступ по рефлексии не проверяется компилятором.