API sendmessage и sendmessagetimeout, совместимые с VB.NET

Да, первый правильный. Не используйте объявления Declare Function...Lib в старом стиле; они поддерживаются только для совместимости с VB 6. Определения нового стиля P/Invoke выглядят следующим образом:

<DllImport("user32.dll", SetLastError:=True)> _
Public Shared Function SendMessageTimeout(ByVal hWnd As IntPtr,
                                          ByVal msg As Integer,
                                          ByVal wParam As IntPtr,
                                          ByVal lParam As IntPtr,
                                          ByVal flags As SendMessageTimeoutFlags,
                                          ByVal timeout As Integer,
                                          ByRef result As IntPtr) As IntPtr
End Function

Но отправлять WM_WININICHANGE, вероятно, нельзя; это сообщение давно устарело. В документах прямо сказано:

Примечание. Сообщение WM_WININICHANGE предоставляется только для совместимости с более ранними версиями системы. Приложения должны использовать сообщение WM_SETTINGCHANGE.

Поэтому я рекомендую использовать WM_SETTINGCHANGE, даже несмотря на то, что заголовки Windows технически определяют их как одно и то же значение. Это не контракт, и ваш код будет намного читабельнее, если вы будете использовать правильные имена. Читая документацию для этого, он говорит:

Приложения должны отправлять WM_SETTINGCHANGE всем окнам верхнего уровня, когда они вносят изменения в системные параметры. (Это сообщение нельзя отправить непосредственно в окно.) Чтобы отправить сообщение WM_SETTINGCHANGE всем окнам верхнего уровня, используйте SendMessageTimeout с параметром hwnd, для которого задано значение HWND_BROADCAST.

Хорошо, по крайней мере, вы уже правильно поняли эту часть. Следующей задачей является написание кода для фактического вызова функции и передачи сообщения. Что-то типа:

Public Shared ReadOnly HWND_BROADCAST As New IntPtr(&HFFFF)
Public Const WM_SETTINGCHANGE As Integer = &H001A

<Flags()> _
Public Enum SendMessageTimeoutFlags
    SMTO_NORMAL = 0
    SMTO_BLOCK = 1
    SMTO_ABORTIFHUNG = 2
    SMTO_NOTIMEOUTIFNOTHUNG = 8
End Enum  

Public Sub BroadcastChangeMessage()
    Dim returnValue As IntPtr = SendMessageTimeout(HWND_BROADCAST,
                                                   WM_SETTINGCHANGE,
                                                   IntPtr.Zero,
                                                   IntPtr.Zero,
                                                   SendMessageTimeoutFlags.SMTO_ABORTIFHUNG Or SendMessageTimeoutFlags. SMTO_NOTIMEOUTIFNOTHUNG,
                                                   5000,
                                                   IntPtr.Zero)
    If returnValue = IntPtr.Zero Then
        MessageBox.Show("Something went wrong and the function failed. Error code: " _
                        & Marshal.GetLastWin32Error().ToString())
    End If
End Sub

Обратите внимание, что я проверяю возвращаемое значение функции SendMessageTimeout. Я точно не помню, как это работает, когда вы указываете HWND_BROADCAST и если вы получаете осмысленный код ошибки, но всегда стоит проверить успех или неудачу.