Копирование внешней конфигурации по умолчанию при первом запуске веб-приложения Grails

Для этого есть лучшая практика.

В общем, никогда не пишите в папку, где развернуто приложение. Вы не имеете над ним контроля. Следующий выпуск удалит все, что вы там написали.

Вместо этого используйте встроенные возможности конфигурации, которые используют настоящие профессионалы (Spring и/или JPA).

JNDI является нормой для поиска ресурсов, таких как базы данных, файлы и URL-адреса.

Операции должны будут настроить JNDI, но они ценят внимание.

Им также необходим начальный набор файлов конфигурации, и они должны быть готовы вносить изменения время от времени по требованию команды разработчиков.

Как всегда, все файлы конфигурации должны находиться в вашем репозитории с исходным кодом.

Наконец-то мне удалось решить эту проблему самостоятельно, используя способность Java находить ресурсы, размещенные в пути к классам.

Я взял файлы .groovy позже, чтобы скопировать их наружу, поместил их в каталог grails-app/conf (который находится в пути к классам) и добавил суффикс к их имени, чтобы они не компилировались при упаковке приложения. Итак, теперь у меня есть *Config.groovy файлов, содержащих настройки по умолчанию (для всех сред), и *Config.groovy.production файлов, содержащих настройки по умолчанию для производственной среды (переопределяющие предварительно скомпилированные значения по умолчанию).

Теперь - Config.groovy начинается так:

grails.config.defaults.locations = [ EmailConfig, AccessConfig, LogConfig, SecurityConfig ]

environments {
    production {
        grails.config.locations = ConfigUtils.getExternalConfigFiles(
            '.production',
            "${userHome}${File.separator}.config${File.separator}${appName}",
            'AccessConfig.groovy',
            'Config.groovy',
            'DataSource.groovy',
            'EmailConfig.groovy',
            'LogConfig.groovy',
            'SecurityConfig.groovy'
        )
    }
}

Затем класс ConfigUtils:

public class ConfigUtils {

    // Log4j may not be initialized yet 
    private static final Logger LOG = Logger.getGlobal()

    public static def getExternalConfigFiles(final String defaultSuffix, final String externalConfigFilesLocation, final String... externalConfigFiles) {

        final def externalConfigFilesDir = new File(externalConfigFilesLocation)

        LOG.info "Loading configuration from ${externalConfigFilesDir}"

        if (!externalConfigFilesDir.exists()) {
            LOG.warning "${externalConfigFilesDir} not found. Creating..."
            try {
                externalConfigFilesDir.mkdirs()
            } catch (e) {
                LOG.severe "Failed to create external configuration storage. Default configuration will be used."
                e.printStackTrace()
                return []
            }
        }

        final def cl = ConfigUtils.class.getClassLoader()
        def result = []

        externalConfigFiles.each {

            final def file = new File(externalConfigFilesDir, it)
            if (file.exists()) {
                result << file.toURI().toURL()
                return
            }

            final def error = false
            final def defaultFileURL = cl.getResource(it + defaultSuffix)
            final def defaultFile

            if (defaultFileURL) {
                defaultFile = new File(defaultFileURL.toURI())
                error = !defaultFile.exists();
            } else {
                error = true
            }

            if (error) {
                LOG.severe "Neither of ${file} or ${defaultFile} exists. Skipping..."
                return
            }

            LOG.warning "${file} does not exist. Copying ${defaultFile} -> ${file}..."

            try {
                FileUtils.copyFile(defaultFile, file)
            } catch (e) {
                LOG.severe "Couldn't copy ${defaultFile} -> ${file}. Skipping..."
                e.printStackTrace()
                return
            }

            result << file.toURI().toURL()
        }

        return result
    }

}