Как использовать переменную в качестве модификатора в подстановке

Хм, если бы мне пришлось это сделать, я бы сделал так:

use warnings;
use strict;
my @stuff = (
{
    search => "this",
    replace => "that",
    modifier => "g",
},
{
    search => "ono",
    replace => "wendy",
    modifier => "i",
}
);
$_ = "this ono boo this\n";
for my $h (@stuff) {
    if ($h->{modifier} eq 'g') {
        s/$h->{search}/$h->{replace}/g;
    } elsif ($h->{modifier} eq 'i') {
        s/$h->{search}/$h->{replace}/i;
    }
    # etc.
}
print;

Есть очень много разных модификаторов, которые вы можете использовать, поэтому я думаю, что это достаточно просто.

Вы можете использовать eval для этого, но это ужасно беспорядочно.

Хотя метод, использующий eval для компиляции новой замены, вероятно, является наиболее простым, вы можете создать более модульную замену:

use warnings;
use strict;

sub subst {
    my ($search, $replace, $mod) = @_;

    if (my $eval = $mod =~ s/e//g) {
        $replace = qq{'$replace'};
        $replace = "eval($replace)" for 1 .. $eval;
    } else {
        $replace = qq{"$replace"};
    }
    sub {s/(?$mod)$search/$replace/ee}
}

my $sub = subst '(abc)', 'uc $1', 'ise';

local $_ = "my Abc string";

$sub->();

print "$_\n";  # prints "my ABC string"

Это только слегка проверено, и читателю предоставляется в качестве упражнения реализовать другие флаги, такие как g

Вы можете использовать eval, если наденете защитные очки и костюм деления на ноль.

E.g.:

use strict;
use warnings;
sub mk_re {
  my ($search, $replace, $modifier) = @_;
  $modifier ||= '';
  die "Bad modifier $modifier" unless $modifier =~ /^[msixge]*$/;
  my $sub = eval "sub { s/($search)/$replace/$modifier; }";
  die "Error making regex for [$search][$replace][$modifier]: $@" unless $sub;
  return $sub;
}

my $search = 'looking';
my $replace = '"find: $1 ="';
my $modifier = 'e';

# Sub can be stored in an array or hash
my $sub = mk_re($search, $replace, $modifier);

$_ = "abc-looking-def";
print "$_\n";
$sub->();
print "$_\n";

Конечно s/$search/$replace/ работает, как вы ожидаете. Это не простые динамические модификаторы.

Для обычного соответствия модификаторам pimsx вы можете использовать Perl Extended Patterns, чтобы на лету изменять флаги модификаторов как часть вашего шаблона. Они имеют форму (?pimsx-imsx) для включения / выключения этих модификаторов.

Для форм s// e и ee вы можете использовать (?{ perl code}), описанные в том же разделе perlre. Для всех форм eval e или ee учитывайте безопасность полученного кода!

Мне известно, что нет формы для изменения глобального совпадения на первое совпадение, поэтому глобальное и первое совпадение должно быть отдельными операторами.

Вот комбинация ответа Кинопико и eval.

eval используется здесь для создания таблицы поиска управляемым и поддерживаемым способом, а таблица поиска используется для сохранения всех if .. elsif .. elsif, на которые не слишком интересно смотреть.

(очень легко протестировано)

my @stuff = (
{
    search => "this",
    replace => "that",
    modifier => "g",
},
{
    search => "ono",
    replace => "wendy",
    modifier => "i",
}
);
$_ = "this ono boo this\n";

my @modifiers = qw{m s i x g e};

my $s_lookup = {};

foreach my $modifier (@modifiers) { 
    $s_lookup->{$modifier} =  eval " sub { s/\$_[0]/\$_[1]/$modifier } ";
}

for my $h (@stuff) {
    $s_lookup->{$h->{modifier}}->($h->{search},$h->{replace});
}

print; 

Чтобы быть полностью полезным, необходимо:

1. комбинации возможных модификаторов
2. функция сортировки в поисковой таблице, чтобы комбинация «msi» и «mis» попадала на один и тот же ключ.