cxgrid выделение (или цвет) измененной ячейки в закрытом запросе формы

С помощью события cxGrid1DBTableView1CustomDrawCell легко заставить cxGrid рисовать ячейку (или строку), выделенную каким-либо образом. И имея флаг, который указывает, что событие OnCloseQuery выполняется, вы можете ограничить его действие внутри этого события.

Обновить. Код, который я изначально разместил вместе с этим ответом, не смог успешно пометить более одной ячейки в текущей строке сетки как измененные. Однако обновленный код ниже может это сделать; обратите внимание на комментарии в двух процедурах.

type
  TForm1 = class(TForm)
    [...]
  public
    QueryingClose : Boolean;
  end;

procedure TForm1.FormCloseQuery(Sender: TObject; var CanClose: Boolean);
begin
  try
    QueryingClose := True;
    //{cxGrid1.Invalidate{True);  Do NOT call Invalidate, because it causes the
    //  grid's repainting logic to operate in a way which effectively makes it
    //  impossible to mark more that one cell in the current data row as changed
    ShowMessage('Close?');
  finally
    QueryingClose := False;
  end;
end;

procedure TForm1.cxGrid1DBTableView1CustomDrawCell(Sender:
    TcxCustomGridTableView; ACanvas: TcxCanvas; AViewInfo:
    TcxGridTableDataCellViewInfo; var ADone: Boolean);
var
  Field : TField;
  MarkCell : Boolean;
  S1,
  S2 : String;
  EC : TcxGridTableEditingController;
begin
  if QueryingClose  and
    (TcxGridDBTableView(Sender).DataController.DataSet.State in[dsEdit, dsInsert]) then begin
    Field := TcxGridDBColumn(AViewInfo.Item).DataBinding.Field;
    S1 := VarToStr(Field.OldValue);

    //  When this event is called, the user may be in the middle of editing a cell's contents
    //  So, the purpose of the following lines is to close the inplace editor being used to do
    //  this amd post the chamged value back to the TField associated with the cell
    EC :=  TcxGridDBTableView(Sender).Controller.EditingController;
    if EC.IsEditing then
      EC.HideEdit(True);

    S2 := VarToStr(Field.Value);
    MarkCell := S1 <> S2;
    if MarkCell then
      ACanvas.Brush.Color := clLime;
  end;
end;

Чтобы это работало, ваш тип-потомок TDataSet должен поддерживать правильный возврат исходного содержимого полей в свойстве OldValue; TClientDataSet, который я использовал для написания / тестирования этого кода, безусловно, делает это, но я понятия не имею, какой именно тип TDataSet вы используете.

Надеюсь, должно быть очевидно, что вы можете использовать эти две процедуры для создания списка TFields, значения которых изменились, включая FieldName OldValue и Value.