Метод отправки MSXML2.XMLHTTP работает с ранним связыванием, не работает с поздним связыванием

Код ниже работает. Но если я закомментирую строку Dim objRequest As MSXML2.XMLHTTP и раскомментирую строку Dim objRequest As Object, появится сообщение об ошибке:

Неверный параметр

Почему и что (если что) я могу с этим поделать?

Public Function GetSessionId(strApiId, strUserName, strPassword) As String

    Dim strPostData As String

    Dim objRequest As MSXML2.XMLHTTP
    'Dim objRequest As Object '

    strPostData = "api_id=" & strApiId & "&user=" & strUserName & "&password=" & strPassword

    Set objRequest = New MSXML2.XMLHTTP
    With objRequest
        .Open "POST", "https://api.clickatell.com/http/auth", False
        .setRequestHeader "Content-Type", "application/x-www-form-urlencoded"
        .send strPostData
        GetSessionId = .responseText
    End With

End Function

Кори, да, я знаю, что мне придется это сделать, чтобы мой код работал без ссылки на библиотеку типов MSXML. Здесь проблема не в этом. Код не работает при использовании Dim objRequest As Object независимо от того, использую ли я

Set objRequest = NEW MSXML2.XMLHTTP со ссылкой, или

Set objRequest = CreateObject("MSXML2.XMLHTTP") без ссылки.


http xmlhttprequest vba msxml
person Brendan Reynolds    schedule 21.11.2008    source источник

Ответы (3)


arrow_upward
18
arrow_downward

Почему-то это работает:

Dim strPostData As String
Dim objRequest As Object

strPostData = "api_id=" & strApiId & "&user=" & strUserName & "&password=" & strPassword

Set objRequest = New MSXML2.XMLHTTP
With objRequest
  .Open "POST", "https://api.clickatell.com/http/auth", False
  .setRequestHeader "Content-Type", "application/x-www-form-urlencoded"
  .send (strPostData)
   GetSessionId = .responseText
End With

Вместо создания URL-кодированного strPostData путем конкатенации строк настоятельно рекомендуется использовать функцию кодирования URL-адресов:

strPostData = "api_id=" & URLEncode(strApiId) & _
              "&user=" & URLEncode(strUserName) & _
              "&password=" & URLEncode(strPassword)

В этом потоке есть несколько вариантов для функции URLEncode() в VBA: Как можно URL-адрес закодировать строку в Excel VBA?

person Tomalak    schedule 21.11.2008
comment
Очень странно, что решением было добавить парафениз к .send (strPostData). Но я только что подтвердил, что это действительно так. - person b.roth; 09.08.2010
comment
@Bruno: Спасибо за подтверждение. Я убежден, что этому есть вполне логическое объяснение, где-то в глубинах VBA или взаимодействия VBA-COM в целом или библиотеки MSXML2.XMLHTTP в частности, но я понятия не имею. Я уверен, что @Eric Lippert сможет объяснить. ;) - person Tomalak; 09.08.2010
comment
Добавление круглых скобок вокруг strPostData принудительно передает его по значению. Я предполагал, что вы сделаете это только в том случае, если вам нужно защитить свою локальную переменную от возможного изменения вызываемой процедурой. Я не уверен, почему в результате сам метод ведет себя иначе. Для получения дополнительной информации см. Здесь: stackoverflow.com/questions/ 1070863 / - person mwolfe02; 01.11.2010
comment
@ mwolfe02: Отлично, спасибо за объяснение, это имеет смысл с точки зрения VB. Я предполагаю, что это либо вызывает другой перегруженный метод send() с библиотекой XMLHTTP, либо это может иметь какое-то отношение к различиям в буферизации внутренней строки параметров ByVal и ByRef. - person Tomalak; 02.11.2010
comment
@Henrik Если вы также используете это для POST-данных, как в примере кода выше, проверьте только что сделанное мной обновление ответа. - person Tomalak; 22.05.2017
comment
Я использую его для любого метода, на этот раз именно GET выдает ошибку отправки XMLHTTP. На самом деле, я не заметил, что вы изменили сейчас. И когда я нашел его, было трудно увидеть разницу в коде Брендана. Я различал их глазами :) Думаю, ответ мог бы быть более ясным, если бы вы сказали: «По какой-то причине просто заключить параметр в круглые скобки работает» или что-то подобное. Ваше здоровье! - person Henrik Erlandsson; 23.05.2017
comment
@Henrik Вы всегда можете просмотреть все редакции сообщения в StackOverflow, щелкнув ссылку отредактировано {date} под ним. В этом случае я добавил подсказку о данных кодирования URL в VBA. - person Tomalak; 23.05.2017

arrow_upward
3
arrow_downward

Если вы используете Dim objRequest As Object, вам потребуется код:
Установите objRequest = CreateObject ("MSXML2.XMLHTTP")

person Corey Trager    schedule 21.11.2008
comment
Вы сообщаете, выпуская New MSXML2.XMLHTTP. Для меня работают оба способа. - person Tomalak; 21.11.2008

arrow_upward
0
arrow_downward

Я понимаю, что это почти идентично коду из приведенного выше Томалека (вся заслуга вам!), Но этот вопрос помог мне найти полное решение возникшей у меня проблемы (отправка Excel на сервер PHP, а затем обработка ответа) ... так что, если это кому-то поможет:

Sub Button1_Click2()

Dim objXMLSendDoc As Object
Set objXMLSendDoc = New MSXML2.DOMDocument
objXMLSendDoc.async = False
Dim myxml As String
myxml = "<?xml version='1.0'?><Request>Do Something</Request>"
If Not objXMLSendDoc.LoadXML(myxml) Then
    Err.Raise objXMLSendDoc.parseError.ErrorCode, , objXMLSendDoc.parseError.reason
End If

Dim objRequest As MSXML2.XMLHTTP
Set objRequest = New MSXML2.XMLHTTP
With objRequest
    .Open "POST", "http://localhost/SISADraftCalcs/Test2.php", False
    .setRequestHeader "Content-Type", "application/xml;charset=UTF-16"
    .setRequestHeader "Cache-Control", "no-cache"
    .send objXMLSendDoc
End With

Dim objXMLDoc As MSXML2.DOMDocument
Set objXMLDoc = objRequest.responseXML
If objXMLDoc.XML = "" Then
    objXMLDoc.LoadXML objRequest.responseText
    If objXMLDoc.parseError.ErrorCode <> 0 Then
        MsgBox objXMLDoc.parseError.reason
    End If
End If

Dim rootNode As IXMLDOMElement
Set rootNode = objXMLDoc.DocumentElement

MsgBox rootNode.SelectNodes("text").Item(0).text

End Sub
person Alistair Collins    schedule 22.02.2010