Vb.net Сохранить, какие узлы были развернуты в TreeView

Вот несколько основных идей, которые помогут вам в реализации:

Создайте список, чтобы отслеживать узлы, которые в настоящее время развернуты:

Private _ExpandedNodeList As New List(Of String)

Настройте два обработчика событий для отслеживания событий AfterCollapse и AfterExpand TreeView — они происходят, когда пользователь открывает/закрывает разные части дерева. Хитрость здесь в том, что обработчики событий просто добавляют и удаляют значение тега узла, которое представляет собой некоторую строку, которую вы установили для узла при построении дерева.

Private Sub TreeView_AfterCollapse(sender As Object, e As TreeViewEventArgs) Handles TreeView.AfterCollapse
    If _ExpandedNodeList.Contains(e.Node.Tag.ToString) Then
        _ExpandedNodeList.Remove(e.Node.Tag.ToString)
    End If
End Sub
Private Sub TreeView_AfterExpand(sender As Object, e As TreeViewEventArgs) Handles TreeView.AfterExpand
    If Not _ExpandedNodeList.Contains(e.Node.Tag.ToString) Then
        _ExpandedNodeList.Add(e.Node.Tag.ToString)
    End If
End Sub

Теперь давайте предположим, что у вас есть точка в приложении, где вам нужно восстановить TreeView до определенного состояния. Вы можете рекурсивно использовать узлы в TreeView и вызывать Expand для тех, которые есть в вашем списке.

Моя реализация выглядит так:

Private Sub ShowVisibleNodes()
    Dim Node As TreeNode

    For Each ExpandedChildNodeName As String In _ExpandedNodeList
        For Each RootNode As TreeNode In TreeView.Nodes
            Node = NodeFromTagName(ExpandedChildNodeName, RootNode)
            If Node IsNot Nothing Then
                Node.Expand()
            End If
        Next
    Next

End Sub
Private Function NodeFromTagName(ByVal NodeTagName As String, NodeToSearch As TreeNode) As TreeNode
    Dim NextNode As TreeNode

    'check input node
    If NodeToSearch.Tag IsNot Nothing Then
        If NodeToSearch.Tag.Equals(NodeTagName) Then
            Return NodeToSearch
        End If
    End If

    'check child nodes and recurse on intermediary nodes
    For Each Node As TreeNode In NodeToSearch.Nodes
        If Node.Tag IsNot Nothing Then
            If Node.Tag.Equals(NodeTagName) Then
                Return Node
            End If
            NextNode = NodeFromTagName(NodeTagName, Node)
            If NextNode IsNot Nothing Then
                Return NextNode
            End If
        End If
    Next

    Return Nothing

End Function

Обратите внимание, что этот код не гарантирует работу, если просто добавить его в приложение.

По крайней мере, вам нужно тщательно подумать о построении вашего дерева и о том, устанавливаете ли вы значение тега для каждого узла дерева.

Надеюсь, это поможет вам начать.