завершение zsh с виртуальным путем

Я хочу создать дополнение zsh для инструмента с виртуальным файловым деревом. например мое файловое дерево выглядит следующим образом:

/
|- foo/
|  |- bar
|  |- baz/
|     |- qux
|- foobar

Мой инструмент mycmd имеет подкоманду для вывода списка текущего каталога:

$ mycmd ls
foo/
foobar
$ mycmd ls foo/
bar
baz/

Мое фактическое завершение zsh выглядит так:

_mycmd_ls() {
    if [ ! -z "$words[-1]" ]; then
        dir=$(dirname /$words[-1])
        lastpart=$(basename $words[-1])
        items=$(mycmd ls $dir | grep "^$lastpart")
    else
        items=$(mycmd ls)
    fi
    _values -s ' ' 'items' ${(uozf)items}
}


_mycmd() {
    local -a commands

    commands=(
        'ls:list items in directory'
    )

    _arguments -C -s -S -n \
        '(- 1 *)'{-v,--version}"[Show program\'s version number and exit]: :->full" \
        '(- 1 *)'{-h,--help}'[Show help message and exit]: :->full' \
        '1:cmd:->cmds' \
        '*:: :->args' \

    case "$state" in
        (cmds)
            _describe -t commands 'commands' commands
            ;;
        (args)
            _mycmd_ls
            ;;
        (*)
            ;;
    esac
}

_mycmd

ИМХО это _values неправильная служебная функция. Фактическое поведение:

$ mycmd ls<TAB>
foo/    foobar
$ mycmd ls foo/<TAB>  ## <- it inserts automatically a space before <TAB> and so $words[-1] = ""
foo/    foobar

Я не могу использовать служебную функцию _files или _path_files, потому что дерево файлов только виртуальное.


zsh zsh-completion
person tru    schedule 01.03.2017    source источник
comment
Мне было бы очень любопытно посмотреть, есть ли способ сделать это. Я сталкиваюсь с такими же проблемами.   -  person Lery    schedule 19.12.2018

Ответы (1)


arrow_upward
2
arrow_downward

Я бы предложил использовать compadd, а не _values, чтобы получить контроль над добавленным символом суффикса. Затем, просмотрев доступные варианты, установите пустой символ суффикса на случай, если виртуальный каталог является частью результата:

_mycmd_ls() {
    if [ ! -z "$words[-1]" ]; then
        dir=$(dirname /$words[-1])
        lastpart=$(basename $words[-1])
        items=$(mycmd ls $dir | grep "^$lastpart")
    else
        items=$(mycmd ls)
    fi

    local suffix=' ';
    # do not append space to word completed if it is a directory (ends with /)
    for val in $items; do
        if [ "${val: -1:1}" = '/' ]; then
            suffix=''
            break
        fi
    done

    compadd -S "$suffix" -a items
}
person Xavier Delaruelle    schedule 23.12.2018
comment
Благодарю вас! Я изо всех сил пытался понять все функции и стили утилиты завершения, и этот фрагмент кода сделал именно то, что мне было нужно. - person Thomas K; 21.02.2019