TAniIndicator не вращается — загрузка tlistview

Ваш рабочий поток проводит все свое время внутри своего метода Process(), который вызывается TThread.Synchronize(), поэтому он выполняется в основном потоке пользовательского интерфейса. Process() не обрабатывает сообщения пользовательского интерфейса, поэтому TAniIndicator не работает.

Как есть, ваш рабочий поток совершенно бесполезен. Весь ваш код выполняется в основном потоке пользовательского интерфейса. Итак, вы можете вообще избавиться от TLoadThread:

procedure TForm1.FormCreate(Sender: TObject);
begin
  AniIndicator1.Visible := False;
end;

procedure TForm1.BuildListView;
var
  i : integer;
  LI : TListViewItem;
begin
  AniIndicator1.Visible := True;
  AniIndicator1.Enabled := True;
  ListView1.BeginUpdate;
  try
    for i := 1 to 2000 do
    begin
      LI := ListView1.Items.Add;
      LI.Text := 'ListView Item ' + IntToStr(i);
      if (i mod 100) = 0 then
        Application.ProcessMessages;
    end;
  finally
    ListView1.EndUpdate;
    AniIndicator1.Enabled := False;
    AniIndicator1.Visible := False;
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  BuildListView;
end;

В противном случае, если вы используете поток, не синхронизируйте сам цикл, а только те части, которые действительно касаются пользовательского интерфейса:

type
  TLoadThread = class(TThread)
  public
    constructor Create; reintroduce;
  protected
    procedure Execute; override;
  end;

constructor TLoadThread.Create;
begin
  inherited Create(True);
  FreeOnTerminate := True;
end;

procedure TLoadThread.Execute;
begin
  Form1.BuildListView;
end;

var
  _loadThread : TLoadThread = nil;

procedure TForm1.ThreadTerminated(Sender: TObject);
begin
  _loadThread := nil;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  AniIndicator1.Visible := False;
end;

procedure TForm1.BuildListView;
var
  i : integer;
begin
  TThread.Synchronize(nil,
   procedure
   begin
     AniIndicator1.Visible := True;
     AniIndicator1.Enabled := True;
     ListView1.BeginUpdate;
   end
  );
  try
    for i := 1 to 2000 do
    begin
      TThread.Synchronize(nil,
        procedure
        var
          LI : TListViewItem;
        begin
          LI := ListView1.Items.Add;
          LI.Text := 'ListView Item ' + IntToStr(i);
        end
      );
    end;
  finally
    TThread.Synchronize(nil,
      procedure
      begin
        ListView1.EndUpdate;
        AniIndicator1.Enabled := False;
        AniIndicator1.Visible := False;
      end
    );
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  if _loadThread <> nil then
  begin
    _loadThread := TLoadThread.Create;
    _loadThread.OnTerminate := ThreadTerminated;
    _loadThread.Start;
  end;
end;