Добавить пользовательскую форму в другую книгу во время выполнения

Проблема, с которой вы столкнулись, заключается в том, что пользовательские формы по умолчанию создаются частным образом. Это означает, что проект не может ссылаться на форму пользователя в другом проекте, и если вы не можете ссылаться на форму, вы не можете вызвать ее метод Show.

Ваш оператор Set myForm = CallerWorkbook.VBProject.VBComponents.Add(vbext_ct_MSForm) возвращает VbComponent, а не UserForm, поэтому вы не можете использовать VBA.UserForms.Add(myForm.Name)

Есть 2 способа обойти это:

1. Создайте PublicNotCreatable шаблон пользовательской формы в своей надстройке.

Пользовательская форма подобна классу, поэтому она может иметь установленное свойство Instancing, как класс. Однако VBE не предоставляет свойство Instancing в окне свойств для пользовательских форм, поэтому для установки экземпляра необходимо экспортировать форму, а затем отредактировать атрибут Attribute VB_Exposed в файле FRM в текстовом редакторе перед импортом формы. снова. Вот шаги:

• Создайте пользовательскую форму с именем TemplateForm в проекте надстройки.
• Удалите TemplateForm и выберите Экспорт формы перед ее удалением.
• Откройте файл TemplateForm.frm в текстовом редакторе.
• Отредактируйте строку Attribute VB_Exposed = False так, чтобы она читалась как Attribute VB_Exposed = True.
• Сохраните изменения в TemplateForm.frm
• Импортируйте TemplateForm.frm в свою надстройку

• Добавьте в надстройку общедоступную функцию, которая возвращает новый экземпляр TemplateForm. Я заставил эту функцию принимать ссылку на книгу, чтобы надстройка могла настраивать любые свойства книги в форме:

  Public Function GetTemplateForm(CallerWorkbook As Workbook) As TemplateForm
    Dim frm As TemplateForm
    Set frm = New TemplateForm
    'Set early-bound properties with intellisense
    frm.Caption = "Select"
    frm.Width = 300
    frm.Height = 270
  
    'Configure CallerWorkbook specific form properties here
    '...
    Set GetTemplateForm = frm
  End Function
  

• Затем в рабочей книге пользователя вы можете отобразить экземпляр TemplateForm без необходимости динамического добавления формы или работы с мерцанием экрана или сложным для отладки кодом:

  Sub ShowAddinForm()
      With MyAddin.GetTemplateForm(ThisWorkbook)
          'Do more workbook specific propery setting here...
          '...
          .Show
      End With
  End Sub
  

** Примечание. Надстройка VBA Rubberduck скоро будет иметь возможность добавлять PublicNotCreatable UserForm.

2. Пусть надстройка создает компонент UserForm, но управляет им рабочая книга пользователя.

Этот подход далеко не так элегантен. Пользователь должен управлять гораздо большим количеством кода, мерцанием экрана и трудным для отладки кодом. Вот шаги:

• Добавьте этот код в надстройку:

  Public Function GetTempFormName(CallerWorkbook As Workbook) As String
      Const vbext_ct_MSForm As Long = 3
  
      'This is to stop screen flashing while creating form
      Application.VBE.MainWindow.Visible = False
  
      'Add to CallerWorkbook instead
      With CallerWorkbook.VBProject.VBComponents.Add(vbext_ct_MSForm)
          .Properties("Caption") = "Select"
          .Properties("Width") = 300
          .Properties("Height") = 270
          GetTempFormName = .Name
      End With
  End Function
  
  Public Sub RemoveTempForm(CallerWorkbook As Workbook, FormName As String)
      With CallerWorkbook.VBProject.VBComponents
          Dim comp As Object
          Set comp = .Item(FormName)
          .Remove .Item(FormName)
      End With
  End Sub
  

• Затем в рабочей книге пользователя добавьте этот код:

  Sub GetAddinToCreateForm()
      Dim FormName As String
      FormName = MyAddin.GetTempFormName(ThisWorkbook)
      With VBA.UserForms.Add(FormName)
          .Show
      End With
      MyAddin.RemoveTempForm ThisWorkbook, FormName
  End Sub