Пакетная команда для переименования файлов в папках

Как упоминает @jarmod в комментариях: сохраните безопасную копию ваших исходных файлов, прежде чем запускать эту операцию! На всякий случай вам понадобится резервная копия.

Это должно сработать, если вы запустите его из основного каталога. Он будет перебирать все совпадающие файлы в подкаталогах и копировать в текущий (основной) каталог.

@echo off
Setlocal enabledelayedexpansion

Set "Pattern=\"
Set "Replace=_"
set "RemovePath=!CD:%Pattern%=%Replace%!_"

For /r %%# in ("*.doc?") Do (
    Set "File=%%~f#"
    set "trimfile=!File:%Pattern%=%Replace%!"
    set "trimfile=!trimfile:%RemovePath%=% %!"

    REM If you remove "echo" from the next line, the copy will happen
    echo copy "!File!" "!trimfile!"
)

Pause

Что оно делает:

1. Устанавливает несколько шаблонов для замены. То есть вы хотите заменить обратную косую черту \ на подчеркивание _.
2. Захватите текущий каталог, чтобы мы могли позже заменить его в имени файла.
3. Переберите все совпадающие файлы, используя полный путь, и замените \ в пути на _.
4. Удалите путь из результирующей строки, так как мы хотим только начать новое имя файла с именем каталога следующего уровня.
5. Повторите команду, которая будет запущена после удаления ключевого слова echo. *

Примечание. Самая важная строка отключается командой echo для безопасного выполнения. Если вам это нравится, удалите слово echo, и начнется операция copy.

Переутомленный недооцененный учитель!

@ECHO OFF
SETLOCAL
SET "sourcedir=U:\sourcedir\t w o"
FOR /f "delims=" %%a IN ( 
 'dir /s /b /a-d "%sourcedir%\*.doc" "%sourcedir%\*.docx" '
 ) DO for %%w in ("%%~dpa.") do for %%g in ("%%~dpw.") do for %%q in ("%%~dpg.") do ECHO REN "%%a" "%%~nxq_%%~na_%%~nxg%%~xa"
)

GOTO :EOF

Вам нужно будет изменить настройку sourcedir в соответствии с вашими обстоятельствами. В листинге используется настройка, которая подходит моей системе.

Греческий?

Нет, санскрит.

Прежде всего, возьмите dir листинг в /b базовой форме, /s с подкаталогами, /a-d, но без совпадающих имен каталогов двух масок файлов.

Обработайте результирующий список, игнорируя разделители по умолчанию ("delims=") до %%a, затем возьмите Drive и Path %%a (%%~dpa) и добавьте ., которое оценивается как имя родительского каталога без обратной косой черты в конце. Похоже, это имя файла, поэтому %%~dpw - это имя-прародитель, а %%~dpq - имя-прапрадедушка.

И затем все, что нам нужно сделать, это переименовать имя файла в %%a в ggp-Name и eXtension (%%~nxq) подчеркивание имя исходного файла (%%~na) подчеркивание grandparent-Name и eXtension (%%~nxg) eXtension исходного файла (%%~xa)

Необходимые команды REN просто ECHO указаны в целях тестирования. Убедившись, что команды верны, измените ECHO REN на REN, чтобы фактически переименовать файлы.

Внимание: это однократная операция, если вам не нужны имена файлов вроде \Math A\Jim Book\Book 2 Subtraction\Math A_Math A_Subtraction Booklet_Jim Book_Jim Book.docx
затем \Math A\Jim Book\Book 2 Subtraction\Math A_Math A_Math A_Subtraction Booklet_Jim Book_Jim Book_Jim Book.docx
...

Чтобы запустить пакет, все, что вам нужно сделать, это выполнить 'd:\wherever\you put\thisbatch" или, если вы поместите thisbatch.bat в каталог, который является элементом вашего path, тогда будет достаточно thisbatch.

Если вы установите sourcedir на . (то есть на одну точку), тогда пакет будет выполняться из любого вашего текущего каталога.