Проблема с заменой битов в Haskell

Если вам нужна эффективная реализация, я не думаю, что вы можете избежать работы с байтами. Вот пример решения. Предполагается, что в ByteString всегда есть четное число байтов. Я не очень хорошо знаком с распаковкой или настройкой строгости, но я думаю, что это необходимо, если вы хотите быть очень эффективным.

import Data.ByteString (pack, unpack, ByteString)
import Data.Bits
import Data.Word

-- the main attraction
packString :: ByteString -> ByteString
packString = pack . packWords . unpack

-- main attraction equivalent, in [Word8]
packWords :: [Word8] -> [Word8]
packWords ws = evenPacked ++ unevenPacked
    where evenBits = map packEven ws
          unevenBits = map packUneven ws
          evenPacked = consumePairs packNibbles evenBits
          unevenPacked = consumePairs packNibbles unevenBits

-- combines 2 low nibbles (first 4 bytes) into a (high nibble, low nibble) word
-- assumes that only the low nibble of both arguments can be non-zero. 
packNibbles :: Word8 -> Word8 -> Word8
packNibbles w1 w2 = (shiftL w1 4) .|. w2 

packEven w = packBits w [0, 2, 4, 6]

packUneven w = packBits w [1, 3, 5, 7]

-- packBits 254 [0, 2, 4, 6] = 14 
-- packBits 254 [1, 3, 5, 7] = 15
packBits :: Word8 -> [Int] -> Word8
packBits w is = foldr (.|.) 0 $ map (packBit w) is

-- packBit 255 0 = 1
-- packBit 255 1 = 1
-- packBit 255 2 = 2
-- packBit 255 3 = 2
-- packBit 255 4 = 4
-- packBit 255 5 = 4
-- packBit 255 6 = 8
-- packBit 255 7 = 8
packBit :: Word8 -> Int -> Word8
packBit w i = shiftR (w .&. 2^i) ((i `div` 2) + (i `mod` 2))

-- sort of like map, but halves the list in size by consuming two elements. 
-- Is there a clearer way to write this with built-in function?
consumePairs :: (a -> a -> b) -> [a] -> [b]
consumePairs f (x : x' : xs) = f x x' : consumePairs f xs
consumePairs _ [] = []
consumePairs _ _ = error "list must contain even number of elements"

это должно работать:

import Data.List
import Data.Function

map fst $ sortBy (compare `on` snd) $ zip yourList $ cycle [0,1]

Небольшое пояснение: поскольку sortBy сохраняет исходный порядок, мы можем соединить каждое значение в четной позиции с «0» и каждое значение в нечетной позиции с «1», затем мы просто сортируем по второму значению пары. Таким образом, все значения в четных позициях будут помещены перед значениями в нечетных позициях, но их порядок будет сохранен.

Крис

Если производительность не критична, я бы рекомендовал использовать представление битового вектора для такого проекта. Как вы уже поняли, произвольный доступ к отдельным битам доставляет определенные неудобства, когда они находятся в упакованном виде, но Data.Vector предоставляет множество функций для подобных задач.

import Data.Bits
import qualified Data.Vector as V

type BitVector = V.Vector Bool

unpack :: (Bits a) => a -> BitVector
unpack w = V.generate (bitSize w) (testBit w)

pack :: (Bits a) => BitVector -> a
pack v = V.ifoldl' set 0 v
  where
    set w i True = w `setBit` i
    set w _ _    = w

mkPermutationVector :: Int -> V.Vector Int
mkPermutationVector d = V.generate (2^d) b
  where
    b i | i < 2^(d-1) = 2*i
        | otherwise   = let i' = i-2^(d-1)
                        in 2*i'+1

permute :: Int -> BitVector -> BitVector
permute d v = V.backpermute v (mkPermutationVector d)

Обратите внимание, как это позволяет указать перестановку, точно расшифровав математическое описание. Это существенно снижает вероятность ошибок и более приятно для написания, чем битовый код.

Чтобы проверить ваш пример вектора (в базе 10):

*Main> import Data.Word
*Main Data.Word> let permute16 = pack . permute 4 . unpack :: Word16 -> Word16
*Main Data.Word> permute16 43690
65280

Теперь, переходя к битовым векторам в качестве представления, вы теряете многое из того, что получаете бесплатно, используя типы Haskell, такие как экземпляры Num. Однако вы всегда можете реализовать Num операций для своего представления; вот начало:

plus :: BitVector -> BitVector -> BitVector
plus as bs = V.tail sums
  where
    (sums, carries) = V.unzip sumsAndCarries
    sumsAndCarries  = V.scanl' fullAdd (False, False) (V.zip as bs)
    fullAdd (_, cin) (a, b) = ((a /= b) /= cin
                              , (a && b) || (cin && (a /= b)))

Вы также можете найти полезным пакет Левента Эркока sbv, хотя я не уверен, что он предоставляет функцию как удобно как backpermute для вашего конкретного вопроса.

Обновление: мне показалось, что на этот вопрос будет интересно ответить, поэтому я немного расширил код в виде библиотеки: бит-вектор.