Как в Haskell обрезать пробелы в начале и в конце строки?

Если у вас есть серьезные потребности в обработке текста, воспользуйтесь пакетом text от hackage:

> :set -XOverloadedStrings
> import Data.Text
> strip "  abc   "
"abc"

Если вы слишком упрямы, чтобы использовать text, и вам не нравится неэффективность обратного метода, то, возможно (и я имею в виду МОЖЕТ БЫТЬ) что-то вроде приведенного ниже будет более эффективным:

import Data.Char

trim xs = dropSpaceTail "" $ dropWhile isSpace xs

dropSpaceTail maybeStuff "" = ""
dropSpaceTail maybeStuff (x:xs)
        | isSpace x = dropSpaceTail (x:maybeStuff) xs
        | null maybeStuff = x : dropSpaceTail "" xs
        | otherwise       = reverse maybeStuff ++ x : dropSpaceTail "" xs


> trim "  hello this \t should trim ok.. .I  think  ..  \t "
"hello this \t should trim ok.. .I  think  .."

Я написал это в предположении, что длина пробелов будет минимальной, поэтому ваши O (n) из ++ и reverse не вызывают особого беспокойства. Но я еще раз чувствую необходимость сказать, что если вас действительно беспокоит производительность, вам вообще не следует использовать String - перейдите к Text.

РЕДАКТИРОВАТЬ, подтверждая мою точку зрения, быстрый тест Criterion сообщает мне, что (для особенно длинной строки слов с пробелами и ~ 200 пробелов до и после) моя обрезка занимает 1,6 мс, обрезка с использованием реверса занимает 3,5 мс, а Data.Text.strip занимает 0,0016 мс. ..

От: http://en.wikipedia.org/wiki/Trim_(programming)#Haskell

import Data.Char (isSpace)

trim :: String -> String
trim = f . f
   where f = reverse . dropWhile isSpace

После того, как был задан этот вопрос (около 2012 г.) Data.List получил dropWhileEnd, что значительно упростило это:

trim = dropWhileEnd isSpace . dropWhile isSpace

Неэффективно, но легко понять и вставить туда, где это необходимо:

strip = lstrip . rstrip
lstrip = dropWhile (`elem` " \t")
rstrip = reverse . lstrip . reverse

Конечно, Data.Text лучше по производительности. Но, как уже упоминалось, делать это со списками просто весело. Вот версия, которая обрабатывает строку за один проход (без реверса и ++) и поддерживает бесконечные списки:

rstrip :: String -> String
rstrip str = let (zs, f) = go str in if f then [] else zs
    where
        go [] = ([], True)
        go (y:ys) =
            if isSpace y then
                let (zs, f) = go ys in (y:zs, f)
            else
                (y:(rstrip ys), False)

p.s. что касается бесконечных списков, это будет работать:

List.length $ List.take n $ rstrip $ cycle "abc  "

и по очевидной причине это не будет (будет работать вечно):

List.length $ List.take n $ rstrip $ 'a':(cycle " ")

Вы можете комбинировать Data.Text strip с его функциями un / Packing, чтобы избежать перегрузки строк:

import qualified Data.Text as T

strip  = T.unpack . T.strip . T.pack
lstrip = T.unpack . T.stripStart . T.pack
rstrip = T.unpack . T.stripEnd . T.pack

Тестирование:

> let s = "  hello  "
> strip s
"hello"
> lstrip s
"hello  "
> rstrip s
"  hello"

В настоящее время пакет MissingH поставляется с strip функция:

import           Data.String.Utils

myString = "    foo bar    "
-- strip :: String -> String
myTrimmedString = strip myString
-- myTrimmedString == "foo bar"

Поэтому, если преобразование из String в Text и обратно не имеет смысла в вашей ситуации, вы можете использовать указанную выше функцию.

Я знаю, что это старый пост, но я не видел решений, реализующих старый добрый fold.

Сначала удалите начальное белое пространство, используя dropWhile. Затем, используя foldl' и простое закрытие, вы можете проанализировать оставшуюся часть строки за один проход и на основе этого анализа передать этот информативный параметр в take без необходимости reverse:

import Data.Char (isSpace)
import Data.List (foldl')

trim :: String -> String
trim s = let
  s'    = dropWhile isSpace s
  trim' = foldl'
            (\(c,w) x -> if isSpace x then (c,w+1)
                         else (c+w+1,0)) (0,0) s'
  in
   take (fst trim') s'

Переменная c отслеживает объединенное белое и небелое пространство, которое должно быть поглощено, а переменная w отслеживает правое белое пространство, которое нужно удалить.

Тестовые прогоны:

print $ trim "      a   b c    "
print $ trim "      ab c    "
print $ trim "    abc    "
print $ trim "abc"
print $ trim "a bc    "

Вывод:

"a   b c"
"ab c"
"abc"
"abc"
"a bc"

Я считаю, что это должно быть верно в отношении O (n):

import Data.Char (isSpace)

trim :: String -> String
-- Trimming the front is easy. Use a helper for the end.
trim = dropWhile isSpace . trim' []
  where
    trim' :: String -> String -> String
    -- When finding whitespace, put it in the space bin. When finding
    -- non-whitespace, include the binned whitespace and continue with an
    -- empty bin. When at the end, just throw away the bin.
    trim' _ [] = []
    trim' bin (a:as) | isSpace a = trim' (bin ++ [a]) as
                     | otherwise = bin ++ a : trim' [] as

Я ничего не знаю о времени выполнения или эффективности, но как насчет этого:

-- entirely input is to be trimmed
trim :: String -> String
trim = Prelude.filter (not . isSpace')

-- just the left and the right side of the input is to be trimmed
lrtrim :: String -> String
lrtrim = \xs -> rtrim $ ltrim xs
  where
    ltrim = dropWhile (isSpace')
    rtrim xs
      | Prelude.null xs = []
      | otherwise = if isSpace' $ last xs
                    then rtrim $ init xs
                    else xs 

-- returns True if input equals ' '
isSpace' :: Char -> Bool
isSpace' = \c -> (c == ' ')

Решение без использования каких-либо других модулей или библиотек, кроме Prelude.

Некоторые тесты:

>lrtrim ""
>""

>lrtrim "       "
>""

>lrtrim "haskell       "
>"haskell"

>lrtrim "      haskell       "
>"haskell"

>lrtrim "     h  a  s k e   ll       "
>"h  a  s k e   ll"

Это может быть время выполнения O (n).

Но на самом деле я этого не знаю, потому что не знаю время выполнения функций last и init. ;)

Следуя тому, что предлагали другие люди, вы можете избежать необходимости переворачивать строку, используя:

import Data.Char (isSpace)

dropFromTailWhile _ [] = []
dropFromTailWhile p item
  | p (last items) = dropFromTailWhile p $ init items
  | otherwise      = items

trim :: String -> String
trim = dropFromTailWhile isSpace . dropWhile isSpace

Если вы хотите реализовать свою собственную trim функцию без импорта каких-либо необычных пакетов.

import Data.Char (isSpace)

trimLeft :: String -> String
trimLeft = dropWhile isSpace

trimRight :: String -> String
trimRight = dropWhileEnd isSpace

trim :: String -> String
trim = trimRight . trimLeft

Другое (стандартное) решение

import System.Environment
import Data.Text

strip :: String -> IO String
strip = return . unpack . Data.Text.strip . pack

main = getLine >>= Main.strip >>= putStrLn