Ваш вызов пользовательского ввода не установил указатель на buffer. Таким образом, вместо этого будет прочитано prompt. Кроме того, заданная длина была 454 вместо [предполагаемой] 45. Кроме того, этот системный вызов не возвращает длину, поэтому сохранение v0 ничего не дало.
После исправления вышесказанного программа работает. Но он будет записывать выходные данные фиксированной длины, поэтому в конце будут двоичные нули.
Я добавил код для вычисления длины строки (например, strlen). Я также добавил комментарии на боковой панели к большинству строк. Я очень рекомендую это для любого ассемблера. В любом случае, вот исправленная программа [извините за бесплатную очистку стиля]:
.data
file1: .asciiz "file1.txt"
prompt: .asciiz "User entry\n"
buffer: .space 46
.eqv BUFMAX 45 # usable buffer length (one less)
.text
# prompt user
la $a0,prompt # prompt string
li $v0,4 # puts syscall number
syscall
# read user string
li $v0,8
la $a0,buffer # FIXME -- this was missing
li $a1,BUFMAX # FIXME -- this was 454
syscall
###move $s1,$v0 # FIXME -- does nothing v0 is not length
###li $s1,BUFMAX # use fixed length
###j writeFile1 # would do write with zeroes in file
# calculate string length (e.g. like strlen)
move $s1,$a0 # point to buffer start
getlen:
lb $t0,0($s1) # get byte -- is it zero?
addi $s1,$s1,1 # advance pointer
bne $t0,$zero,getlen # no, loop
sub $s1,$s1,$a0 # get length from end pointer
subi $s1,$s1,1 # compensate for preincrement
writeFile1:
# open the output file
li $v0,13 # open syscall number
la $a0,file1 # filename
li $a1,1 # open for writing
li $a2,0 # open mode
syscall
move $s6,$v0 # save fildes number
# write
li $v0,15 # write syscall number
move $a0,$s6 # get fildes number
la $a1,buffer # get buffer pointer
move $a2,$s1 # get buffer length
syscall
# close
li $v0,16
move $a0,$s6 # get fildes number
syscall
j exit
exit:
li $v0,10 # exit syscall number
syscall
person
Craig Estey
schedule
11.03.2016
