Как напечатать курсор в блоке PL/SQL?

Вы не можете напечатать такой курсор; ему пришлось бы неявно преобразовывать строки и столбцы в строки, а этого ожидать слишком много. Процедура dbms_output.put_line() принимает только строковый аргумент или любой другой аргумент, который можно неявно преобразовать в строку. Курсор не может.

Вам придется перебрать набор результатов курсора, выбирая подходящий тип записи; а затем вызовите dbms_output в этом цикле, который объединяет все значения столбца из набора результатов (отформатированные и, возможно, дополненные, если вы пытаетесь эмулировать выбор) в одну строку.

Не зная точно, как определяется ON24MASTER.WEBCAST_REPORTS.ResultSetCursor (предположительно TYPE ResultSetCursor IS REF CURSOR), или что возвращает запрос, который заполняет его в вашей процедуре - какие имена столбцов - трудно быть более конкретным.

Но поскольку вы пометили это для SQL Developer, вы можете использовать его встроенную обработку для переменных курсора ref, что удобно:

variable rc refcursor;

DECLARE
  LEADEMAIL VARCHAR2(200);
  CLIENTID NUMBER;
BEGIN
  LEADEMAIL := '[email protected]';
  CLIENTID := 22921;

  :rc := WEBCAST_REPORTS.LEAD_BASIC_INFO(
    LEADEMAIL => LEADEMAIL,
    CLIENTID => CLIENTID
  );

END;
/

print rc

Перед блоком объявляется переменная связывания rc с помощью команды variable< /а>. Внутри блока, который используется вместо локального v_Return, поэтому его даже не нужно объявлять локально. (Обратите внимание на двоеточие перед :rc в назначении из функции - это обозначает переменную связывания). А затем после блокировки клиент позволяет вам print курсор ссылки. (Эти ссылки на документы предназначены для SQL*Plus, но они входят в число множество команд, поддерживаемых SQL Developer.)

С фиктивным пакетом:

create or replace package WEBCAST_REPORTS AS
  TYPE ResultSetCursor IS ref cursor;
  FUNCTION LEAD_BASIC_INFO(
    leadEmail VARCHAR2,
    clientId NUMBER
  ) RETURN ResultSetCursor;
end WEBCAST_REPORTS;
/

create or replace package body WEBCAST_REPORTS AS
  FUNCTION LEAD_BASIC_INFO(
    leadEmail VARCHAR2,
    clientId NUMBER
  ) RETURN ResultSetCursor IS
    resultSet ResultSetCursor;
  BEGIN
    OPEN resultSet FOR select * from dual;
    RETURN resultSet;
  END LEAD_BASIC_INFO;
end WEBCAST_REPORTS;
/

затем код, который я показал выше, запускается как скрипт, показывает это в окне вывода скрипта:

PL/SQL procedure successfully completed.


D
-
X

В Oracle 12c вы можете использовать DBMS_SQL.RETURN_RESULT. то есть,

DECLARE
  LEADEMAIL VARCHAR2(200);
  CLIENTID NUMBER;
  v_Return ON24MASTER.WEBCAST_REPORTS.ResultSetCursor;
BEGIN
  LEADEMAIL := '[email protected]';
  CLIENTID := 22921;

  v_Return := WEBCAST_REPORTS.LEAD_BASIC_INFO(
    LEADEMAIL => LEADEMAIL,
    CLIENTID => CLIENTID
  );

    DBMS_SQL.RETURN_RESULT(v_Return); 

END;

SQL*Developer распечатает результаты.