Jenkins - прервать выполнение сборки, если запущена новая

С безопасностью сценария Jenkins многие решения здесь становятся сложными, поскольку они используют методы, не внесенные в белый список.

С этими этапами в начале Jenkinsfile это работает для меня:

def buildNumber = env.BUILD_NUMBER as int
if (buildNumber > 1) milestone(buildNumber - 1)
milestone(buildNumber)

Результат здесь будет:

• Сборка 1 запускается и создает веху 1
• Пока работает сборка 1, срабатывает сборка 2. У него есть этап 1 и этап 2. Он проходит этап 1, что приводит к прерыванию сборки №1.

включить параллельный запуск заданий для вашего проекта с помощью Execute concurrent builds if necessary

используйте execute system groovy script в качестве первого шага сборки:

import hudson.model.Result
import jenkins.model.CauseOfInterruption

//iterate through current project runs
build.getProject()._getRuns().iterator().each{ run ->
  def exec = run.getExecutor()
  //if the run is not a current build and it has executor (running) then stop it
  if( run!=build && exec!=null ){
    //prepare the cause of interruption
    def cause = { "interrupted by build #${build.getId()}" as String } as CauseOfInterruption 
    exec.interrupt(Result.ABORTED, cause)
  }
}

а в прерванных заданиях будет журнал:

Build was aborted
interrupted by build #12
Finished: ABORTED 

Если кому-то это нужно в Jenkins Pipeline Multibranch, это можно сделать в Jenkinsfile следующим образом:

def abortPreviousRunningBuilds() {
  def hi = Hudson.instance
  def pname = env.JOB_NAME.split('/')[0]

  hi.getItem(pname).getItem(env.JOB_BASE_NAME).getBuilds().each{ build ->
    def exec = build.getExecutor()

    if (build.number != currentBuild.number && exec != null) {
      exec.interrupt(
        Result.ABORTED,
        new CauseOfInterruption.UserInterruption(
          "Aborted by #${currentBuild.number}"
        )
      )
      println("Aborted previous running build #${build.number}")
    } else {
      println("Build is not running or is current build, not aborting - #${build.number}")
    }
  }
}

Основываясь на идее @ C4stor, я сделал эту улучшенную версию ... Я считаю ее более читаемой по сравнению с версией @daggett

import hudson.model.Result
import hudson.model.Run
import jenkins.model.CauseOfInterruption.UserInterruption

def abortPreviousBuilds() {
    Run previousBuild = currentBuild.rawBuild.getPreviousBuildInProgress()

    while (previousBuild != null) {
        if (previousBuild.isInProgress()) {
            def executor = previousBuild.getExecutor()
            if (executor != null) {
                echo ">> Aborting older build #${previousBuild.number}"
                executor.interrupt(Result.ABORTED, new UserInterruption(
                    "Aborted by newer build #${currentBuild.number}"
                ))
            }
        }

        previousBuild = previousBuild.getPreviousBuildInProgress()
    }
}

Чтобы это заработало, в глобальной общей библиотеке есть следующий скрипт:

import hudson.model.Result
import jenkins.model.CauseOfInterruption.UserInterruption

def killOldBuilds() {
  while(currentBuild.rawBuild.getPreviousBuildInProgress() != null) {
    currentBuild.rawBuild.getPreviousBuildInProgress().doKill()
  }
}

И вызывая это в моем конвейере:

@Library('librayName')
def pipeline = new killOldBuilds()
[...] 
stage 'purge'
pipeline.killOldBuilds()

Изменить: в зависимости от того, насколько сильно вы хотите убить oldBuild, вы можете использовать doStop (), doTerm () или doKill ()!

Добавление к ответу Брэндона Сквиццато. Если сборки иногда пропускаются, упомянутый механизм этапов не работает. Это решает установка более старых вех в цикле for.

Также убедитесь, что в ваших параметрах не указано disableConcurrentBuilds. В противном случае конвейер не дойдет до этапа, и это не сработает.

def buildNumber = env.BUILD_NUMBER as int
for (int i = 1; i < buildNumber; i++)
{
    milestone(i)
}
milestone(buildNumber)

На основе метода @daggett. Если вы хотите прервать выполнение сборки при поступлении нового push-уведомления и до получения обновлений.
1. Включите Execute concurrent builds if necessary
2. Включите Prepare an environment for the run
3. Выполните следующий код в Groovy Script или Evaluated Groovy script

import hudson.model.Result
import hudson.model.Run
import jenkins.model.CauseOfInterruption

//def abortPreviousBuilds() {
    Run previousBuild = currentBuild.getPreviousBuildInProgress()

    while (previousBuild != null) {
        if (previousBuild.isInProgress()) {
            def executor = previousBuild.getExecutor()
            if (executor != null) {
                println ">> Aborting older build #${previousBuild.number}"
                def cause = { "interrupted by build #${currentBuild.getId()}" as String } as CauseOfInterruption 
                executor.interrupt(Result.ABORTED, cause)
            }
        }
        previousBuild = previousBuild.getPreviousBuildInProgress()
    }
//}

Я также скомпилировал версию из ранее приведенных с несколькими незначительными изменениями:

• цикл while() генерировал несколько выходных данных для каждой сборки
• UserInterruption в настоящее время ожидает userId вместо строки рассуждений и нигде не будет показывать строку рассуждений. Следовательно, это просто предоставляет userId

def killOldBuilds(userAborting) {
    def killedBuilds = []
    while(currentBuild.rawBuild.getPreviousBuildInProgress() != null) {
        def build = currentBuild.rawBuild.getPreviousBuildInProgress()
        def exec = build.getExecutor()

        if (build.number != currentBuild.number && exec != null && !killedBuilds.contains(build.number)) {
            exec.interrupt(
                    Result.ABORTED,
                    // The line below actually requires a userId, and doesn't output this text anywhere
                    new CauseOfInterruption.UserInterruption(
                            "${userAborting}"
                    )
            )
            println("Aborted previous running build #${build.number}")
            killedBuilds.add(build.number)
        }
    }
}