Выражения вычислений F#: можно ли использовать их для упрощения кода?

Во-первых, создавать новый MaybeBuilder каждый раз, когда вам это нужно, довольно расточительно. Вы должны сделать это один раз, желательно прямо рядом с определением самого MaybeBuilder, а затем просто везде использовать один и тот же экземпляр. Именно так работает большинство построителей вычислений.

Во-вторых: вы можете сократить количество беспорядка, если просто определите логику "попробовать" как функцию и повторно используете ее:

let myFunction2  (m:Map<string,Map<string,float>>) s1 s2 =
    let try' (x1, x2) = maybe{
        let! subMap = m.TryFind x1
        return! subMap.TryFind x2
    }

    match try' (s1, s2) with
    |Some f -> f
    |_ ->         
        match try' (s2, s1) with
        |Some f -> f
        |_ -> failwith (sprintf "Unable to locate a value between %s and %s" s1 s2)

В-третьих, обратите внимание на шаблон, который вы используете: попробуйте это, если нет, попробуйте то, если нет, попробуйте другое и т. д. Шаблоны можно абстрагировать как функции (в этом вся суть!), поэтому давайте сделаем это. :

let orElse m f = match m with
   | Some x -> Some x
   | None -> f()

let myFunction2  (m:Map<string,Map<string,float>>) s1 s2 =
    let try' (x1, x2) = maybe{
        let! subMap = m.TryFind x1
        return! subMap.TryFind x2
    }

    let result = 
        try' (s1, s2)
        |> orElse (fun() -> try' (s2, s1))

    match result with
    |Some f -> f
    |_ -> failwith (sprintf "Unable to locate a value between %s and %s" s1 s2)

И, наконец, я думаю, что вы делаете это неправильно. То, что вам действительно нужно, это словарь с симметричным ключом, состоящим из двух частей. Так почему бы просто не сделать это?

module MyMatrix =
    type MyKey = private MyKey of string * string
    type MyMatrix = Map<MyKey, float>

    let mkMyKey s1 s2 = if s1 < s2 then MyKey (s1, s2) else MyKey (s2, s1)


let myFunction2 (m:MyMatrix.MyMatrix) s1 s2 =
    match m.TryFind (MyMatrix.mkMyKey s1 s2) with
    | Some f -> f
    | None -> failwith (sprintf "Unable to locate a value between %s and %s" s1 s2)

Здесь MyKey — это тип, который инкапсулирует пару строк, но гарантирует, что эти строки «по порядку», то есть первая лексикографически «меньше», чем вторая. Чтобы гарантировать это, я сделал конструктор типа закрытым и вместо этого предоставил функцию mkMyKey, которая правильно создает ключ (иногда называемый "умный конструктор").

Теперь вы можете свободно использовать MyKey как для построения, так и для поиска на карте. Если вы введете (a, b, 42), вы получите и (a, b, 42), и (b, a, 42).

Несколько в сторону: общая ошибка, которую я вижу в вашем коде, — это отказ от использования абстракции. Вам не нужно обрабатывать каждую часть данных на самом низком уровне. Язык позволяет вам определять концепции более высокого уровня, а затем программировать в их терминах. Используйте эту способность.

Я понимаю, что это может быть просто упрощение для того, чтобы задать вопрос здесь, но что вы на самом деле хотите сделать, когда ни один из ключей не найден, и как часто вы ожидаете, что первый поиск будет неудачным?

Есть веские причины избегать исключений в F# — они медленнее (я не знаю, насколько точно, и, вероятно, это зависит от вашего варианта использования), и предполагается, что они используются в «исключительных обстоятельствах», но у языка есть хорошая поддержка для них.

Используя исключения, вы можете написать это как довольно читаемую трехстрочную строку:

let myLookupFunction (m:Map<string,Map<string,float>>) s1 s2 =
  try m.[s1].[s2] with _ -> 
  try m.[s2].[s1] with _ ->
    failwith (sprintf "Unable to locate a value between %s and %s" s1 s2)

Тем не менее, я полностью согласен с Федором в том, что было бы разумно определить свою собственную структуру данных для хранения данных, а не использовать карту карт (с возможным переключением ключей).