Скрытие элементов в TListBox при фильтрации по строке

Элементы списка VCL, List Box в API, не имеет свойства видимости. Единственная возможность не показывать элемент - это удалить его.

Однако вы можете использовать элемент управления в виртуальном режиме, где нет никаких элементов. Вы сами решаете, какие данные хранить, что отображать. Это LBS_NODATA стиль окна в API . В VCL установите для свойства style значение lbVirtual.

Далее следует чрезвычайно упрощенный пример.

Давайте сохраним массив записей, по одной записи на виртуальный элемент.

type
  TListItem = record
    FileName: string;
    Visible: Boolean;
  end;

  TListItems = array of TListItem;

Вы можете расширить поля в соответствии с вашими требованиями. Я добавил, что видимость - одна из главных проблем в этом вопросе. Вы, вероятно, добавите что-нибудь, представляющее исходное имя, чтобы знать, какое имя было изменено, и т. Д.

Имейте один массив для каждого списка. В этом примере содержится одно окно со списком.

var
  ListItems: TListItems;

Хотя лучше сделать это поле, это только для демонстрации.

Требуемые единицы.

uses
  ioutils, types;

Некоторая инициализация при создании формы. Очистите правку фильтра. Установите соответствующий стиль списка. Заполните несколько имен файлов. Все элементы будут видны при запуске.

procedure TForm1.FormCreate(Sender: TObject);
var
  ListFiles: TStringDynArray;
  i: Integer;
begin
  ListFiles := ioutils.TDirectory.GetFiles(TDirectory.GetCurrentDirectory);

  SetLength(ListItems, Length(ListFiles));
  for i := 0 to High(ListItems) do begin
    ListItems[i].FileName := ListFiles[i];
    ListItems[i].Visible := True;
  end;

  ListBox1.Style := lbVirtual;
  ListBox1.Count := Length(ListFiles);

  Edit1.Text := '';
end;

В виртуальном режиме список интересует только свойство Count. Это определит количество отображаемых элементов, соответственно прокручиваемую область.

Вот часть фильтра, она чувствительна к регистру.

procedure TForm1.Edit1Change(Sender: TObject);
var
  Text: string;
  Cnt: Integer;
  i: Integer;
begin
  Text := Edit1.Text;
  if Text = '' then begin
    for i := 0 to High(ListItems) do
      ListItems[i].Visible := True;
    Cnt := Length(ListItems);
  end else begin
    Cnt := 0;
    for i := 0 to High(ListItems) do begin
      ListItems[i].Visible := Pos(Text, ListItems[i].FileName) > 0;
      if ListItems[i].Visible then
        Inc(Cnt);
    end;
  end;
  ListBox1.Count := Cnt;
end;

Особый случай OnChange редактирования - это когда текст пуст. Тогда все предметы будут показаны. В противном случае код из вопроса. Здесь мы также сохраняем общее количество видимых элементов, чтобы мы могли соответствующим образом обновить список.

Теперь единственная интересная часть, список требует данных.

procedure TForm1.ListBox1Data(Control: TWinControl; Index: Integer;
  var Data: string);
var
  VisibleIndex: Integer;
  i: Integer;
begin
  VisibleIndex := -1;
  for i := 0 to High(ListItems) do begin
    if ListItems[i].Visible then
      Inc(VisibleIndex);
    if VisibleIndex = Index then begin
      Data := ListItems[i].FileName;
      Break;
    end;
  end;
end;

Что здесь происходит, так это то, что для списка требуется, чтобы элемент отображался с указанием его индекса. Мы просматриваем главный список, подсчитывая видимые элементы, чтобы определить, какой из них соответствует этому индексу, и предоставляем его текст.

Я часто это делаю, но со списками, а не со списками. Однако основные принципы остались прежними.

Я стараюсь хранить отдельные элементы как объекты, которые в Delphi являются ссылочными типами. И я храню их все в одном основном нефильтрованном списке, которому принадлежат объекты, в то время как я поддерживаю отфильтрованный список (который не владеет объектами) для целей отображения. Как и @Sertac, я совмещаю это с представлением виртуального списка.

Чтобы увидеть, как это работает на практике, создайте новое приложение VCL и поместите представление списка (lvDisplay) и элемент управления (eFilter) в основную форму:

Обратите внимание, что я добавил три столбца к элементу управления представлением списка: «Имя», «Возраст» и «Цвет». Я также делаю его виртуальным (OwnerData = True).

Теперь определите класс для отдельных элементов данных:

type
  TDogInfo = class
    Name: string;
    Age: Integer;
    Color: string;
    constructor Create(const AName: string; AAge: Integer; const AColor: string);
    function Matches(const AText: string): Boolean;
  end;

где

{ TDogInfo }

constructor TDogInfo.Create(const AName: string; AAge: Integer;
  const AColor: string);
begin
  Name := AName;
  Age := AAge;
  Color := AColor;
end;

function TDogInfo.Matches(const AText: string): Boolean;
begin
  Result := ContainsText(Name, AText) or ContainsText(Age.ToString, AText) or
    ContainsText(Color, AText);
end;

И создадим нефильтрованный список собак:

TForm1 = class(TForm)
  eFilter: TEdit;
  lvDisplay: TListView;
  procedure FormCreate(Sender: TObject);
  procedure FormDestroy(Sender: TObject);
private
  FList, FFilteredList: TObjectList<TDogInfo>;
public
end;

где

function GetRandomDogName: string;
const
  DogNames: array[0..5] of string = ('Buster', 'Fido', 'Pluto', 'Spot', 'Bill', 'Rover');
begin
  Result := DogNames[Random(Length(DogNames))];
end;

function GetRandomDogColor: string;
const
  DogColors: array[0..2] of string = ('Brown', 'Grey', 'Black');
begin
  Result := DogColors[Random(Length(DogColors))];
end;

procedure TForm1.FormCreate(Sender: TObject);
var
  i: Integer;
begin

  FList := TObjectList<TDogInfo>.Create(True); // Owns the objects

  // Populate with sample data
  for i := 1 to 1000 do
    FList.Add(
      TDogInfo.Create(GetRandomDogName, Random(15), GetRandomDogColor)
    );

  FFilteredList := FList;

  lvDisplay.Items.Count := FFilteredList.Count;
  lvDisplay.Invalidate;

end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  if FFilteredList <> FList then
    FreeAndNil(FFilteredList);
  FreeAndNil(FList);
end;

Идея состоит в том, что элемент управления представлением списка всегда отображает FFilteredList, который либо указывает на тот же экземпляр объекта, что и FList, либо указывает на его отфильтрованную (или отсортированную) версию:

// The list view's OnData event handler
procedure TForm1.lvDisplayData(Sender: TObject; Item: TListItem);
begin

  if FFilteredList = nil then
    Exit;

  if not InRange(Item.Index, 0, FFilteredList.Count - 1) then
    Exit;

  Item.Caption := FFilteredList[Item.Index].Name;
  Item.SubItems.Add(FFilteredList[Item.Index].Age.ToString);
  Item.SubItems.Add(FFilteredList[Item.Index].Color);

end;

// The edit control's OnChange handler
procedure TForm1.eFilterChange(Sender: TObject);
var
  i: Integer;
begin

  if string(eFilter.Text).IsEmpty then // no filter, display all items
  begin
    if FFilteredList <> FList then
    begin
      FreeAndNil(FFilteredList);
      FFilteredList := FList;
    end;
  end
  else
  begin
    if (FFilteredList = nil) or (FFilteredList = FList) then
      FFilteredList := TObjectList<TDogInfo>.Create(False); // doesn't own the objects
    FFilteredList.Clear;
    for i := 0 to FList.Count - 1 do
      if FList[i].Matches(eFilter.Text) then
        FFilteredList.Add(FList[i]);
  end;

  lvDisplay.Items.Count := FFilteredList.Count;
  lvDisplay.Invalidate;

end;

Результат:

Обратите внимание, что для каждой собаки всегда есть только один объект в памяти, поэтому, если вы переименуете собаку, изменения отразятся в представлении списка, отфильтрованные или нет. (Но не забудьте сделать это недействительным!)