Система обнаружила исключение защиты

Вывод // SYSOUT DD может сбивать с толку при использовании COBOL, SORT (DFSORT или SyncSORT) и Language Environment, которые могут выдавать вам сообщения во время выполнения, поскольку все они используют SYSOUT по умолчанию, и сообщения будут отображаться смешанными.

К счастью, вы можете изменить поведение по умолчанию, как показано здесь для DFSORT и Language Envrionment (в LE есть много способов указать параметр, наиболее гибким является //CEEOPTS DD в вашем JCL): https://stackoverflow.com/a/29521423/1927206

Сам COBOL имеет параметр компилятора OUTDD. значение по умолчанию SYSOUT, но вы можете указать любой OUTDD (xxxx)

Хорошо, просмотрев ваш JCL и ваши комментарии о том, как оператор DISPLAY в вашей программе влияет на данные, мне удалось частично воспроизвести.

Я использую DFSORT и не понимаю вашего точного поведения, поэтому предполагаю, что вы используете SYNCSORT.

Поведение, которое я могу получить после удаления //SYSOUT DD из моего JCL, выглядит следующим образом:

IGZ0026W На специальный регистр SORT-RETURN никогда не ссылались, но текущее содержимое указывает, что операция сортировки или слияния в программе STOB87 в строке номер 46 была неудачной.

Когда я добавляю // SYSOUT обратно в JCL, программа работает успешно.

Когда я вынимаю // SYSOUT и добавляю DISPLAY перед SORT, программа работает. Это связано с тем, что если в JCL нет // SYSOUT, первый выполненный DISPLAY вызовет его динамическое создание (вывод будет отображаться в спуле, как если бы это было отдельное задание с тем же именем и номером задания).

В моем случае DFSORT жалуется на отсутствие // SYSOUT. При использовании DISPLAY // SYSOUT не пропадает во время запуска DFSORT.

Я должен предположить, что SYNCSORT сталкивается с аналогичной проблемой, но сообщение COBOL во время выполнения не создается, и сам SYNCSORT не работает при следующем RELEASE.

Хотя это кажется простой и распространенной проблемой, поскольку мы всегда копируем часть JCL, чтобы создать новую часть JCL, // SYSOUT всегда присутствует.

Проконсультируйтесь с Руководством по программированию Enterprise COBOL, глава 12, я думаю, и узнайте, как использовать SORT-RETURN для подтверждения успешного завершения SORT.

Я почти уверен, что если вы включите // SYSOUT в свой JCL, вы больше не получите аварийного завершения, независимо от того, есть ли у вас DISPLAY.

Причина высокого «смещения» заключается в том, что аварийный процессор не может идентифицировать точку входа вашего продукта SORT, поэтому продолжает поиск в обратном направлении, чтобы найти то, что он может идентифицировать, и находит точку входа вашей программы, а затем вычисляет неправильное смещение. . Это также может произойти при ВЫЗОВЕ некоторых программ на Ассемблере.

Во-первых, к вашему S0C4, который является исключением защиты, что означает, что вы пытаетесь получить доступ к хранилищу, которое не «принадлежит» вам, для того доступа, который вам нужен.

Вы получаете S0C4 в программе SU98PGM6. Вы хитро стерли свое PROGRAM-ID имя при размещении здесь сообщения, что, вероятно, не помогло.

SU98PGM6 - это не ваша программа. Аварийное завершение (Abnormal End) находится по смещению X'0005517A 'в сбойной программе. Это означает, что с «начала» программы (точка входа) инструкция со смещением / смещением X'0005517A 'является той, которая попыталась сделать плохую вещь. Это смещение, равное 348538 в десятичной системе, указывает на довольно большую программу. Ваша программа очень маленькая.

Это может произойти разными способами. Например, вы могли скопировать JCL откуда-то еще и не смогли изменить EXEC PGM=. У вас может быть программа с тем же именем, что и ваша ранее в конкатенации STEPLIB. Возможно, вы скомпилировали не ту программу. И т.п.

Когда вы получаете аварийное завершение работы, всегда подтверждайте, что список компиляции, который у вас есть, относится к прерванной программе. Простой и полезный способ сделать это:

   01  W-WHEN-COMPILED                     PIC X(8)BX(8).

   ...

  * where it can only be executed once:
       MOVE WHEN-COMPILED           TO W-WHEN-COMPILED
       DISPLAY 
               "yourname COMPILED ON " 
               W-WHEN-COMPILED

"ваше имя" вы замените текстом, следующим за ИД ПРОГРАММЫ.

Результат будет таким:

yourname COMPILED ON 11/24/15 10.35.26

Это будет соответствовать дате / времени в заголовке на каждой странице списка компиляции.

Если вы запускаете программу и не получаете этого вывода, или вы получаете результат, но это не тот результат, который ожидается, то вы знаете, что ваша программа не работает.

Теперь о вашей программе.

1. Вам не нужно использовать процедуры ввода / вывода, чтобы иметь возможность СОРТИРОВАТЬ
2. Вы должны всегда использовать предложение FILE STATUS оператора SELECT и всегда проверять поля статуса файла (по одному на файл), которые вы определяете, после каждой операции ввода-вывода. Проверка поля состояния файла для входного файла позволит вам определить конец файла без использования извилистой конструкции AT END/NOT AT END.
3. Если вы используете процедуры сортировки, COBOL выполняет ввод-вывод. Если вы этого не сделаете и используете опцию компилятора FASTSRT, ваш продукт SORT выполнит ввод-вывод, что будет намного эффективнее, чем COBOL.
4. Если вы не выбираете или не переформатируете записи, вам не нужны процедуры сортировки.
5. Поскольку вы используете INTO, который выполняет неявное ПЕРЕМЕЩЕНИЕ записи, вам не нужно также ПЕРЕМЕЩАТЬ данные по отдельности.
6. COBOL, поскольку компиляторы, поддерживающие Стандарт 1985 года, который, я уверен, у вас будет, есть "ограничители области видимости". До этого единственным ограничителем области видимости была точка / точка. В наши дни при использовании «императивных операторов» и для всех условных операторов используются явные, конкретные указатели конца области видимости. В вашем случае замените использование READ / END-READ, RETURN / END-RETURN
7. Используйте точки / точки только в PROCEDURE DIVISION, где они требуются, а не в строке кода. Это помогает перемещать / копировать код из одного места в другое.
8. Используйте для тестов 88-уровневые имена условий, а не литералы. Вы можете сделать имя значимым, чтобы никому не приходилось задумываться о том, что означает «F» в конкретном контексте.

Чтобы просто СОРТИРОВАТЬ файл в программе на языке COBOL, посмотрите SORT ... USING ... GIVING... и используйте параметр компилятора FASTSRT (если возможно).

Вы еще не осведомлены о значениях абзацев (или SECTION) и оператора EXIT.

При использовании PERFORM или SORT PROCEDURE выполнение передается коду в абзаце и возвращает управление при достижении следующего абзаца.

Ваши "выходные" абзацы в том виде, в каком вы их закодировали, никогда не используются, но кто-то, глядя на код, предположит (если они глупые, и многие люди сделают предположение), что вы использовали THRU, и они будут придерживаться GO TO абзац «выход». Тогда они будут удивлены, что программа ведет себя плохо (если им повезет) и в конечном итоге выяснят, что они использовали GO TO для передачи управления из диапазона PERFORM / PROCEDURE.

Если ваши местные стандарты предписывают использование выходных параграфов, вы должны использовать THRU в своих инструкциях PERFORM и PROCEDURE.

Выходные абзацы совершенно бесполезны и ничего не делают, кроме как предоставляют целевую метку для GO TO, а это означает, что кто-то в будущем, вероятно, будет использовать GO TO для «удобства».

Вот ваша исходная программа с удаленными выходными абзацами:

IDENTIFICATION DIVISION.                       
PROGRAM-ID. ******.                          
ENVIRONMENT DIVISION.                          
INPUT-OUTPUT SECTION.                          
FILE-CONTROL.                                  
     SELECT IN-FILE ASSIGN TO IFILE.           
     SELECT OUT-FILE ASSIGN TO OFILE.          
     SELECT SORT-FILE ASSIGN TO SORTWK.        
DATA DIVISION.                                 
FILE SECTION.                                  
SD SORT-FILE.                                  
01 SORT-REC.                                   
   05 S-NAME     PIC X(20).                    
   05 S-ADDRESS  PIC X(20).                    
   05 S-ID       PIC 9(9).                     
   05 S-CREDITS  PIC 99.                       
   05 FILLER     PIC X(29).                    
FD IN-FILE.                                    
01 IN-REC.                                     
   05 IN-NAME    PIC X(20).                    
   05 IN-ADDRESS PIC X(20).                    
   05 IN-ID      PIC 9(9).                     
   05 IN-CREDITS PIC 99.                       
   05 FILLER     PIC X(29).                    
FD OUT-FILE.                                   
01 OUT-REC       PIC X(80).                    
WORKING-STORAGE SECTION.                       
01 WS-WORK-AREA.                               
    05  EOF-SW    PIC X           VALUE SPACES.
01 WS-DETAIL-LINES.                            
   05 RPT-LINE.                                
      10 OUT-NAME    PIC X(20).                
      10 OUT-ADDRESS PIC X(20).                
      10 OUT-ID      PIC 9(9).
      10 OUT-CREDITS PIC 99.                      
      10 FILLER      PIC X(29)       VALUE SPACES.
PROCEDURE DIVISION.                               
    SORT SORT-FILE                                
            ON ASCENDING KEY S-ID                 
            INPUT PROCEDURE READ-RELEASE          
            OUTPUT PROCEDURE RETURN-WRITE        
    GOBACK
    .                                     
OPEN-FILES-RTN.                                   
    OPEN INPUT IN-FILE                           
    OPEN OUTPUT OUT-FILE
    .                         

READ-RELEASE.                                     
    PERFORM OPEN-FILES-RTN
    PERFORM READ-INPUT                            
     UNTIL EOF-SW = 'F'                          
    .

READ-INPUT.                                       
    READ IN-FILE                                  
     AT END MOVE 'F' TO EOF-SW
    END-READ                   
    RELEASE SORT-REC FROM IN-REC
    .

RETURN-WRITE.                                     
    MOVE SPACES TO EOF-SW
    PERFORM WRITE-FL                              
     UNTIL EOF-SW  = 'F'                         
    PERFORM CLOSE-FILES-RTN                      
    .

WRITE-FL.                                         
    RETURN SORT-FILE RECORD INTO OUT-REC          
     AT END MOVE 'F' TO EOF-SW
    END-RETURN
    WRITE OUT-REC
    .

CLOSE-FILES-RTN.           
    CLOSE IN-FILE OUT-FILE
    .

Я также изменил STOP RUN на GOBACK, который является гораздо более гибким, и удалил ваше имя первого абзаца, так как это не нужно и для людей, плохо знакомых с COBOL, слишком много подразумевает (сам COBOL не имеет понятия "main", поскольку это может быть быть уместным на других языках, которые вы, возможно, знаете).