`принуждение` и создание экземпляров переменных типа

member :: Ord a => a -> Map a b -> Bool
member' :: Ord a => a -> MySet a -> Bool

GHC должен принять

Coercible (Map a b) (MySet a)

Он видит, что

Coercible (MySet a) (Map a ())

что оставляет его нуждающимся

Coercible (Map a ()) (Map a b)

что приводит к

Coercible () b

Но что такое b? Это неоднозначно. В этом случае не имеет значения, что такое b, потому что по параметричности member может быть все равно. Так что было бы совершенно разумно выбрать b ~ () и тривиально разрешить принуждение. Но GHC обычно не выполняет такой параметрический анализ при выводе типов. Я подозреваю, что это может быть сложно изменить. В частности, каждый раз, когда вывод типа «угадывается», существует риск, что он может ошибиться и заблокировать вывод где-то еще. Это большая банка червей.

Что касается вашей проблемы, у меня нет хорошего решения. Когда у вас есть несколько функций с похожими шаблонами, вы можете абстрагироваться от них, но вы все равно столкнетесь со значительным раздражением.

Решение с TypeApplications довольно простое:

{-# LANGUAGE TypeApplications #-}

import Data.Coerce
import qualified Data.Map as M

newtype Set a = Set (M.Map a ())

member :: Ord a => a -> Set a -> Bool
member = coerce (M.member @_ @())

union :: Ord a => Set a -> Set a -> Set a
union = coerce (M.union @_ @())

Обратите внимание, что для некоторых функций потребуется больше или меньше подстановочных знаков, например.

smap :: (Ord b) => (a -> b) -> Set a -> Set b
smap = coerce (M.mapKeys @_ @_ @())

Чтобы определить, как именно вы должны указать тип приложения (помимо проб и ошибок), используйте

>:set -fprint-explicit-foralls
>:i M.mapKeys
M.mapKeys ::
  forall k2 k1 a. Ord k2 => (k1 -> k2) -> M.Map k1 a -> M.Map k2 a

Порядок переменных, который вы получаете от :i, такой же, как и у TypeApplications.

Обратите внимание, что вы не можете использовать coerce вместо fromList — это не ограничение, это просто не имеет смысла:

fromList :: Ord a => [a] -> Set a
fromList = coerce (M.fromList @_ @())

Это дает ошибку

* Couldn't match representation of type `a' with that of `(a, ())'

Лучшее, что вы можете сделать здесь, вероятно,

fromList :: Ord a => [a] -> Set a
fromList = coerce (M.fromList @_ @()) . map (flip (,) ())