Пакетный файл - Как использовать FindStr с процентами

Да, требуется еще один уровень побега, потому что каждая сторона конвейера выполняется через CMD /C с контекстом командной строки, а не пакетным контекстом. Начальный пакетный синтаксический анализатор преобразует %%SOME_VAR%% в %SOME_VAR%. Затем синтаксический анализатор командной строки оставляет %SOME_VAR% как есть, если переменная не определена. Нам нужно предотвратить расширение, если переменная определена. Удвоение процентов не работает в контексте командной строки. Решение состоит в том, чтобы вставить исчезающую точку вставки где-то между процентами, например %^SOME_VAR%. Знак вставки рассматривается как часть имени переменной, поэтому он предотвращает расширение переменной (если только у вас нет переменной с именем ^SOME_VAR). После неудачного развертывания каретка поглощается обычным процессом выхода. Символ вставки должен быть экранирован, чтобы пакетный синтаксический анализатор передал символ вставки в контекст командной строки CMD /C.

Окончательная линия партии становится:

Echo %%^^SOME_VAR%% | FindStr SOME_VAR

Примечание. Я упростил команду FINDSTR до гораздо более простого, но эквивалентного поиска.

Когда вы изменяете поиск справа, чтобы включить проценты, вам также нужно будет вставить экранированный знак вставки.

Обновление в ответ на вопрос в комментарии
Следующий код демонстрирует некоторые возможные способы работы с переменными:

@echo off
setlocal disableDelayedExpansion

:: Put both the text you want to search, as well as the search itself, in variables
set "text=%%SOME_VAR%%;C:\Windows\system32...................etc"
set "search=%%SOME_VAR%%"
echo text=%text%
echo search=%search%
echo(

echo(
echo Starting with delayed expansion disabled
echo -----------------------------------------
echo(

:: Use delayed expansion to safely expand any variable without worrying about content.
:: Both sides of the pipe are executed in a command line context with delayed expansion disabled.
:: You must use CMD /V:ON to enable delayed expansion within the pipe.

echo Test when SOME_VAR is undefined:
set "SOME_VAR="
if 1==1 (
  cmd /v:on /c echo !text!|cmd /v:on /c findstr "!search!"
)
echo(

echo Test when SOME_VAR is defined:
set "SOME_VAR=DEFINED"
if 1==1 (
  cmd /v:on /c echo !text!|cmd /v:on /c findstr "!search!"
)
echo(


setlocal enableDelayedExpansion
echo(
echo(
echo Now try with delayed expansion enabled
echo -----------------------------------------
echo(

:: Even though delayed expansion is enabled within the batch script, it is still disabled
:: within the pipe, so we still have to explicitly enable it via CMD /V:ON.
:: But now we must prevent expansion of the variables while in the batch context.
:: You have two options:

:: 1) Escape the !. The escape syntax changes depending on whether it is inside quotes or not:
echo Escape test:
if 1==1 (
  cmd /v:on /c echo ^^!text^^!|cmd /v:on /c findstr "^!search^!"
)
echo(

:: 2) Enclose both sides of the pipe within parentheses (very weird, but it works)
echo Parentheses test:
if 1==1 (
  (cmd /v:on /c echo !text!)|(cmd /v:on /c findstr "!search!")
)

--ВЫХОД--

text=%SOME_VAR%;C:\Windows\system32...................etc
search=%SOME_VAR%


Starting with delayed expansion disabled
-----------------------------------------

Test when SOME_VAR is undefined:
%SOME_VAR%;C:\Windows\system32...................etc

Test when SOME_VAR is defined:
%SOME_VAR%;C:\Windows\system32...................etc



Now try with delayed expansion enabled
-----------------------------------------

Escape test:
%SOME_VAR%;C:\Windows\system32...................etc

Parentheses test:
%SOME_VAR%;C:\Windows\system32...................etc