Я успешно написал сценарий, который берет строку для поиска в определенном файле, а затем выводит строку, в которой она впервые встречается, а затем я беру это значение в цикл for и пропускаю синтаксический анализ этого количества строк и записываю его содержимое в новый файл. Однако я не получаю пустых строк, которые мне сложно решить.
Строка, которую я ищу, - это «/]», кэширует номер строки, где она встречается, а затем накапливает ее в переменной с разделением запятыми. Затем я снова беру эту переменную в цикл for и извлекаю первое встречающееся значение в качестве моей последней переменной «пропустить это количество строк», которую я затем использую в нижней части цикла for, который снова читает этот файл и записывает его значения в a новые файлы и пропускает это количество строк в начале файла.
Итак, вот часть скрипта, которая делает то, что я описал выше:
setlocal enabledelayedexpansion
setlocal enableextensions
set live_svn_access_file=c:\csvn\data\conf\svn_access_file
set of=c:\test.txt
for /f "Tokens=1 Delims=:" %%i in ('findstr /n /c:"/]" %live_svn_access_file%') do (
rem cache value in a variable
set line=%%i
rem accumulate data to one variable
if defined line set skip=!skip!, !line!
)
rem strip first two characters in variable ", "
set skip=!skip:~2!
rem strip everything except first value in array
for /f "Tokens=1 Delims=," %%i in ('echo !skip!') do (
rem store value in a variable
set skip=%%i
)
rem calculate lines - 1 (arithmetic)
set /a skip=!skip!-1
set skip=!skip!
if not defined skip set error=Could not automatically find which parts to skip from live svn_access_file && goto error-handler
for /f "Tokens=* Delims= Skip=%skip%" %%i in (%live_svn_access_file%) do (
rem cache value in a variable
set read-input=%%i
rem write and append content of variable to output-file
echo !read-input! >> %of%
)
Я переписал скрипт, чтобы он соответствовал рабочему, это измененный скрипт:
setlocal enabledelayedexpansion
setlocal enableextensions
set live_svn_access_file=c:\csvn\data\conf\svn_access_file
set of=c:\test.txt
for /f "Tokens=1 Delims=:" %%i in ('findstr /n /r /c:"\[..*\]" %live_svn_access_file%') do (
rem cache value in a variable
set line=%%i
rem accumulate data to one variable
if defined line set skip=!skip!, !line!
)
rem take the 2nd sections linenumber into a variable, skipping the first [*foo*]
for /f "Tokens=2 Delims=," %%i in ('"echo !skip!"') do (
rem store value in a variable
set skip=%%i
)
rem add 1 line to skip from retrieved value
set /a skip=!skip!-1
rem verify that number of lines to skip has been successfully retrieved, if not go to error-handler
if not defined skip set error=Could not automatically find which parts to skip from live svn_access_file && goto error-handler
if ["%skip%"] LSS ["1"] set error=Number of lines to skip was less than 1, this will most likely fail && goto error-handler
rem read live svn_access_file, but skip X-lines and write to output-file
setlocal DisableDelayedExpansion
for /f "usebackq Delims= Skip=%skip%" %%i in (`"findstr /n ^^ %live_svn_access_file%"`) do (
rem cache value in a variable
set read-input=%%i
rem write and append content of variable to output-file
setlocal EnableDelayedExpansion
rem strip line number prefix
set read-input=!read-input:*:=!
rem write read lines to output-file
echo(!read-input!>>%of%
endlocal
)
if not defined read-input echo. >> %of%
создает строку с одним пробелом вместо пустой строки, вы можете изменить ее на(>> %of% echo.)
. Вам следует избегатьecho.
, это медленно и может дать сбой, лучше использоватьecho(
. Опцияskip=%skip%
не работает, если%skip%
равно нулю - person jeb   schedule 26.10.2011