Delphi: подсказка заголовка столбца DBGrid - принудительно сбросить подсказку?

Я думал, что реализовал подсказку заголовка столбца в моей собственной DBGrid. Вроде бы просто, - подумал я.

я добавил

TitleHints: TStrings

который содержит информацию в этом формате:

имя = значение

Где имя (0-99) для столбцов, не основанных на полях, и имя поля для столбцов на основе полей. Значение - это подсказка столбца, crlf - \ n.

Все в порядке, OnMouseMove - подсказка по положению.

Но: показана только первая подсказка, а дальнейшие нет. Я думаю, это потому, что механизм подсказок активируется, когда мышь попадает в «Control» ... Когда я выхожу из Control и возвращаюсь снова, я получаю еще одну подсказку - один раз. Независимо от того, что я отключил ShowHint.

Поскольку я не хочу создавать свой собственный HintWIndow, если это возможно, я ищу способ сбросить механизм подсказки, чтобы он считал Applicaion: это первый случай в этом элементе управления. Могу ли я сделать это любым способом, например, "отправить сообщение" или вызвать "cancelhint", если он существует, и т. Д.

Вы знаете об этом способе?

Спасибо за вашу помощь, и хорошего вам дня!

С уважением: dd


delphi controls title hint dbgrid
person durumdara    schedule 14.10.2011    source источник

Ответы (1)


arrow_upward
3
arrow_downward

Вы можете повторно активировать подсказку в своем переопределенном MouseMove, например:

type
  TDBGrid = class(DBGrids.TDBGrid)
  private
    FLastHintColumn: Integer;
  protected
    procedure CMHintShow(var Message: TCMHintShow); message CM_HINTSHOW;
    function GetColumnTitleHint(Col: Integer): string;
    procedure MouseMove(Shift: TShiftState; X: Integer; Y: Integer); override;
  public
    constructor Create(AOwner: TComponent); override;
  end;


procedure TDBGrid.CMHintShow(var Message: TCMHintShow);
var
  Cell: TGridCoord;
begin
  if not Assigned(Message.HintInfo) or not (dgTitles in Options) then
    inherited
  else
  begin
    Cell := MouseCoord(Message.HintInfo^.CursorPos.X, Message.HintInfo^.CursorPos.Y);
    if Cell.Y = 0 then
    begin
      FLastHintColumn := Cell.X - 1;
      Message.HintInfo^.HintStr := GetColumnTitleHint(FLastHintColumn);
    end
    else
      FLastHintColumn := -1;
  end;
end;

function TDBGrid.GetColumnTitleHint(Col: Integer): string;
begin
  Result := Columns[Col].Title.Caption + ' hint';
end;

procedure TDBGrid.MouseMove(Shift: TShiftState; X, Y: Integer);
var
  Cell: TGridCoord;
begin
  inherited MouseMove(Shift, X, Y);
  if dgTitles in Options then
  begin
    Cell := MouseCoord(X, Y);
    if Cell.Y = 0 then
    begin
      if Cell.X - 1 <> FLastHintColumn then
        Application.ActivateHint(Mouse.CursorPos);
    end
    else
      Application.CancelHint;
  end;
end;

constructor TDBGrid.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);
  FLastHintColumn := -1;
end;

GetColumnTitleHint - это только пример, вы должны реализовать его, чтобы вернуть правильное значение из вашего TitleHints свойства.

Надеюсь это поможет.

person Ondrej Kelle    schedule 14.10.2011