Как перечислить все предикаты, имеющие определенный атом?

вот моя попытка, используя SWI-Prolog

?- current_predicate(so:F/N), N>0, length(As,N), Head =.. [F|As], clause(so:Head,Body), As=[A|_], A==agora.

обратите внимание, что я закодировал в модуле имя так факты, поэтому я уточняю с помощью имени модуля соответствующие вызовы. Такие встроенные функции (пункт/2 и current_predicate/1) совместимы с ISO, а модули (в SWI-prolog) - нет. Так что я не уверен в переносимости и т.д.

пункт/2 — это встроенная функция, позволяющая легко писать метаинтерпретации. См. ссылку для потрясающего введения в эту историческую «сильную сторону» Пролога.

Два последних вызова (я имею в виду As=[A|_], A==agora) избегают сопоставления предложений, имеющих переменную в качестве первого аргумента.

Я нашел два решения, второе, на мой взгляд, чище, но они разные.

Параметры:

• PredName: имя предиката.
• Arity: Arity предиката.
• ParamValue: если я хочу фильтровать по одному конкретному параметру.
• PosParam: позиция параметра в предикате.
• ListParam: все значения параметров posibles values ​​(всегда должны быть переменными).

Решение 1:

filter_predicate(PredName, Arity, ParamValue,PosParam, ListParam):-
    current_predicate(PredName/Arity),
    Arity >= PosParam,
    nth(PosParam, ListParam, ParamValue),
    append([PredName], ListParam, PredList),
    GlobalArity is Arity + 1,
    length(PredList, GlobalArity),
    Predicate =.. PredList,
    Predicate.

Запрос

filter_predicate(PredName, Arity, agora, 1, Pm).

Вывод

Arity = 2                                                                              
Pm = [agora,'Alejandro Amenabar']
PredName = director ? 

yes

Решение 2:

filter_predicate(PredName, Arity, ParamList):-
    current_predicate(PredName/Arity),
    append([PredName], ParamList, PredList), 
    GlobalArity is Arity + 1,
    length(PredList, GlobalArity),
    Predicate =.. PredList,
    Predicate.

Запрос 1:

filter_predicate(PredName, Arity, [agora, X]).

Вывод

Arity = 2
PredName = director
X = 'Alejandro Amenabar' ? 

Запрос 2:

filter_predicate(PredName, Arity, [X, 'Alejandro Amenabar']).

Вывод

Arity = 2
PredName = director
X = agora ? 

Использование чтения строк в списки с прологом

Все ваши предикаты находятся в файле my_file.pl.

например my_file.pl содержит:

movie(agora).
director(agora, 'Alejandro Amenabar').
duration(agora, '2h').

Вы можете использовать:

getLines(File,L):-
 setup_call_cleanup(
 open(File, read, In),
 readData(In, L),
 close(In)
 ).

readData(In, L):-
  read_term(In, H, []),
  (   H == end_of_file
  ->  L = []
  ;   L = [H|T],
      readData(In,T)
  ).


pred_arg_file(Pred,Argue,File):-
  getLines(File,L),
  member(M,L),
  M=..List,
  member(Argue,List),
  List=[Pred|_].

Затем вы можете запросить:

 ?-pred_arg_file(Pred,agora,'my_file.pl').
 Pred = movie ;
 Pred = director ;
 Pred = duration ;
 false

or

?- findall(Pred,pred_arg_file(Pred,agora,'my_file.pl'),Preds).
Preds = [movie,director,duration].

Если вы хотите вернуть свойства, верните весь список, а не только заголовок.

pred_arg_file(List,Argue,File):-
  getLines(File,L),
  member(M,L),
  M=..List,
  member(Argue,List).

Насколько я понимаю, вы должны изменить представление данных, чтобы вы могли запрашивать отношения. Как указывалось в других ответах, поэтому используйте тройки, вы можете легко написать код, чтобы изменить все ваши отношения в эту форму как единое целое. Затем вам нужно решить, как лучше всего хранить лайки и антипатии. Это повлияет на то, как работает отрицание. В этом примере:

relation(starwars,is,movie).
relation(lucas, directs,starwars).
relation(agora, is,movie).
relation('Alejandro Amenabar', directs, agora).
relation(agora, duration, '2h').

like(ma,'Alejandro Amenabar').
like(ma,movie).
like(ma,'2h').

ma_does_not_want_to_go(Film):-
  relation(Film,is,movie),
  relation(Film,_,Test), \+like(ma,Test).
ma_does_not_want_to_go(Film):-
  relation(Film,is,movie),
  relation(Test,_,Film), \+like(ma,Test).

ma_wants_to_go(Film):-
  relation(Film,is,movie),
  \+ma_does_not_want_to_go(Film).

sa_invites_ma(Film,true):-
  ma_wants_to_go(Film).

sa_invites_ma(Film,false):-
  ma_does_not_want_to_go(Film).

Черновик решения, использующего Logtalk с GNU Prolog в качестве внутреннего компилятора:

% a movie protocol
:- protocol(movie).

    :- public([
        director/1,
        duration/1,
        genre/1
    ]).

:- end_protocol.


% a real movie
:- object('Agora',
    implements(movie)).

    director('Alejandro Amenabar').
    duration(120).
    genre(drama).

:- end_object.


% another real movie
:- object('The Terminator',
    implements(movie)).

    director('James Cameron').
    duration(112).
    genre(syfy).

:- end_object.


% a prototype person
:- object(person).

    :- public([
        likes_director/1,
        likes_genre/1
    ]).

    :- public(likes/1).
    likes(Movie) :-
        conforms_to_protocol(Movie, movie),
        (   Movie::genre(Genre),
            ::likes_genre(Genre) ->
            true
        ;   Movie::director(Director),
            ::likes_director(Director) ->
            true
        ;   fail
        ).

:- end_object.


% a real person
:- object(mauricio,
    extends(person)).

    likes_director('Ridlye Scott').

    likes_genre(drama).
    likes_genre(syfy).

:- end_object.

Некоторые примеры запросов:

$ gplgt
...

| ?- {movies}.
...

(5 ms) yes
| ?- mauricio::likes('Agora').

true ? 

yes
| ?- mauricio::likes(Movie).  

Movie = 'Agora' ? ;

Movie = 'The Terminator' ? ;

no

| ?- 'The Terminator'::director(Director).

Director = 'James Cameron'

yes

Код можно улучшить несколькими способами, но этого должно быть достаточно, чтобы дать вам четкое представление о том, как оценить это решение.

Если я правильно понял ваш вопрос, то предлагаю следующее:

Что, если вы измените свою схему или, следуя этой идее, вы можете создать метод, который имитирует то же самое.

class(movie, agora).
property(director, agora, 'Alejandro Amenabar').
property(duration, agora, '2h').

Если вам нужны типы агор, запрос будет таким:

class(Type, agora)

Если вам нужны все свойства агоры, это будет:

property( PropertyName, agora, Value).