Получение позиции курсора через escape-последовательность VT-100 консоли Windows 10

Существенное изменение через три года

Он работает с чтением ответа с использованием XCOPY или REPLACE.

Я использую здесь replace, чтобы избежать языковых проблем.

@echo off
for /F "delims=#" %%a in ('"prompt #$E# & for %%a in (1) do rem"') do set "ESC=%%a"

call :get_cursor_pos
exit /b

:get_cursor_pos
set "response="
set pos=2

:_get_loop
REM *** Request Cursor position
<nul set /p "=%ESC%[6n" 
FOR /L %%# in (1 1 %pos%) DO pause < CON > NUL

for /F "tokens=1 skip=1 eol=" %%C in ('"REPLACE /W ? . < con"') DO (
    set "char=%%C"
)
set "response=%response%%char%"
set /a pos+=1
if "%char%" NEQ "R" goto :_get_loop

set response
exit /b

Основная проблема в том, что XCOPY или REPLACE позволяют мне прочитать один символ из входного потока, но затем очищают оставшийся буфер.

И наоборот, PAUSE считывает один символ, сохраняя оставшийся буфер, но не показывает, какой символ был прочитан.

Чтобы решить эту проблему, я отправляю запрос несколько раз, каждый раз читая разные символы ответа. Для каждой итерации я использую комбинацию из 2 или более операторов PAUSE, за которыми следует REPLACE, чтобы прочитать определенный символ ответа. Каждая итерация использует на PAUSE больше, чем предыдущая итерация, пока я не смогу прочитать завершающий R.

Я разработал эту технику и первоначально разместил ее на странице DosTips - состояния запросов с использованием последовательностей виртуальных терминалов консоли .

У меня НЕ Windows 10, поэтому я не могу пройти ни один тест. Однако, если ответом последовательности Ansi ESC[6n является заполнить буфер ввода с клавиатуры символами ESC[<n>;<m>R, тогда просто необходимо добавить клавишу Enter к такому вводу, чтобы прочитать его с помощью команды SET /P, и это можно сделать с помощью метода SendKeys JScript.

Я также использовал более простой метод, чтобы получить символ ESC в переменной.

ИЗМЕНИТЬ: я изменил код в соответствии с комментариями ...

@if (@CodeSegment == @Batch) @then

@echo off
title Ansi Test
setlocal EnableDelayedExpansion

for /F %%a in ('echo prompt $E ^| cmd') do set "esc=%%a"
set "csi=%esc%["

echo Inquiry:%csi%6n
cscript //nologo //E:JScript "%~F0"
set /p "pos=" > NUL
echo response=!pos:%esc%=ESC!

@end

var sh = WScript.CreateObject("WScript.Shell");
sh.AppActivate("Ansi Test");
sh.SendKeys("{ENTER}");

Пожалуйста, выложите результат ...