Как заставить таймер работать? Вызов int 4ah через 5 секунд после запуска

DOSBox не дает доступа к часам реального времени.

Такие функции, как int 1Ah AH=06h (BIOS.SetSystemAlarm) и int 21h AH=2Dh (DOS.SetSystemTime), работают некорректно!
Почему? Что ж, DOSBox — это эмулятор, предназначенный для воспроизведения (существующих) игр DOS. Обычно игры не устанавливают часы (реального времени) и не используют будильник часов реального времени. Игры скорее имеют дело с задержками всех видов. Это объясняет, почему DOSBox не поддерживает такую ​​функциональность.
Хотя мы должны принять выбор разработчика, было бы неплохо, если бы он предоставил нам задокументированные коды возврата, сигнализирующие об ошибке.

• int 1Ah AH=06h (BIOS.SetSystemAlarm) лучше вернуть CF=1
• int 21h AH=2Dh (DOS.SetSystemTime) лучше вернуть AL=FFh

К счастью, Timer Tick работает нормально.

Чтобы создать программу, которая печатает «Привет от обработчика!», мы можем успешно использовать прерывание 1Ch. Задержка в 5 секунд будет означать 91 такт таймера, потому что в каждой секунде около 18,2 тика. При использовании этого 1-канального прерывания очень важно привязать его к исходному (предыдущему) обработчику, чтобы другие процессы могли по-прежнему управлять своим бизнесом.

Ниже мой вариант этой задачи:

; Create .COM program. We'll have CS=DS=ES=SS.
    org     256
; Show we're alive.
    mov     dx, Msg
    mov     ah, 09h
    int     21h
; Hook the 1Ch interrupt.
    xor     ax, ax
    mov     es, ax
    cli
    mov     ax, MyInt1C
    xchg    ax, [es:001Ch*4]
    mov     [Int1C+1], ax             ; Patch the 'jmpf' instruction (offset)
    mov     ax, cs
    xchg    ax, [es:001Ch*4+2]
    mov     [Int1C+3], ax             ; Patch the 'jmpf' instruction (segment)
    sti
; Wait for a key. Bulk of the program happens in the DOS kernel!
    mov     ah, 01h
    int     21h
; Restore the 1Ch interrupt.
    cli
    mov     ax, [Int1C+1]
    mov     [es:001Ch*4], ax
    mov     ax, [Int1C+3]
    mov     [es:001Ch*4+2], ax
    sti
; Terminate.
    mov     ax, 4C00h   
    int     21h
; -----------------------------------
MyInt1C:
    cmp     word [cs:TimeOut], 0     ; Zero disables this functionality
    je      Int1C
    dec     word [cs:TimeOut]
    jnz     Int1C                    ; Time not yet elapsed
    push    ds
    push    dx
    push    ax
    push    cs
    pop     ds
    mov     dx, Msg_
    mov     ah, 09h
    int     21h
    pop     ax
    pop     dx
    pop     ds
Int1C:
    jmpf    0:0                      ; Chain to the original handler
; -----------------------------------
TimeOut     dw  273                  ; 15 seconds x 18.2 = 273 ticks
Msg         db  'Sep says to wait 15 seconds...',13,10,'$'
Msg_        db  '15 seconds have elapsed. Press any key.',13,10,'$'

Майкл Петч сделал этот ценный комментарий о повторном входе в DOS или его отсутствии.

Я протестировал вышеуказанную программу под DOSBox без каких-либо проблем, потому что, цитируя мое руководство программиста,

Когда DOS ожидает ввода с клавиатуры, она бездействует в цикле, считывая символы по мере их поступления. Пока DOS ожидает в этот момент, она может использовать обработку файлов и другие функции, даже если флаг InDOS указывает на обратное.

Приведенная выше программа ничего не делает, кроме ожидания ввода с клавиатуры, так что все в порядке. В более сложной программе можно было бы и проверить флаг InDOS, и перехватить int 28h.
Однако остается простое решение, чтобы вообще не использовать DOS и выводить сообщение, используя, например, БИОС.Телетайп:

MyInt1C:
    cmp     word [cs:TimeOut], 0     ; Zero disables this functionality
    je      Int1C
    dec     word [cs:TimeOut]
    jnz     Int1C                    ; Time not yet elapsed
    push    ax
    push    bx
    push    si
    mov     bx, 0007h
    mov     si, Msg_
    cld
    jmps    .b
.a: mov     ah, 0Eh
    int     10h
.b: lods    byte [cs:si]
    test    al, al
    jnz     .a
    pop     si
    pop     bx
    pop     ax
Int1C:
    jmpf    0:0                      ; Chain to the original handler
; -----------------------------------
TimeOut     dw  273                  ; 15 seconds x 18.2 = 273 ticks
Msg         db  'Sep says to wait 15 seconds...',13,10,'$'
Msg_        db  '15 seconds have elapsed. Press any key.',13,10,0