Разрабатывайте с помощью Heredis для Windows

После множества поисков и попыток я предлагаю этот метод с использованием CMake, хотя информацию можно использовать и для сборки с другими системами сборки.

Возьмите проект Microsoft redis с открытым исходным кодом и откройте файл проекта msvs\RedisServer.sln

Соберите проект в нужной конфигурации (отладка, выпуск,...)

Создайте переменную среды с именем hiredis_ROOT (Панель управления->Система->Дополнительные параметры системы->Переменные среды) и установите ее значение в извлеченную папку redis.

Создайте модуль поиска cmake с содержимым, указанным ниже, и поместите его в корень проекта в папку cmake с именем Findhiredis.cmake.

# set search hint directories
set(
     hiredis_POSSIBLE_ROOT_PATHS
     $ENV{hiredis_ROOT}
     /usr/local
     /usr
)


# find hiredis include directory
# =================================================================================

find_path(
  hiredis_INCLUDE_DIR
  NAME          hiredis/hiredis.h
  HINTS         ${hiredis_POSSIBLE_ROOT_PATHS}
  PATH_SUFFIXES "include" "deps"
)

if(NOT hiredis_INCLUDE_DIR)
  message(STATUS "Checking for hiredis... no")
  message(STATUS "Could not find include path for hiredis, try setting hiredis_ROOT")
  return()
endif()


# find hiredis library
# =================================================================================

# library for debug builds
find_library(
  hiredis_LIBRARY_DEBUG
  NAMES          hiredis
  HINTS          ${hiredis_POSSIBLE_ROOT_PATHS}
  PATH_SUFFIXES  "msvs/x64/Debug"
  DOC            "hiredis library for debug builds"
)

# library for release builds
find_library(
  hiredis_LIBRARY_RELEASE
  NAMES          hiredis
  HINTS          ${hiredis_POSSIBLE_ROOT_PATHS}
  PATH_SUFFIXES  "msvs/x64/Release"
  DOC            "hiredis library for release builds"
)

# create library name for linking
set(hiredis_LIBRARY "")
if(hiredis_LIBRARY_DEBUG AND hiredis_LIBRARY_RELEASE)
  set(hiredis_LIBRARY "optimized;${hiredis_LIBRARY_RELEASE};debug;${hiredis_LIBRARY_DEBUG}")
elseif(hiredis_LIBRARY_DEBUG)
  set(hiredis_LIBRARY "${hiredis_LIBRARY_DEBUG}")
elseif(hiredis_LIBRARY_RELEASE)
  set(hiredis_LIBRARY "${hiredis_LIBRARY_RELEASE}")
endif()

# check the result
if(NOT hiredis_LIBRARY)
  message(STATUS "Checking for hiredis... no")
  message(STATUS "hiredis include directory: ${hiredis_INCLUDE_DIR}")
  message(STATUS "Could not find hiredis library")
  return()
endif()


# find hiredis' interop library
# =================================================================================

find_library(
  hiredis_interop_LIBRARY_DEBUG
  NAMES          Win32_Interop
  HINTS          ${hiredis_POSSIBLE_ROOT_PATHS}
  PATH_SUFFIXES  "msvs/x64/Debug"
  DOC            "Windows modified interop library for debug builds"
)

find_library(
  hiredis_interop_LIBRARY_RELEASE
  NAMES          Win32_Interop
  HINTS          ${hiredis_POSSIBLE_ROOT_PATHS}
  PATH_SUFFIXES  "msvs/x64/Release"
  DOC            "Windows modified interop library for release builds"
)

set(hiredis_interop_LIBRARY "")
if(hiredis_interop_LIBRARY_DEBUG AND hiredis_interop_LIBRARY_RELEASE)
  set(hiredis_interop_LIBRARY "optimized;${hiredis_interop_LIBRARY_RELEASE};debug;${hiredis_interop_LIBRARY_DEBUG}")
elseif(hiredis_interop_LIBRARY_DEBUG)
  set(hiredis_interop_LIBRARY "${hiredis_interop_LIBRARY_DEBUG}")
elseif(hiredis_interop_LIBRARY_RELEASE)
  set(hiredis_interop_LIBRARY "${hiredis_interop_LIBRARY_RELEASE}")
endif()

# check the result
if(NOT hiredis_interop_LIBRARY)
  message(STATUS "Checking for hiredis' interop... no")
  message(STATUS "hiredis include directory: ${hiredis_INCLUDE_DIR}")
  message(STATUS "Could not find hiredis interop library")
  return()
endif()


# Sum up libraries
# =================================================================================

set(Ws2_32_LIBRARY "optimized;Ws2_32;debug;Ws2_32")
set(
    hiredis_LIBRARIES

    ${hiredis_LIBRARY}
    ${hiredis_interop_LIBRARY}
    ${Ws2_32_LIBRARY}
)


# everything is found. just finish up
# =================================================================================

set(hiredis_FOUND TRUE CACHE BOOL "Whether hiredis is found on the system or not")
set(hiredis_INCLUDE_DIR ${hiredis_INCLUDE_DIR} CACHE PATH "hiredis include directory")
set(hiredis_LIBRARIES ${hiredis_LIBRARIES} CACHE FILEPATH "hiredis library for linking against")

message(STATUS "Checking for hiredis... yes")

включите модуль поиска на верхнем уровне CMakeLists.txt с помощью этой команды:

set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_SOURCE_DIR}/cmake")
find_package(hiredis REQUIRED)

Установите пользовательские определения, включите пути и библиотеки ссылок в свой проект cmake:

set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /D_CRT_SECURE_NO_WARNINGS")
set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} /MTd")
set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} /MT")
include_directories(${hiredis_INCLUDE_DIR})
target_link_libraries(my-redis-application ${hiredis_LIBRARIES})

Вот и все. И вы сделали.

Могу предложить альтернативную библиотеку cpp bredis: она не использует официальный парсер redis (hiredis библиотека) , поэтому он прекрасно компилируется в Windows (c++ 14).