Создание игры в понг на ассемблере, как мне получить ввод нескольких клавиш одновременно?

Другой ответ касается многопользовательской игры, в которой ни один из игроков не нажимает свои выделенные клавиши и, таким образом, не загружает клавиатуру. Хотя этот сценарий вполне разумен, вы можете разрешить игрокам удерживать клавишу нажатой в течение более длительного периода времени. Для этого мы можем заменить обработчик клавиатуры, предоставляемый BIOS/DOS, нашим собственным обработчиком.

С каждой клавишей на клавиатуре связано уникальное 8-битное число, которое мы называем скан-кодом.
При каждом нажатии клавиши клавиатура делает скан-код соответствующей клавиши доступным на порту 60h. Клавиатура также генерирует прерывание 09h. Обработчик этого прерывания может проверить скан-код и обработать его любым способом. Это то, что делает приведенная ниже демонстрационная программа.
Когда клавиша нажата, скан-код представляет собой байт с отключенным старшим битом. Когда клавиша отпущена, скан-код представляет собой байт со старшим битом. Остальные 7 бит остаются одинаковыми как для нажатия, так и для отпускания.

Следует отметить, что, хотя он подходит для вашей игры в понг, встроенный обработчик подстановки является минималистичным. Сложный обработчик также будет учитывать расширенные скан-коды с префиксом E0h или E1h.

Программа имеет дополнительные комментарии, чтобы вы могли легко понять, что происходит. Код использует синтаксис FASM. Демонстрация нормально работает в реальной среде DOS и в DOSBox (0.74).

; Multi-player Keyboard Input (c) 2021 Sep Roland

    ORG  256               ; Output will be a .COM program

    mov  ax, 3509h         ; DOS.GetInterruptVector
    int  21h               ; -> ES:BX
    push es bx             ; (1)

    mov  dx, Int09
    mov  ax, 2509h         ; DOS.SetInterruptVector
    int  21h

    mov  ax, 0013h         ; BIOS.SetVideoMode 320x200 (256 colors)
    int  10h
    mov  ax, 0A000h        ; Video buffer
    mov  es, ax
    cld                    ; So we can use the string primitive STOSB

Cont:
    mov  si, 160           ; Width
    mov  di, 100           ; Height

    mov  al, 0             ; Black
    cmp  [KeyList+48h], al ; Up
    je   .a
    mov  al, 2             ; Green
.a: mov  cx, 160           ; X
    mov  dx, 0             ; Y
    call Paint

    mov  al, 0             ; Black
    cmp  [KeyList+50h], al ; Down
    je   .b
    mov  al, 14            ; Yellow
.b: mov  cx, 160           ; X
    mov  dx, 100           ; Y
    call Paint

    mov  al, 0             ; Black
    cmp  [KeyList+11h], al ; aZerty / qWerty
    je   .c
    mov  al, 4             ; Red
.c: mov  cx, 0             ; X
    mov  dx, 0             ; Y
    call Paint

    mov  al, 0             ; Black
    cmp  [KeyList+1Fh], al ; S
    je   .d
    mov  al, 1             ; Blue
.d: mov  cx, 0             ; X
    mov  dx, 100           ; Y
    call Paint

    cmp  byte [KeyList+1], 0 ; ESC
    je   Cont

    pop  dx ds             ; (1)
    mov  ax, 2509h         ; DOS.SetInterruptVector
    int  21h

    mov  ax, 4C00h         ; DOS.Terminate
    int  21h
; --------------------------------------
Int09:
    push ax bx
    in   al, 60h
    mov  ah, 0
    mov  bx, ax
    and  bx, 127           ; 7-bit scancode goes to BX
    shl  ax, 1             ; 1-bit press/release goes to AH
    xor  ah, 1             ; -> AH=1 Press, AH=0 Release
    mov  [cs:KeyList+bx], ah
    mov  al, 20h           ; The non specific EOI (End Of Interrupt)
    out  20h, al
    pop  bx ax
    iret
; --------------------------------------
; IN (al,cx,dx,si,di)
Paint:
    push cx dx di          ; AL=Color CX=X DX=Y SI=Width DI=Height
    push ax                ; (1)
    mov  ax, 320           ; BytesPerScanline
    mul  dx
    add  ax, cx            ; (Y * BPS) + X
    mov  dx, di
    mov  di, ax
    pop  ax                ; (1)
.a: mov  cx, si
    rep  stosb
    sub  di, si
    add  di, 320
    dec  dx
    jnz  .a
    pop  di dx cx
    ret
; --------------------------------------
KeyList db 128 dup 0

KeyList db 128 dup 0

KeyList программы записывает текущее состояние всех клавиш на клавиатуре. Если байт равен 0, клавиша не нажата. Если байт равен 1, эта клавиша в данный момент нажата.

проблема с этим кодом в том, что одновременно может двигаться только одна доска, а мне нужны обе

Ощущение одновременности возникает из-за того, что ты действуешь быстро, очень быстро. Почти все в вашем компьютере работает последовательно, но мы воспринимаем многие вещи как происходящие параллельно.

Ваш код checkskey в порядке. На одной доске используются клавиши q и s, а на другой — клавиши вверх и вниз.
Как только клавиша становится доступной, функция BIOS клавиатуры 00h немедленно извлечет ее, и ваша программа соответствующим образом обновит графику. Но если ваши процедуры графического вывода занимают слишком много времени, то игроки начнут думать, что клавиатура тормозит.

Глядя на ваши графические подпрограммы, я вижу, что вы используете функцию Video BIOS 0Ch для размещения пикселей на экране. Это медленно и особенно болезненно, так как вы играете на самом простом графическом экране, где вы можете всего MOV байта, чтобы нарисовать пиксель.

В программе, которая нуждается в быстрой графике, может быть очень выгодно, чтобы регистр сегмента ES постоянно указывал на видеобуфер.

  mov  ax, 0A000h
  mov  es, ax
  cld             ; Because of the use of STOSB

Это все, что нужно, чтобы очистить экран:

ClearScreen:
  xor  di, di
  mov  cx, 64000
  mov  al, 0
  rep stosb
  ret

Вот как вы рисуете горизонтальную линию (160 100)-(200 100):

  mov  dl, 15    ; BrightWhite
  mov  cx, 51    ; 51 pixels from 160 to 200
  mov  bx, 160   ; X
  mov  ax, 100   ; Y
  call DrawLine

  ...

DrawLine:
  push dx
  mov  di, 320   ; BytesPerScanline
  mul  di
  add  ax, bx
  mov  di, ax    ; Address DI = (Y * BPS) + X
  pop  ax        ; Color AL
  rep stosb
  ret