Как написать CMakeLists.txt для большого проекта с несколькими подкаталогами?

Мне нужен только один CMakeLists.txt в корневом каталоге или для каждого каталога нужен свой CMakeLists.txt файл?

Обычно по одному на каждом уровне дерева там, где это имеет смысл.

eg:

root/
+--- CMakeLists.txt             // your root CMakeLists
+--- foo/
|    +--- CMakeLists.txt        // foo component's CMakeLists
|    +--- foo.c
|    +--- tests/
|         +--- CMakeLists.txt   // foo test's CMakeLists
|         +--- foo_tests.c
+--- bar/
     +--- CMakeLists.txt        // bar component's CMakeLists
     +--- bar.c
     +--- bar_impl/             // no CMakeLists for this dir, it is part of bar
     |    +--- bar_impl.c
     +--- tests/
          +--- CMakeLists.txt   // bar test's CMakeLists
          +--- bar_tests.c

Корень проекта CMakeLists.txt:

В корне вашего проекта CMakeLists.txt вы указываете минимальные требования cmake, имя проекта и включаете подкаталоги, в которых есть ваши различные компоненты.

root/CMakeLists.txt:

cmake_minimum_required (VERSION 3.5)
project (my_project C)

add_subdirectory(foo)
add_subdirectory(bar)

Компонент CMakeLists.txt:

Затем в каждом подкаталоге компонентов у вас есть еще один CMakeLists.txt файл, в который вы добавляете библиотеки, исполняемые файлы и т. Д.

root/foo/CMakeLists.txt:

add_library(foo foo.c)
target_include_directories(foo PUBLIC ${CMAKE_CURRENT_SOURCE_DIR})

add_subdirectory(tests)

root/foo/tests/CMakeLists.txt:

add_executable(foo_test foo_tests.c)
target_link_libraries(foo_test foo)

Вы следуете этой структуре для бара и т. Д.

root/bar/CMakeLists.txt:

add_library(bar 
    bar.c 
    bar_impl/bar_impl.c)
target_include_directories(bar PUBLIC ${CMAKE_CURRENT_SOURCE_DIR})
target_link_libraries(bar foo)

add_subdirectory(tests)

root/bar/tests/CMakeLists.txt:

add_executable(bar_test bar_tests.c)
target_link_libraries(bar_test bar)

Создание файлов сборки:

Чтобы начать сборку, вы указываете cmake на свой root/CMakeLists.txt

cd root
mkdir build
cd build
cmake ..

(или используйте диспетчер сборки вашего ide, чтобы сгенерировать его конфигурацию сборки)

дальнейшее чтение

Подробнее о различных функциях, которые я здесь использовал, см. В документации:

• cmake_minimum_required
• project
• add_subdirectory
• target_include_directories
• target_link_libraries

Наконец, чтобы ответить на ваш второй вопрос:

Как рекурсивно добавить исходные файлы в CMakeLists.txt?

Это не рекомендуется (дополнительные подробности см. В этом обсуждении).

Лучше явно перечислить каждый файл, который вы хотите включить в свою цель.

Обратите внимание: если у вас есть исходные файлы в нескольких отдельных каталогах, но все они принадлежат одной и той же логической цели, тогда вам не нужен CMakeLists.txt файл для каждого каталога - просто укажите подкаталог в имени файла.

Пример:

foo/
+--- foo.c
+--- bar.c
+--- baz/
     +--- baz.c
     +--- bang.c

Если вам нужна одна цель foo для всех вышеупомянутых файлов, вы должны создать ее следующим образом:

add_library(foo 
   foo.c
   bar.c
   baz/baz.c
   baz/bang.c)

Или, если вы действительно хотите использовать переменную для хранения списка SRCS

set(SRCS 
   foo.c
   bar.c
   baz/baz.c
   baz/bang.c)

add_library(foo ${SRCS})